StdOutRead broken or what am i doing wrong

[EndFunc]

I'm not unfamiliar to Autoit obviously but this is baffling me. Is this a bug in StdOutRead?

This is a very simple way to see the GUID of your power settings on a laptop but its not working as long as it's inside an IF conditional.

Local $foo = Run(@ComSpec & " /c powercfg -getactivescheme", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
Local $line
While 1
    $line = StdoutRead($foo)
    If @error Then ExitLoop
    If StringInStr($line, "GUID") Then
        MsgBox(0, "STDOUT read:", $line)
    EndIf
WEnd

The message should show: Power Scheme GUID: 381b4222-f694-41f0-9685-ff5bb260df2e  (Balanced)

But it's only coming back with a partial string Power Scheme GUID:

If you remove the condition IF statement and just leave the msgbox line by itself on the 2nd iteration it will show the entire string. 

Now if you do this code below, you can see it going through 2 iterations, which it should, so I use another msgbox to show that.  If you also put another msgbox line out side of that then you get 2 iterations and 3 msgboxes(in the real script I won't be using msgbox, it will be a variable.)

Local $foo = Run(@ComSpec & " /c powercfg -getactivescheme", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
Local $line
While 1
    $line = StdoutRead($foo)
    If @error Then ExitLoop
    If StringInStr($line, "GUID") Then
        MsgBox(0, "STDOUT read:", $line)
    EndIf
    MsgBox(0, "STDOUT read:", $line)
WEnd

I use the conditional so I can capture that string on the iteration that contains GUID. But it doesn't work as long as its in side the IF statement and only shows the partial string. 

Anyone have any ideas why it's acting so weird?

 

[guinness]

I will give a clue: &=.

[EndFunc]

I understand what you're saying to do, however even when I do that, for some reason if I use that conditional inside the loop, it will return part of the string in string I "Searched" for instead of the full string that was searched. So it doesn't seem to work the way I logically would expect it or like another language would handle the string. 

I'm trying to understand why AutoIt works this way. 

example:

If I want to know if a VAR contains a string I check it with a stringinstr().

However with AutoIt when I'm in the loop to capture the stdout, and I msgbox or echo the variable during each iteration, the first msgbox is empty and the 2nd returns the full string I'm looking for. Basically going line by line which is how I thought it worked and has in the past without using &= to add the var together, this example directly from the help. Which is what the below code does, so far so good. 

Local $foo = Run(@ComSpec & " /c powercfg -getactivescheme", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
Local $line

While 1
    $line = StdoutRead($foo)
    If @error Then ExitLoop
    MsgBox(0,0,$line)
WEnd

So now using the code above the msgbox showed me on the 2nd iteration the value of $line is "Power Scheme GUID: 381b4222-f694-41f0-9685-ff5bb260df2e  (Balanced)"

Great, it shows the full line. 

Ok I now want to introduce a conditional so that it will skip the first time which $line has no value in the first iteration and do this below

Func _GUID()
Local $foo = Run(@ComSpec & " /c powercfg -getactivescheme", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
Local $line
$k = 0
While 1
        $line = StdoutRead($foo)
    If @error Then ExitLoop
    If StringInStr($line, "GUID") Then
        return $line ;or msgbox the result to see value
    EndIf
WEnd
EndFunc

But then it returns the value of $line = "Power Scheme GUID:" . Whoa, what happened to the rest of the line with the actual GUID. It gets cut off. So it will return an incomplete result.

This is where I do understand why it works that way. Without the StringinStr condition, the 2nd iteration gives the full string, with the the condition it only returns a partial string on the 2nd iteration.

So then my code is broken because it will stop once it finds GUID. Just because I introduce a condition the value of $line should not change on the 2nd iteration but it does. 

Now doing as suggested using &= and adjusting my code I get the full string, but logically I don't see why the original way I tried to do it won't work.

This works below, BUT, I've never really had to use &= before reading stdout and I don't always want to. If the result is a lot of text I only what to capture the line that has the string in it, because more than likely I'm going to manipulate it. I've made plenty of scripts in the past 9 years using AutoIt and have never had to do it this way. So that is why I'm so confused. 

Func _GUID()

Local $foo = Run(@ComSpec & " /c powercfg -getactivescheme", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
Local $line

While 1
    $line &= StdoutRead($foo)
    If @error Then ExitLoop
WEnd

MsgBox(0,0, $line) ;yep full string I need is there

$line = StringStripWS($line, 8)
$G = _StringBetween($line, ":", "(")
MsgBox(0,0, $G[0])

EndFunc

So I still think something is wrong.   

Edited June 4, 2013 by EndFunc

[FireFox]

Hi,

There's nothing wrong, if the process makes a "ConsoleWrite" at different times you won't have a continuous string.

Try this :

$sToSearch = "toto"

...

While 1
$line &= StdoutRead(...
If @error Then ExitLoop

If StringInStr($line, $sToSearch, 2) > 0 Then ;you could also do a stringregexp to check if the GUID is present
;do stuff
Else
$line = "" ;reset the $line content, and work on a smaller data
EndIf
WEnd

Br, FireFox.

[EndFunc]

@FireFox, ok thanks. It's just weird because this is the first time I've ran into a problem using that before. It's always worked the way I've used it in the past. I guess I've been lucky not sure. 

[BrewManNH]

This is how I'd do it when reading StdOut.

#include <Constants.au3>
Local $foo = Run(@ComSpec & " /c powercfg -getactivescheme", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
Local $line
While ProcessExists($foo)
    Sleep(10)
WEnd
$line = StdoutRead($foo)
If StringInStr($line, "GUID") Then
    MsgBox($MB_SYSTEMMODAL, "STDOUT read:", $line)
EndIf

[guinness]

Another way (I didn't include the StringInStr)

#include <Constants.au3>

Local $iPID = Run(@ComSpec & ' /c powercfg -getactivescheme', @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
Local $sStdOut = StdoutRead(ProcessWaitClose($iPID) * $iPID)
MsgBox($MB_SYSTEMMODAL, '', $sStdOut)

BrewManNH,

You made me a happy person today when I saw $MB_SYSTEMMODAL and not 4096.

[BrewManNH]

 

BrewManNH,

 

You made me a happy person today when I saw $MB_SYSTEMMODAL and not 4096.

I'm reforming, slowly but surely. 

[FireFox]

You made me a happy person today when I saw $MB_SYSTEMMODAL and not 4096.

And you would be happier if you knew that I stopped to use magic numbers.

I'm now familiar with the "Constants" include

[guinness]

And you would be happier if you knew that I stopped to use magic numbers.

I'm now familiar with the "Constants" include

Ecstatic, is what I would be.

[EndFunc]

This is how I'd do it when reading StdOut.

 

#include <Constants.au3>
Local $foo = Run(@ComSpec & " /c powercfg -getactivescheme", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
Local $line
While ProcessExists($foo)
    Sleep(10)
WEnd
$line = StdoutRead($foo)
If StringInStr($line, "GUID") Then
    MsgBox($MB_SYSTEMMODAL, "STDOUT read:", $line)
EndIf

Hmm, now this works as I would think it should putting the extra loop. That's a cool trick to use. 

[BrewManNH]

Unless you need to read the output from the program in real time, then reading it after it has closed is usually much easier to code.

[guinness]

expandcollapse popup

#include <Array.au3> ; Required for _ArrayDisplay only.
#include <Constants.au3>

; Recursively display a list of files in a directory.
Example()

Func Example()
    Local $sFilePath = @ScriptDir ; Search the current script directory.
    Local $sFilter = "*.*" ; Search for all files in the current directory. For a list of valid wildcards, search for 'Wildcards' in the Help file.

    ; If the file path isn't a directory then return from the 'Example' function.
    If Not StringInStr(FileGetAttrib($sFilePath), "D") Then
        Return SetError(1, 0, 0)
    EndIf

    ; Remove trailing backslashes and append a single trailing backslash.
    $sFilePath = StringRegExpReplace($sFilePath, "[\\/]+\z", "") & "\"

    #cs
        Commandline parameters for DIR:
        /B - Simple output.
        /A-D - Search for all files, minus folders.
        /S - Search within subfolders.
    #ce
    Local $iPID = Run(@ComSpec & ' /C DIR "' & $sFilePath & $sFilter & '" /B /A-D /S', $sFilePath, @SW_HIDE, $STDOUT_CHILD)
    ; If you want to search with files that contains unicode characters, then use the /U commandline parameter.

    ; Wait until the process has closed using the PID returned by Run.
    ProcessWaitClose($iPID)

    ; Read the Stdout stream of the PID returned by Run. This can also be done in a while loop. Look at the example for StderrRead.
    Local $sOutput = StdoutRead($iPID)

    ; Use StringSplit to split the output of StdoutRead to an array. All carriage returns (@CR) are stripped and @LF (line feed) is used as the delimiter.
    Local $aArray = StringSplit(StringTrimRight(StringStripCR($sOutput), StringLen(@LF)), @LF)
    If @error Then
        MsgBox($MB_SYSTEMMODAL, "", "It appears there was an error trying to find all the files in the current script directory.")
    Else
        ; Display the results.
        _ArrayDisplay($aArray)
    EndIf
EndFunc   ;==>Example

In the current beta version of the help file this little "trick" is documented.

 

[EndFunc]

Unless you need to read the output from the program in real time, then reading it after it has closed is usually much easier to code.

 

Never really thought to try it that way. Usually just works. Cool good to know.