Do... untill expression

[nazirequbal786]

how to write the below expression in such a way that untill the notepad.exe exist getting the message box in regular interval

 

 Run("notepad.exe")

Do


MsgBox(0, "Datadriv at end of the file ", $datadrive)

sleep(1000)

Until ProcessExists("notepad.exe") <> '0'
 

Kindy suggest

[guinness]

#include <Constants.au3>

Local $iPID = Run('notepad.exe')
Do
    MsgBox($MB_SYSTEMMODAL, '', 'Notepad has not started.')
    Sleep(100)
Until ProcessExists($iPID) > 0

The PID is created right away so the message box will show only once. Maybe you want to look for the window handle instead. What is your idea?

 

Edited June 18, 2013 by guinness

[JLogan3o13]

You could do it in a While statement:

While Not ProcessExists("Notepad.exe")
    MsgBox(0, "", "Notepad not open", 10)
    Sleep(1000)
WEnd

Or if you want to stick with Do:

Do
    MsgBox(0, "", "Notepad not open", 10)
    Sleep(1000)
Until ProcessExists("Notepad.exe")

[nazirequbal786]

actually i dont want to pause the excution, want to excute the message box untill the process exist.

[guinness]

But the process is created right away, so why do you want to monitor a process or PID? As I said maybe a window handle would be a better choice. What is your overall intention?

[jdelaney]

Do
    Run(@AutoItExe & ' /AutoIt3ExecuteLine  "MsgBox(0, ''No notepad!'', ''No notepad!'', ''5'')"')
    Sleep(1000)
Until ProcessExists("Notepad.exe")

[nazirequbal786]

i want to lauch the exe and while exe is running i want to handle every possible popup (error popup).

i am planing to handle errors inside do .. untill loop.

[guinness]

What errors could arise with Notepad?

[nazirequbal786]

notepad is just the example

[guinness]

While ProcessExists($iPID) * Sleep(250)
; Add error checking.
WEnd

I would do it like that. So your question has been answered as far as I'm concerned.

[nazirequbal786]

i want to achive exactly opposite to this script suggested by jlogan3o13

 

1. Do
2.     MsgBox(0, "", "Notepad not open", 10)
3.     Sleep(1000)
4. Until ProcessExists("Notepad.exe")

[jdelaney]

This will get the parent window, as well as the popups:

#include <WinAPI.au3>

$application = "notepad.exe c:\noththere.txt"
$iMaxWait = 20 * 1000
$iTimer = TimerInit()
$iPid = Run($application)
While TimerDiff($iTimer) < $iMaxWait
    $data = WinList()
    For $i = 1 To UBound($data) - 1
        $tempPID = ""
        _WinAPI_GetWindowThreadProcessId($data[$i][1], $tempPID)
        If $tempPID<>$iPid Then ContinueLoop
        $handle = $data[$i][1]
        $hParent = _WinAPI_GetWindow($handle,4)
        If $hParent = 0 Then
            $hParent = $handle
        EndIf
        ConsoleWrite("Found Parent window=[" & $hParent & "]" & @CRLF)
        ExitLoop 2
    Next
    Sleep(50)
WEnd
Sleep(2000)
While TimerDiff($iTimer) < $iMaxWait
    $hPopup = _WinAPI_GetWindow($hParent,6)
    If $hPopup > 0 Then
        ConsoleWrite("popup exists:" & WinGetTitle($hPopup) & @CRLF)
        MsgBox(1,1,"found popup")
    Else
        ExitLoop
    EndIf
WEnd

Edited June 18, 2013 by jdelaney

[guinness]

 

i want to achive exactly opposite to this script suggested by jlogan3o13

 

1. Do
2.     MsgBox(0, "", "Notepad not open", 10)
3.     Sleep(1000)
4. Until ProcessExists("Notepad.exe")

 

The opposite of that is waiting until the process closes.

[JLogan3o13]

You stated in your OP that you wanted the messagebox UNTIL notepad was present. Now you want the opposite? You're not being very clear.

[nazirequbal786]

yes i think this script can solve my problem.

While ProcessExists($iPID) * Sleep(250)

; Add error checking.

WEnd

 

 

Thank you very much all for your reply, i will get back if still unable to solve my problem

[guinness]

That's literally the same concept as JLogan3o13 posted and use autoit tags (blue button) when posting AutoIt code. Thanks.

[nazirequbal786]

Sorry if i am not clear to you, as i am new to this scripting type of things.

[guinness]

Try to work small first and then continue from there.

[jdelaney]

This one is better...if there is a popup, the primary window will NOT be in state = 4 (enabled)

#include <WinAPI.au3>

$application = "notepad.exe c:\noththere.txt"
$iMaxWait = 20 * 1000
$iTimer = TimerInit()
$iPid = Run($application)
While TimerDiff($iTimer) < $iMaxWait
    $data = WinList()
    For $i = 1 To UBound($data) - 1
        $tempPID = ""
        _WinAPI_GetWindowThreadProcessId($data[$i][1], $tempPID)
        If $tempPID<>$iPid Then ContinueLoop
        $handle = $data[$i][1]
        $hParent = _WinAPI_GetWindow($handle,4)
        If $hParent = 0 Then
            $hParent = $handle
        EndIf
        $iState = WinGetState($hParent)
        ConsoleWrite("Found Parent window=[" & $hParent & "] with state=[" & $iState & "]" & @CRLF)
        ExitLoop 2
    Next
    Sleep(50)
WEnd
While Not BitAND (WinGetState($hParent), 4)
    $hPopup = _WinAPI_GetWindow($hParent,6)
    If $hPopup > 0 Then
        ConsoleWrite("popup exists:" & WinGetTitle($hPopup) & " " & WinGetText($hPopup) & @CRLF)
        ; Add actions to fulfill popups
    Else
        ExitLoop
    EndIf
    Sleep (500)
WEnd

Edited June 18, 2013 by jdelaney