[SOLVED] image in Listview issue

[GreenCan]

Does anyone know if I can get rid of the effect in Column 0 of the Listview in the attached example?

Although there is no thumbnail, the left most part seems to be reserved for an image that does not exist.

It could be related to _GUIImageList_GetImageCount($hImage) but I don't know what to put instead of this.

The question is related to post SQLite ListView and BLOB demo

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Local $hGUI = GUICreate("ListView example", 300, 250)

Local $hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems", 10, 10, 280,230, $LVS_REPORT, $WS_EX_CLIENTEDGE)
_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, _
$LVS_EX_SUBITEMIMAGES, $LVS_EX_INFOTIP))

GUICtrlSendMsg($hListView, $LVM_SETCOLUMNWIDTH, 0, 60)
GUICtrlSendMsg($hListView, $LVM_SETCOLUMNWIDTH, 1, 250)

Local $iImageSquareSize = 30
Local $hImage = _GUIImageList_Create($iImageSquareSize, $iImageSquareSize, 5, 3)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
_GUICtrlListView_SetImageList($hListView, $hImage, 1)

_GUICtrlListView_AddItem($hListView, "Test item 1", _GUIImageList_GetImageCount($hImage))
;_GUICtrlListView_SetItemImage($hListView, 0, -1)
_GUICtrlListView_AddSubItem($hListView, 0, "SubItem test 1", 1, 0)
_GUICtrlListView_AddItem($hListView, "Test item 2", _GUIImageList_GetImageCount($hImage))

_GUICtrlListView_AddSubItem($hListView, 1, "SubItem test 2", 1)

_GUICtrlListView_AddItem($hListView, "Test item 3", _GUIImageList_GetImageCount($hImage))
_GUICtrlListView_AddSubItem($hListView, 2, "SubItem test 3", 1, 1)

GUISetState()

While 1
Switch GUIGetMsg()
         Case $GUI_EVENT_CLOSE
             ExitLoop
         EndSwitch
WEnd

Thanks for assistance

GreenCan

Edited May 9, 2013 by GreenCan

[BrewManNH]

Why are you using $WS_EX_CLIENTEDGE for the ListView control? That constant is equivalent to $LVS_EX_REGIONAL, which might be part of the problem, although I'm not sure what $LVS_EX_REGIONAL does because the descriptions I've found for it are vague to say the least.

[Melba23]

GreenCan,

I would agree with BrewManNH here - I would never recommend using extended styles with ListViews other than using the _GUICtrlListView_SetExtendedListViewStyle function to set LVS_EX styles. I have seen many cases where the control gets very confused by identical WS_EX and LVS_EX values.

M23

[GreenCan]

GreenCan,

I would agree with BrewManNH here - I would never recommend using extended styles with ListViews other than using the _GUICtrlListView_SetExtendedListViewStyle function to set LVS_EX styles. I have seen many cases where the control gets very confused by identical WS_EX and LVS_EX values.

M23

Thanks for your both your replies BrewManNH and M23

I use $WS_EX_CLIENTEDGE because it draws a nice borderline around the ListView, removing it results in a less attractive effect.

$LVS_EX_REGIONAL has no effect at all when I add it to the list in _GUICtrlListView_SetExtendedListViewStyle

If I put it instead of the wrongly used $WS_EX_CLIENTEDGE then I have the borderline again

Local $hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems", 10, 10, 280,230, $LVS_REPORT, $LVS_EX_REGIONAL)

You have to admit that the Helpfile is no very clear on what $LVS_EX_REGIONAL does:

$LVS_EX_REGIONAL - Sets the control region to include only the item icons and text

But still, that doesn't solve the issue

GreenCan

Edited May 7, 2013 by GreenCan

[BrewManNH]

I'm guessing, by testing this, that as soon as you assign an image list to the listview, the first column is automatically sized to accept the image size specified in the _GUIImageList_Create function even if you don't use one in it.

[GreenCan]

I'm guessing, by testing this, that as soon as you assign an image list to the listview, the first column is automatically sized to accept the image size specified in the _GUIImageList_Create function even if you don't use one in it.

Yes, that is also what I assume, shouldn't that be considered as a bug?

Additionally, don't you find it strange that the third parameter should be filled in with a strange function?

_GUICtrlListView_AddItem($hListView, "Test item 1", _GUIImageList_GetImageCount($hImage))

I you omit it, you get an image in column 1

Edited May 7, 2013 by GreenCan

[Melba23]

GreenCan,

If it is a bug it is a bug in the ListView control itself, not AutoIt.

M23

[BrewManNH]

If it is a bug, it's a Windows bug because _GUICtrlListView_SetImageList just uses _SendMessage($hWnd, $LVM_SETIMAGELIST, to tell the listview that you're assigning an image list to the LV and it's not just AutoIt that has this "problem".

[GreenCan]

OK, Let me take my phone and call Steve Balmer muttley

[JohnOne]

http://msdn.microsoft.com/en-us/library/windows/desktop/bb774732?v=vs.85.aspx

Version 4.71 through Version 5.80 only. Not supported on Windows Vista. Sets the list view window region to include only the item icons and text using SetWindowRgn. Any area that is not part of an item is excluded from the window region. This style is only available to list-view controls that use the LVS_ICON style.

[GreenCan]

Thanks JohnOne,

I think this is a little bit better than the slimmed version in the help file

[KaFu]

How about this little workaround I use in SMF too ?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Local $hGUI = GUICreate("ListView example", 300, 250)

Local $hListView = _GUICtrlListView_Create($hGUI, "SubItems|Items", 10, 10, 280, 230, $LVS_REPORT, $WS_EX_CLIENTEDGE)
_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_INFOTIP))

GUICtrlSendMsg($hListView, $LVM_SETCOLUMNWIDTH, 1, 60)
GUICtrlSendMsg($hListView, $LVM_SETCOLUMNWIDTH, 0, 250)

Local $iImageSquareSize = 30
Local $hImage = _GUIImageList_Create($iImageSquareSize, $iImageSquareSize, 5, 3)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
_GUICtrlListView_SetImageList($hListView, $hImage, 1)


_GUICtrlListView_AddItem($hListView, "SubItem test 1", 0)
_GUICtrlListView_AddSubItem($hListView, 0, "Test item 1", 1)

_GUICtrlListView_AddItem($hListView, "SubItem test 2", 2)
_GUICtrlListView_AddSubItem($hListView, 1, "Test item 2", 1)

_GUICtrlListView_AddItem($hListView, "SubItem test 3", 1)
_GUICtrlListView_AddSubItem($hListView, 2, "Test item 3", 1)

_GUICtrlListView_SetColumnOrder($hListView, "1|0")

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

[Clark]

Haha, clever workaround KaFu.

[GreenCan]

This is indeed smart.

Thank you KaFu

[KaFu]

You're welcome .

[BrewManNH]

Brilliant method, I didn't even know about ColumnOrder. I love it when I learn new stuff.

[BrewManNH]

From your other post on this, I'd suggest reading the help file in regards to SetColumnOrder again (or for the first time) you're using it wrong.

[faustf]

but  ,  why i must   mix  a colum  and  after with columoreder   unmix  again  ??? 

in  this example  put  icon only first  in  first colum  and   first in 3  colum

and  dont  use  columorder i think is possible to do with  out  columorder

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

_Main()

Func _Main()
    Local $hGui, $listview, $hImage
    Local $exStyles = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)

    $hGui = GUICreate("ImageList AddIcon", 400, 300)
    $listview = _GUICtrlListView_Create($hGui, "", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($listview, $exStyles)
    GUISetState()

    ; Load images
    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    ;_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    ;_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    ;_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 170)
    ;_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 171)
    ;_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 172)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
;   _GUICtrlListView_SetImageList($listview, $hImage, 1)

    ; Add columns
    _GUICtrlListView_AddColumn($listview, "Column 1", 120)
    _GUICtrlListView_AddColumn($listview, "Column 2", 100)
    _GUICtrlListView_AddColumn($listview, "Column 3", 100)

    ; Add items
    _GUICtrlListView_AddItem($listview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($listview, 0, "Row 1: Col 2", 1, 1)
    _GUICtrlListView_AddSubItem($listview, 0, "Row 1: Col 3", 2, 2)
    _GUICtrlListView_AddItem($listview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($listview, 1, "Row 2: Col 2", 1, 2)
    _GUICtrlListView_AddItem($listview, "Row 3: Col 1", 2)
    _GUICtrlListView_AddItem($listview, "Row 4: Col 1", 3)
    _GUICtrlListView_AddItem($listview, "Row 5: Col 1", 4)
    _GUICtrlListView_AddSubItem($listview, 4, "Row 5: Col 2", 1, 3)
    _GUICtrlListView_AddItem($listview, "Row 6: Col 1", 5)
    _GUICtrlListView_AddSubItem($listview, 5, "Row 6: Col 2", 1, 4)
    _GUICtrlListView_AddSubItem($listview, 5, "Row 6: Col 3", 2, 3)
    _GUICtrlListView_SetItemImage($ListView, 0, 0,2)
    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

[faustf]

active this

 _GUICtrlListView_SetImageList($listview, $hImage, 1)

[BrewManNH]

 

in  this example  put  icon only first  in  first colum  and   first in 3  colum

and  dont  use  columorder i think is possible to do with  out  columorder

Well, when you figure out how to do that, please let us know.