HotKeySet using same button to call out 2 different functions

[donhorn20]

I currently have two functions, each being called out by a hotkeyset. In this case it is F4 calling out function1() and F6 calling out function2(). I would like to make it where if I press F4 two times it will execute function1(). If I press it three times it will execute function2(). If there is any other key stroke made then it will reset the count. This way I can then use F6 for something else. Is something like this even possible?

[Blue_Drache]

I currently have two functions, each being called out by a hotkeyset. In this case it is F4 calling out function1() and F6 calling out function2(). I would like to make it where if I press F4 two times it will execute function1(). If I press it three times it will execute function2(). If there is any other key stroke made then it will reset the count. This way I can then use F6 for something else. Is something like this even possible?

 

You're asking for, in essence, a keylogger. 

[donhorn20]

You're asking for, in essence, a keylogger. 

 

Are hotkeys not ok? We have samples all over the forum where functions are being called out by hotkeys. I am just looking to see if there is a way to consolidate my two hotkeys into 1. If so how would I go about doing it? Otherwise I will live with what I have and keep it one function per hotkey.

[Melba23]

donhorn20,

I do not see this as any form of keylogger at all - all it uses are HotKeys.

I would do something like this:

expandcollapse popup

Global $iFlag = 0

HotKeySet("q", "_Function")
HotKeySet("{ESC}", "On_Exit")

While 1
    Sleep(10)
WEnd

Func _Function()

    If $iFlag Then
        ; Increase flag count
        $iFlag += 1
        ConsoleWrite("Flag = " & $iFlag & @CRLF)
    Else
        ; Set Check function to run in 500ms
        AdlibRegister("_Checker", 1000) ; Adjust the time to suit <<<<<<<<<<
        ConsoleWrite("Timer Started" & @CRLF)
        ; Set flag
        $iFlag = 1
        ConsoleWrite("Flag = " & $iFlag & @CRLF)
    EndIf

EndFunc

Func _Checker()

    ; How many presses?
    Switch $iFlag
        Case 2
            ConsoleWrite("Running Func_2" & @CRLF)
            ;_Function_2()
        Case 3
            ConsoleWrite("Running Func_3" & @CRLF)
            ;_Function_3()
    EndSwitch
    ; Prevent Check function running again
    AdlibUnRegister("_Checker")
    ; Clear flag
    $iFlag = 0
    ConsoleWrite("Timer and flag reset" & @CRLF)

EndFunc

Func On_Exit()
    Exit
EndFunc

All clear?

M23

[donhorn20]

donhorn20,

I do not see this as any form of keylogger at all - all it uses are HotKeys.

I would do something like this:

expandcollapse popup

Global $iFlag = 0

HotKeySet("q", "_Function")
HotKeySet("{ESC}", "On_Exit")

While 1
    Sleep(10)
WEnd

Func _Function()

    If $iFlag Then
        ; Increase flag count
        $iFlag += 1
        ConsoleWrite("Flag = " & $iFlag & @CRLF)
    Else
        ; Set Check function to run in 500ms
        AdlibRegister("_Checker", 1000) ; Adjust the time to suit <<<<<<<<<<
        ConsoleWrite("Timer Started" & @CRLF)
        ; Set flag
        $iFlag = 1
        ConsoleWrite("Flag = " & $iFlag & @CRLF)
    EndIf

EndFunc

Func _Checker()

    ; How many presses?
    Switch $iFlag
        Case 2
            ConsoleWrite("Running Func_2" & @CRLF)
            ;_Function_2()
        Case 3
            ConsoleWrite("Running Func_3" & @CRLF)
            ;_Function_3()
    EndSwitch
    ; Prevent Check function running again
    AdlibUnRegister("_Checker")
    ; Clear flag
    $iFlag = 0
    ConsoleWrite("Timer and flag reset" & @CRLF)

EndFunc

Func On_Exit()
    Exit
EndFunc

All clear?

M23

 

@ Melba23, this works great and is exactly what I was looking for. If I add a "Case 1" I could have the Function key perform it's default function correct? I understand I would have to define it but it is possible is it not? Thanks for the useful template. It works great.

Don

[Melba23]

donhorn20,

You will probably have to disable the HotKeySet for the key, Send it, and then reenable the HotKeySet to get it to work - otherwise you just fire the HotKey again.

Give it a try and let me now how you get on.

M23