Text as a button

[Queener]

I have not try because I do not know if it's possible. Even if it's possible; I wouldn't know where to start off. But if anybody know of it possible; would like a hint and I'll try to figure it out.

thanks

Edited May 14, 2013 by asianqueen

[BrewManNH]

Clear as mud that was, how about explaining what you're trying to do and what you want the results to be?

[Queener]

say I create the main form with these text:

Change computer name
 
Change computer description
 
Change computer background
 
Change computer screen savor

 

Say if I click on Change computer name, it takes me to form2. This is what I want. Instead of having a button, I want the text to act as a button to open form2.

[BrewManNH]

You can use the UDF for that if you want to get fancy. Or, you can just make the labels clickable using OnEvent mode or Message loop mode which ever your script is using. Labels are actionable just like any other control.

[kylomas]

asianqueen,

A small example of what BewmanNH has suggested using an array of your values to populate the "main form"

#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>
#include <array.au3>

#AutoIt3Wrapper_Add_Constants=n

local $aLabels[3][2] = [['Change computer name',''],['Change computer description',''],['Change computer background','']]

local $gui010 = guicreate('')

for $1 = 0 to ubound($aLabels) - 1
    $aLabels[$1][1] = guictrlcreatelabel($aLabels[$1][0],10,($1+1)*30,250,25)
    guictrlsetfont(-1,10,600,4)
    guictrlsetcolor(-1,0xaa0000)
next

guisetstate()

local $msg
while 1
    $msg = guigetmsg()
    switch $msg
        case $gui_event_close
            Exit
        case $aLabels[0][1] to $aLabels[ubound($aLabels) - 1][1]
            for $1 = 0 to ubound($aLabels) - 1
                if $msg = $aLabels[$1][1] then ConsoleWrite('Clicked on label = ' & guictrlread($aLabels[$1][1]) & @LF)
            next
    EndSwitch
WEnd

kylomas

edit: spelling ("s" key is goofy)

edit:

and just because I have not used event mode in a while, the event mode version

expandcollapse popup

#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>
#include <array.au3>

#AutoIt3Wrapper_Add_Constants=n

Opt('GUIOnEventMode', 1)

local $aLabels[3][2] = [['Change computer name',''],['Change computer description',''],['Change computer background','']]

local $gui010 = guicreate('')

GUISetOnEvent($GUI_EVENT_CLOSE, "fini")

for $1 = 0 to ubound($aLabels) - 1
    $aLabels[$1][1] = guictrlcreatelabel($aLabels[$1][0],10,($1+1)*30,250,25)
    guictrlsetfont(-1,10,600,4)
    guictrlsetcolor(-1,0xaa0000)
    guictrlsetonevent(-1,'_my_menu')
next

guisetstate()

while 1
    sleep(999999)
WEnd

func fini()
    Exit
EndFunc

func _my_menu()

    for $1 = 0 to ubound($aLabels) - 1
        if @GUI_CtrlId = $aLabels[$1][1] then ConsoleWrite($aLabels[$1][0] & ' was actioned' & @LF)
    Next

endfunc

Edited May 14, 2013 by kylomas