Zero =Blank

[RichardL]

I was using AutoIt to make occasional test values for another app. So I had an array of some new values that needed action, and some blanks. Then I realised that zero was not being actioned, and the problem is this test gives true.

$x = 0
If $x = "" Then
  ConsoleWrite("Blank ")
EndIf

So I tried the opposite and that gives true as well.

$x = ""
If $x = 0 Then
  ConsoleWrite("Zero ")
EndIf

So is "" identical to 0? but it can't be because Number() can see the difference? Is this a fault? Or just needs a warning in the help? I looked at the data-types help, but didn't see a clear warning about this.

?

Edited April 10, 2013 by RichardL

[water]

Please check the description of datatypes in the help file.

This sentence describes what's going on: "If a string is used as a number, an implicit call to Number() function is done. So if it doesn't contain a valid number, it will be assumed to equal 0."

[BrewManNH]

Empty strings, and any string that can't be converted to a number, is going to equal to zero.

[water]

AutoIt uses Number() internally so the following comparison is being done:

If 0 = 0 Then ...

[RichardL]

Yes, both your replies explain the second example. In the first, is the comparison done as a number or string? The result implies that "" is converted to 0 so the result is true.

[BrewManNH]

No, it explains both examples because they're identical...you're comparing a string to a number in both, just because the 2 are on opposite sides of the comparison makes no difference. "" = 0 and 0 = ""

[czardas]

Have you tried this?

$x = 0
If $x == "" Then
  ConsoleWrite("Blank ")
EndIf

$x = ""
If $x == 0 Then
  ConsoleWrite("Zero ")
EndIf

Edited April 10, 2013 by czardas

[AZJIO]

Have you tried this?

$x = 0
ConsoleWrite('>|' & $x & '|<' &@LF)
ConsoleWrite(VarGetType($x) &@LF)
$x = ""
ConsoleWrite('>|' & $x & '|<' &@LF)
ConsoleWrite(VarGetType($x) &@LF)

[RichardL]

Tried both examples - use == to force string comparison, use VarGetType to test number/string.

Thanks.

[guinness]

Or IsNumber and IsString.

[AZJIO]

Usually the type of data is known. If function returns 0, won't come to mind to compare it with a line.

Think about what type of data the variable can store. In most cases, this solves the problem.

If the array contains different data types and is compared in the loop as equivalent data, then it's the wrong coding.

[RichardL]

Not quite equivalent data, either a new numeric value or a string blank to indicate not to transfer the value. A cheap trick to avoid adding an array of flags and passing that along with the array of values.

[jchd]

If you use the beta you can assign the keyword Null to a variable. The semantic being "this variable has not been assigned a meaningfull value".

Then after function return you can test for the variable being == Null

[AZJIO]

expandcollapse popup

#include <Array.au3>

Local $a[100]
For $i = 0 To 99
    $tmp = Random(0, 8, 1)
    If $tmp = 5 Then $tmp = ''
    $a[$i] = $tmp
Next

; _ArrayDisplay($a, 'Array')


Local $b[100]
$timer1 = TimerInit()
$j = 0
For $i = 0 To 99
    If $a[$i] Or $a[$i]=='0' Then ; faster
        $b[$j] = $a[$i]
        $j+=1
    EndIf
Next
$timer1 = TimerDiff($timer1)
ReDim $b[$j]


Local $c[100]
$timer2 = TimerInit()
$j = 0
For $i = 0 To 99
    If Not($a[$i]=='0') Then ; slower
        $c[$j] = $a[$i]
        $j+=1
    EndIf
Next
$timer2 = TimerDiff($timer2)
ReDim $c[$j]

_ArrayDisplay($b, 'Array')
; _ArrayDisplay($c, 'Array')

MsgBox(0, "Res", _
'Time1 : ' & Round($timer1, 2) & ' msec' &@LF& _
'Time2 : ' & Round($timer2, 2) & ' msec')

Edited April 11, 2013 by AZJIO