Mouseclick -> r

[saneman]

I made a script so that whenever I click the left mouse button, it would press "r" like 1/4 second later. When in a loop, it just presses "r" without me clicking the left mouse button... and I want it to stop the loop when I press the right mouse button.

Can anyone help? I know this should be very simple... but I'm new and couldn't find a fix.

Heres my code already:

Do

if MouseClick("Left")=True Then

sleep(250)

Send("{ASC 114}")

EndIf

Until MouseClick("Right")

Edited June 2, 2013 by saneman

[somdcomputerguy]

Try it like this

While 1
 If MouseClick("Left") Send("{ASC 114}")
 Sleep(100)
WEnd

edit: nevermind. I misread your post, and this doesn't do what you want. Edited June 2, 2013 by somdcomputerguy

[Melba23]

saneman,

This should do what you want:

expandcollapse popup

#include <Misc.au3>

; Create a way to exit
HotKeySet("{ESC}", "On_Exit")

; Open DLL for IsPressed
$hDLL = DllOpen("user32.dll")

; A flag to show whether to run the loop
$fRun = False

; Start an infinite loop - this is why we need a HotKey to escape
While 1

    ; Look for the left button being pressed
    If _IsPressed("01", $hDLL) Then
        ; Set the flag
        $fRun = True
        ; And just for this example - tell us what is happening
        ConsoleWrite("+ Starting loop" & @CRLF)
        ; And wait for the button to be released
        While _IsPressed("01", $hDLL)
            Sleep(10)
        WEnd
    EndIf

    ; Look for the right button being pressed
    If _IsPressed("02", $hDLL) Then
        ; Clear the flag
        $fRun = False
        ; And just for this example - tell us what is happening
        ConsoleWrite("! Stopping loop" & @CRLF)
        ; And wait for the button to be released
        While _IsPressed("02", $hDLL)
            Sleep(10)
        WEnd
    EndIf

    ; If th flag is set
    If $fRun Then
        ; Wait 1/4 sec
        Sleep(250)
        ; Do what you want to do
        ConsoleWrite("Sending 'r' at " & @MSEC & @CRLF)
    Else
        ; If the flag is not set then just give the CPU a breather
        Sleep(10)
    EndIf

WEnd

Func On_Exit()
    ; Close the DLL - always inportant to tidy up
    DllClose($hDLL)
    Exit
EndFunc

But please make sure you read the Forum rules (there is also a link at bottom right of each page) before you post again.

M23