Any way to drag and drop multiple files at once?

[careca]

I have a simple drag and drop script, i can drop files to a listview, and make them appear in it, but i wonder if its possible to drop multiple files, and how would it "read" them.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $listview, $button, $item1, $item2, $item3, $item4, $msg
    GUICreate("listview items", 220, 200, 100, 100, -1, $WS_EX_ACCEPTFILES)
    $listview = GUICtrlCreateListView("col1|col2|col3  ", 10, 10, 200, 150)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED)
    $item1 = GUICtrlCreateListViewItem("1|4|7", $listview)
    $item2 = GUICtrlCreateListViewItem("2|5|8", $listview)
    $item3 = GUICtrlCreateListViewItem("3|6|9", $listview)
    GUISetState()

    Do
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_DROPPED
                GUICtrlCreateListViewItem(@GUI_DRAGFILE&'|'&'|', $listview)
        EndSelect
    Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

[guinness]

Here, you will need WinAPIEx.au3

expandcollapse popup

#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIEx.au3>
#include <WindowsConstants.au3>

Global $__aGUIDropFiles = 0, $__hGUI = 0

Example()

Func Example()
    $__hGUI = GUICreate('WM_DROPFILES', 400, 200, Default, Default, Default, $WS_EX_ACCEPTFILES)

    Local Const $iDrop = GUICtrlCreateLabel('', 0, 0, 400, 200)
    GUICtrlSetBkColor($iDrop, $GUI_BKCOLOR_TRANSPARENT)
    GUICtrlSetState($iDrop, $GUI_DROPACCEPTED)

    GUISetState(@SW_SHOW, $__hGUI)
    GUIRegisterMsg($WM_DROPFILES, 'WM_DROPFILES')

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $GUI_EVENT_DROPPED
                For $i = 1 To $__aGUIDropFiles[0]
                    MsgBox($MB_SYSTEMMODAL, '', $__aGUIDropFiles[$i])
                Next

        EndSwitch
    WEnd

    GUIDelete($__hGUI)
EndFunc   ;==>Example

Func WM_DROPFILES($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $lParam
    Switch $iMsg
        Case $WM_DROPFILES
            Local Const $aReturn = _WinAPI_DragQueryFileEx($wParam)
            If UBound($aReturn) Then
                $__aGUIDropFiles = $aReturn
            Else
                Local Const $aError[1] = [0]
                $__aGUIDropFiles = $aError
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_DROPFILES

[careca]

Thank you! I was wondering why no one would answer, turns out, it wasn't so simple.

[guinness]

Thank you! I was wondering why no one would answer, turns out, it wasn't so simple.

I was a sleep when you posted and probably others were too.

The WM_DROPFILES you see around by LazyCat (if I remember correctly) is flawed and thus the WinAPIEx is a preferred choice.

[careca]

For anyone who cares, i had a problem with the script recognizing i dropped something,

because the main loop is quite big, so it would randomly detect the drop, solved with

GUISetOnEvent($GUI_EVENT_DROPPED, "Drop")

and then having the code in the function.

Works everytime because it doesn't depend one those specific lines

being processed at the time of drop.

[guinness]

This can be solved by re-organising the loop.

[Melba23]

careca,

I drop multiple files on a GUI like this:

; Global Declaration
Global $aDrop_List

; React to items dropped on the GUI
Func On_WM_DROPFILES($hWnd, $iMsg, $wParam, $lParam)

    ; Credit to ProgAndy for DLL calls

    #forceref $hWnd, $iMsg, $lParam

    Local $iSize, $pFileName

    ; Get number of files dropped
    Local $aRet = DllCall("shell32.dll", "int", "DragQueryFileW", "hwnd", $wParam, "int", 0xFFFFFFFF, "ptr", 0, "int", 0)
    ; Reset array to correct size
    Global $aDrop_List[$aRet[0] + 1] = [$aRet[0]]
    ; And add item names
    For $i = 0 To $aRet[0] - 1
        $aRet = DllCall("shell32.dll", "int", "DragQueryFileW", "hwnd", $wParam, "int", $i, "ptr", 0, "int", 0)
        $iSize = $aRet[0] + 1
        $pFileName = DllStructCreate("wchar[" & $iSize & "]")
        DllCall("shell32.dll", "int", "DragQueryFileW", "hwnd", $wParam, "int", $i, "ptr", DllStructGetPtr($pFileName), "int", $iSize)
        $aDrop_List[$i + 1] = DllStructGetData($pFileName, 1)
        $pFileName = 0
    Next
    ; Send the count to trigger the drop function in the main loop
    GUICtrlSendToDummy($cDrop_Dummy, $aDrop_List[0])

EndFunc   ;==>On_WM_DROPFILES

; And $aDrop_List has a [0] count array of the files dropped

I hope it might be of use.

M23

[careca]

Thank you, appreciated.

[michaelslamet]

I'm working on a similiar script, too.

My listview is accepting multiples files click and drag great, but I also want the user can input by typing (or copy-paste) the file location & file name directly into the listview, not only accept files by click and drag, is it possible?

[guinness]

Melba's code is like mine but without WinAPIEx.

[careca]

michaelslamet: Maybe you can try to make it "read" the clipboard uppon the pressing of the ctrl+v keys..Then use that to create a listview item.

Guinness: i ended up using the code you provided, but still im glad for the alternative. Thank you.

[guinness]

I'm working on a similiar script, too.

My listview is accepting multiples files click and drag great, but I also want the user can input by typing (or copy-paste) the file location & file name directly into the listview, not only accept files by click and drag, is it possible?

Search WM_COMMAND & WM_CLIPBOARD.

Edit: Or WM_NOTIFY (I forget right now.)

Edited May 10, 2013 by guinness

[Ravenswood]

On 5/8/2013 at 2:05 AM, guinness said:

Local Const $aReturn = _WinAPI_DragQueryFileEx($wParam)

Hi. I'm new here, so I'm not sure how you feel about thread necromancy. I apologize for resurrecting an 8-year-old thread. I needed the answer to this very question and this thread was very helpful. Thank you to everyone who posted above.

I do have one question, though, kind of unrelated to the original topic: @guinness, why, in your code, do you make $aReturn a local constant? Why not just a regular local variable? I realize that the answer might simply be that your programming style is different than mine, but experience has taught me that usually if somebody does something like this it's because they know something I'm not aware of. Is there some "gotcha" lurking in the code that making this a constant avoids? Please let me know. Thank you.

[Nine]

No gotcha.  No nothing.  It is just that he felt (I suppose) that the variable will not be modified further on.  Or maybe, just to let know others that Const can be used anywhere?  Or maybe, he thought, someday someone will ask this question ?  Not important that is for sure. 

[Ravenswood]

I get it. It's a safety thing, like using "MustDeclareVars" - not really necessary for the program, but can help catch errors made by the programmer. Thanks.