GUICTRLSETDATA is not working right with many rows

[fs1234]

Hello!

Sorry for my bad english. The test .txt has approx. 3000 rows, but this script is below show me 7xx. What's wrong? Anyone can help me? Tx.

GUICreate("gui", 800, 700)
$Edit = GUICtrlCreateEdit("", 0, 0, 800, 500, )
$Button = GUICtrlCreateButton("OK", 300, 550, 200, 50)

GUISetState(@SW_SHOW)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3
Exit
Case $Button
_OK()
EndSwitch
WEnd

Func _OK()
Local $file = FileOpen(@ScriptDir & "\test.txt")
While 1
Local $line = FileReadLine($file)
If @error = -1 Then ExitLoop
GUICtrlSetData($Edit, $line & @CRLF, 1)
; MsgBox(0, "Line read:", $line)
WEnd
FileClose($file)
EndFunc

[Melba23]

fs1234,

Welcome to the AutoIt forum.

You are bumping up to the default 32k character limit of edit controls. Use _GUICtrlEdit_SetLimitText to increase the limit so you can get all your file into the control.

And it is much easier to read and load the file content in one go:

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>

GUICreate("gui", 800, 700)

$Edit = GUICtrlCreateEdit("", 0, 0, 800, 500)
_GUICtrlEdit_SetLimitText($Edit, 200000) ; Increase text limit
$Button = GUICtrlCreateButton("OK", 300, 550, 200, 50)

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE  ; Try not to use m"agic numbers"
            Exit
        Case $Button
            GUICtrlSetData($Edit, FileRead(@ScriptDir & "\test.txt")) ; Get the file text all in one go
    EndSwitch
WEnd

All clear?

M23

[fs1234]

Thanks for reply Melba! Now perfectly working.

[Melba23]

fs1234,

My pleasure.

M23

[Artisan]

Hey Melba, in your code example you say not to use "magic numbers". I agree with that, but increasing the text character limit to 200,000 looks like a magic number to me. I suggest using FileGetSize() when working with very large files to avoid a potential problem. Is that a good idea, or is that just paranoid? I'm only a hobby coder.

[AZJIO]

there are no restrictions

GUICtrlSendMsg(-1, $EM_LIMITTEXT, -1, 0)

[guinness]

Hey Melba, in your code example you say not to use "magic numbers". I agree with that, but increasing the text character limit to 200,000 looks like a magic number to me.

In this example it isn't.

[water]

A magic number is a number for which AutoIt provides a constant. Like $WS_POPUP from WindowsConstants.au3. $WS_POPUP has a value of 0x80000000. You shouldn't use 0x80000000 in your scripts but $WS_POPUP. Because the value of such a constant can be changed without notice.

[AZJIO]

He wants to:

Const $one = 1
Const $two = 2
Const $three = 3
Const $four = 4
Const $five = 5
; .....
Const $two_hundred_thousand = 200000
; .....

Named constants are not because they can change, but because the script easier to read

Edited May 10, 2013 by AZJIO

[Artisan]

A magic number is a number for which AutoIt provides a constant. Like $WS_POPUP from WindowsConstants.au3. $WS_POPUP has a value of 0x80000000. You shouldn't use 0x80000000 in your scripts but $WS_POPUP. Because the value of such a constant can be changed without notice.

Ah.  Okay, that makes sense.  I thought a magic number was a literal "placeholder" number that was just assumed to work.  Makes sense now.