Ejecting USB Drive

[Cav3man]

I'm working on a script that will eject a usb flash drive.  I did a search on google and the forums and I found a script that people seem to be using for this purpose.  However when I try to us it, the script runs but it doesn't eject the usb flash drive

Here is the script exactly as I am trying to test it

expandcollapse popup

#include <Process.au3>

$DriveLabel = "BACKUP" ; your drive label here

$aDrives = DriveGetDrive("all") ; USB external hard drives report as "Fixed", not "Removable", so use "All" to cover both kinds

If NOT @error Then
    For $i = 1 to $aDrives[0]
        If DriveGetLabel($aDrives[$i]) = $DriveLabel Then
            Local $dstatus = DriveStatus($aDrives[$i])
            MsgBox(0, "1", "Found Drive, it's status is: " & $dstatus)
            If DriveStatus($aDrives[$i]) = "READY" Then
                _RunDos("sync.exe -r "&$aDrives[$i]) ; Flush drive cache
                Sleep(2000)
                EjectDrive($aDrives[$i] & "\")
            EndIf
            Exit
        EndIf
    Next
EndIf

Exit

Func EjectDrive($dLetter) ; From VB script, Authors XoLoX and ChrisL
Local CONST $SSF_DRIVES = 17
Local $oShell, $oNameSpace, $oDrive, $strDrive
$strDrive = $dLetter
$strName=DriveGetLabel($strDrive) & "(" & $strDrive & ")"
$oShell = ObjCreate("Shell.Application")
$oNamespace = $oShell.NameSpace($SSF_DRIVES)
$oDrive = $oNamespace.ParseName($strDrive)
$oDrive.InvokeVerb ("E&ject")
MsgBox(0, "2", "We're here in the function")
If DriveGetLabel($aDrives[$i]) <> $DriveLabel Or DriveGetLabel($aDrives[$i]) = "Removeable Disk" Then
    MsgBox(0, "3", "We're here in the if statement")
    TrayTip("USB Drive "&$strName&" ejected", "You can now remove the device safely.", 5, 1)
    MsgBox(0,"", $strName & " drive ejected. You can now remove the device safely.",5)
EndIf
Endfunc

It's pretty much the exact script found in numerous posts here on the fourm.  I only modified the drive label and added some message boxes to see where in the script the problem was.

the script runs fine up until the "if" statement in function EjectDrive().  If I understand the script, that if statement determines if the drive has actually been ejected.  If it has then it send the message that it's save to remove the device.

When I run the script is does not actually eject the drive so I'm sure that's why the code in the if statement isn't executed.

The Question: What do I need to do to get the script to actually eject the flash drive.

P.S. I'm using windows 7 32-bit if it makes a difference.

[BrewManNH]

Try this modification, there were numerous things wrong with what you posted.
 

#include <Process.au3>

$DriveLabel = "usbdrive" ; your drive label here

$aDrives = DriveGetDrive("all") ; USB external hard drives report as "Fixed", not "Removable", so use "All" to cover both kinds

If Not @error Then
    For $i = 1 To $aDrives[0]
        If DriveGetLabel($aDrives[$i]) = $DriveLabel Then
            Local $dstatus = DriveStatus($aDrives[$i])
            MsgBox(0, "1", "Found Drive, it's status is: " & $dstatus)
            If DriveStatus($aDrives[$i]) = "READY" Then
                _RunDos("sync.exe -r " & $aDrives[$i]) ; Flush drive cache
                Sleep(2000)
                EjectDrive($aDrives[$i] & "\")
            EndIf
            Exit
        EndIf
    Next
EndIf

Exit

Func EjectDrive($dLetter) ; From VB script, Authors XoLoX and ChrisL
    Local Const $SSF_DRIVES = 17
    Local $oShell, $oNameSpace, $oDrive, $strDrive
    $strDrive = $dLetter
    $strName = DriveGetLabel($strDrive) & "(" & $strDrive & ")"
    $oShell = ObjCreate("Shell.Application")
    $oNameSpace = $oShell.NameSpace($SSF_DRIVES)
    $oDrive = $oNameSpace.ParseName($strDrive)
    $oDrive.InvokeVerb("Eject")
    MsgBox(0, "2", "We're here in the function")
    TrayTip("USB Drive " & $strName & " ejected", "You can now remove the device safely.", 5, 1)
    MsgBox(0, "", $strName & " drive ejected. You can now remove the device safely.", 5)
EndFunc   ;==>EjectDrive

[Cav3man]

Thanks for the quick reply.  I looked over the modifications that you made.  I see in the script that I posted, line 32 has an "&" in the middle of the work "Eject".  I don't know why it was there but removing it allowed the script to work in windows 7.  I then tested the script in window xp... and it isn't ejecting the drive .  Does Windows XP require some other method of ejecting a usb flash drive?

[BrewManNH]

Try putting the & back in and testing it on XP. I ran this on Windows 7 and it wouldn't work with the & but works fine without it. Although all the examples I've found doing a search uses the & in the eject command string, it won't work on 7 with it.

[Cav3man]

You are correct.

I just did as you suggested and put the "&" back in and it works in Windows XP.  Without the "&" it works in Windows 7.

So, I 'll need to put in some sort of a check for the OS version so script know's which command to execute.  Once I get that lined out and tested I'll post the final version here for others that may have the same problem.

Thanks again BrewManNH for the help.

[BrewManNH]

Look at @OSVersion to determine which OS your script is running on and something like this would suffice for the change needed.

Local $sEject = "E&ject")
If @OSVersion <> "WIN_XP" Then $sEject = "Eject"
; then change the following line to use the above variable.
$oDrive.InvokeVerb($sEject)

That should work, but untested.

[Cav3man]

I tried what you posted and the script wasn't sending the message that it was ok to remove the drive.  So, i changed up the if statement where it checks the os version and still had the same problem.  But then i added a sleep statement and it worked.  Appearantly it takes the OS a second to register the drive as ejected.

Here is the code that I ended up with:

expandcollapse popup

#include <Process.au3>

$DriveLabel = "SOMELABEL" ; your drive label here

$aDrives = DriveGetDrive("all") ; USB external hard drives report as "Fixed", not "Removable", so use "All" to cover both kinds

If NOT @error Then
    For $i = 1 to $aDrives[0]
        If DriveGetLabel($aDrives[$i]) = $DriveLabel Then
            Local $dstatus = DriveStatus($aDrives[$i])
            If DriveStatus($aDrives[$i]) = "READY" Then
                _RunDos("sync.exe -r "&$aDrives[$i]) ; Flush drive cache
                Sleep(2000)
                EjectDrive($aDrives[$i] & "\")
            EndIf
            Exit
        EndIf
    Next
EndIf

Exit

Func EjectDrive($dLetter) ; From VB script, Authors XoLoX and ChrisL
Local CONST $SSF_DRIVES = 17
Local $oShell, $oNameSpace, $oDrive, $strDrive
$strDrive = $dLetter
$strName=DriveGetLabel($strDrive) & "(" & $strDrive & ")"
$oShell = ObjCreate("Shell.Application")
$oNamespace = $oShell.NameSpace($SSF_DRIVES)
$oDrive = $oNamespace.ParseName($strDrive)

If @OSVersion = "WIN_XP" Then
    $oDrive.InvokeVerb ("E&ject")
Else
    $oDrive.InvokeVerb ("Eject")
EndIf
Sleep(2000)

If DriveGetLabel($aDrives[$i]) <> $DriveLabel Or DriveGetLabel($aDrives[$i]) = "Removeable Disk" Then
    TrayTip("USB Drive "&$strName&" ejected", "You can now remove the device safely.", 5, 1)
    MsgBox(0,"", $strName & " drive ejected. You can now remove the device safely.",5)
EndIf
Endfunc

I tested this on Win_XP SP3 32-bit, Win Vista 64-bit and Win 7 32-bit.

The shorter version that you posted would have probably done the trick if I had thought to put the sleep statement in there.

[BrewManNH]

Func EjectDrive($strDrive) ; From VB script, Authors XoLoX and ChrisL
    Local Const $SSF_DRIVES = 17
    Local $oShell, $oNameSpace, $oDrive
    Local $strName = DriveGetLabel($strDrive) & "(" & $strDrive & ")"
    $oShell = ObjCreate("Shell.Application")
    $oNameSpace = $oShell.NameSpace($SSF_DRIVES)
    $oDrive = $oNameSpace.ParseName($strDrive)
    Local $sEject = "E&ject"
    If @OSVersion <> "WIN_XP" Then $sEject = "Eject"
    $oDrive.InvokeVerb($sEject)
    MsgBox(0, "2", "We're here in the function")
    TrayTip("USB Drive " & $strName & " ejected", "You can now remove the device safely.", 5, 1)
    MsgBox(0, "", $strName & " drive ejected. You can now remove the device safely.", 5)
EndFunc   ;==>EjectDrive

 

I tried it and didn't need a sleep in there, there shouldn't be any reason to use a sleep for this change.

 

You also don't need the If statement in the original function. You're sending it (the function) a drive letter that your script has already determined is the correct drive letter by checking the drive label. There's no need to check to see if it's the right one twice. You'll notice in the rewrite I did, it's using the $strDrive parameter in the function header instead of any global variables. 

[BrewManNH]

 

There are a few things I feel the need to point out here.

1. Sync.exe has an eject parameter so the drive can be ejected after it's flushed instead of using another function.

I wasn't focusing on the whole sync.exe part, as it's not even on Windows 7 and was irrelevant to the problem. I don't know what Sync.exe does or what parameters it uses.

2. _RunDos and Sleep should be replaced with RunWait. This is irrelevant if sync.exe is used to eject the drive.

_RunDos and RunWait are the same thing, it's just that RunDos is a wrapper for RunWait to make it easier to use for beginners.

3. These methods are the same as right clicking the drive and selecting "Eject" but neither method is the same as using the Safely Remove Hardware dialog. I'm unsure what implications this has if any.

On Windows 7, ejecting the drive with right clicking the drive and selecting Eject and right clicking the USB icon in the system tray and selecting Eject work similarly, except that you still have a drive letter assigned for the drive "ejected" after using Eject on the drive where you don't have that on the other method. You still get the message that it's safe to remove the drive after running this script.

[guinness]

Sync basically flushes all file data to the disk, it's a SysInternals application.

I have some previous knowledge of creating such a tool.