How to go into other tab in GUI

[Prashantk]

Hello,

I am preparing script to automate some windows based GUI functionality.

Having below query:

There are multiple tabs in GUI main page like ‘Information’, ‘Additional Info’, ‘Address’ etc., how to go into other tab of GUI like from ‘Information’ to ‘Additional Info’ and so on using AutoIT script.

Please give me information / support about how I can go forward.

Thanks.

GUI_TABS.bmp

[mLipok]

_GUICtrlTab_ClickTab($hTAB, _GUICtrlTab_FindTab($hTAB, 'Addresses'))

[water]

Is this a GUI you created yourself in an AutoIt script or do you want to automate another application?

[Prashantk]

I want to Automate this GUI

[water]

If it is your own GUI then use something like this;

GUICtrlSetState($hTab1, $GUI_Show)

[Prashantk]

Thanks mlipok,

I have tried with this

_GUICtrlTab_ClickTab($hTAB, _GUICtrlTab_FindTab($hTAB, 'Addresses'))

Not getting any error on running script but not able to go on 'Addresses'

Any Clue ?

[water]

This script shows how to jump back to tab1 when you press button "Tab1":

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
Global $iMsg
Global $hGUI = GUICreate("Test", 625, 448, 192, 124)
Global $hTab = GUICtrlCreateTab(8, 8, 609, 400, BitOR($GUI_SS_DEFAULT_TAB, $TCS_MULTILINE))
Global $hT0 = GUICtrlCreateTabItem("General")
Global $hT1 = GUICtrlCreateTabItem("Create Computer")
Global $hT2 = GUICtrlCreateTabItem("Join Computer")
GUICtrlCreateTabItem("")
Global $hButton_Tab1 = GUICtrlCreateButton("Tab1", 8, 416, 97, 25)
Global $hButton_Exit = GUICtrlCreateButton("Exit", 517, 415, 97, 25)
GUISetState(@SW_SHOW)
While 1
    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE, $hButton_Exit
            Exit
        Case $hButton_Tab1
            GUICtrlSetState($hT0, $GUI_Show)
    EndSwitch
WEnd

[mLipok]

try this 
compile to EXE script posted by water  (post #7)

run that exe

and after that

run my script

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
 
WinActivate('Test','Tab1')
sleep(1000)
$hTab = ControlGetHandle('Test','Tab1','[CLASS:SysTabControl32; INSTANCE:1]')
_GUICtrlTab_ClickTab($hTAB, _GUICtrlTab_FindTab($hTAB, 'Join Computer'))
sleep(1000)
_GUICtrlTab_ClickTab($hTAB, _GUICtrlTab_FindTab($hTAB, 'General'))
 

Edited June 25, 2013 by mlipok