FileDelete or FileOpen

[millisys]

Hi,

Is it better syntax to use FileDelete or FileOpen in the following example to clear out an existing file before writing. I apologize if this question has been asked before.

FileOpen()

$report = FileOpen("report.txt",2)
FileWrite($report,"hello world")
FileClose($report)

or

FileDelete()

FileDelete("report.txt")
FileWrite("report.txt","hello world")

Thank you

[guinness]

#include <Constants.au3>

Local $hFileOpen = FileOpen('FILE', $FO_OVERWRITE)

[millisys]

Thank you Guinness,

I was not able to find $FO_OVERWRITE in the help file. Is that a forced overwrite?

Do I still need to FileClose the file after writing even though it is not part of a loop?

[guinness]

It's a constant variable (that will be in the help file in the next version) but you can find it in Constants.au3.

[millisys]

Hi Guinness,

From the FileConstants.au3 it reads

Global Const $FO_OVERWRITE  = 2 ; Write mode (erase previous contents)

Is $FO_OVERWRITE the same as using FileOpen('File',2)?

[guinness]

Yes. But if you're into learning programming you should read up on "magic numbers."

[millisys]

Hi Guinness,

Definitely, I want to get better at programming.

If all I want to do is remove a file before writing, what is the reason to use FileOpen rather than FileDelete? Is there a risk to only using FileDelete? Can I safely use either? I am asking because I have used FileDelete frequently in my scripts and wonder if I should go back and change them.

Thank you

[guinness]

It's one less call to make.

[millisys]

Guinness,

Hmm, I started using FileDelete because I thought it was more efficient by allowing me to avoid using both FileOpen and FileClose. Is that what you are saying, or are you saying that FileOpen/FileClose is more efficient? Do I have to use FileClose if I am just writing to a file?

[guinness]

Well do you intend to write to the file later? If yes, the FileOpen/FileClose if no then FIleDelete. It's up to you, you're the developer.

[millisys]

Hi Guinness,

Ok, it sounds like I kinda understand it correctly. If I am writing during a While...Wend or For...Next loop I will use FileOpen/FileClose with a handle, but if just a one-time write I will use FileDelete with a filename. Is that OK?

I read up on magic numbers. Are referring to using $FO_OVERWRITE instead of 2 because it is descriptive whereas using a 2 is not that informative?

Thank you

[JohnOne]

Pretty much yes.

Just be sure to change back to magic numbers if you post code here, just to wind guinness up, he goes proper radio like

[millisys]

Thank you so much Guinness and JohnOne for your help and excellent guidance.

[AdamUL]

One thing about using FileOpen, it keeps the original file creation date, and on FileWrite changes the modified date.  If you use FileDelete, then create a new file, it will have a new creation date.  If you are not concerned about file creation dates, then this is not a problem.  Just thought you should know.  

[guinness]

JohnOne is right, haha.

If you know this already then ignore my advice. But you do know you can have one file handle for read/write access?

expandcollapse popup

#include <Constants.au3>

Example()

Func Example()
    ; Create a constant variable in Local scope of the filepath that will be read/written to.
    Local Const $sFilePath = @ScriptDir & '\FileOpen.txt'

    ; Open the file for read/write access.
    Local $hFileOpen = FileOpen($sFilePath, $FO_READ + $FO_OVERWRITE)
    If $hFileOpen = -1 Then Return False

    ; Write some data.
    FileWrite($hFileOpen, 'This is some data to show that the handle was open with read/write access.' & @CRLF)

    ; Retrieve the current position in the file.
    Local $iFilePos = FileGetPos($hFileOpen)

    ; Adjust the position to the beginning.
    FileSetPos($hFileOpen, 0, $FILE_BEGIN)

    ; Display the contents of the file.
    MsgBox($MB_SYSTEMMODAL, '', FileRead($hFileOpen))

    ; Adjust the position back to the previous position.
    FileSetPos($hFileOpen, 0, $iFilePos)

    ; Write some addition data.
    FileWrite($hFileOpen, 'This is some additional data.')

    ; Adjust the position back to the previous position.
    FileSetPos($hFileOpen, 0, $FILE_BEGIN)

    ; Display the contents of the file.
    MsgBox($MB_SYSTEMMODAL, '', FileRead($hFileOpen))

    ; Close the handle returned by FileOpen.
    FileClose($hFileOpen)

    ; Delete the temporary file.
    FileDelete($sFilePath)

    Return True
EndFunc   ;==>Example

Edited May 23, 2013 by guinness