Jump to content

Trigger buttonclick from another buttonclick


Go to solution Solved by Melba23,

Recommended Posts

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form2 = GUICreate("Form2", 405, 294, 302, 218)
$Button1 = GUICtrlCreateButton("Button1", 64, 72, 75, 25)
$Button2 = GUICtrlCreateButton("Button2", 208, 72, 75, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
         Case $Button1
            MsgBox(0,"1","Button 1 clicked")
;~          GUICtrlSendMsg
;~          $nMsg=$Button2
         Case $Button2
            MsgBox(0,"2","Button 2 clicked")

    EndSwitch
WEnd

How can i trigger Button2 click from Button1 click ?

Link to post
Share on other sites
  • Moderators
  • Solution

dragonlord,

Easy: ;)

#include <GUIConstantsEx.au3>

$Form2 = GUICreate("Form2", 405, 294, 302, 218)
$Button1 = GUICtrlCreateButton("Button1", 64, 72, 75, 25)
$Button2 = GUICtrlCreateButton("Button2", 208, 72, 75, 25)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
         Case $Button1
            MsgBox(0,"1","Button 1 clicked")
            ContinueCase ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
         Case $Button2
            MsgBox(0,"2","Button 2 clicked")

    EndSwitch
WEnd

All clear? :)

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to post
Share on other sites
  • Moderators

dragonlord,

If you cannot structure the Switch so that you get all the Cases in a suitable order then you can do something like this: ;)

#include <GUIConstantsEx.au3>

$Form2 = GUICreate("Form2", 500, 500)
$Button1 = GUICtrlCreateButton("Button 1", 50, 75, 75, 25)
$Button2 = GUICtrlCreateButton("Button 2", 150, 75, 75, 25)
$Button3 = GUICtrlCreateButton("Button 3", 250, 75, 75, 25)

$cDummy_3 = GUICtrlCreateDummy() ; Create a dummy control <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            MsgBox(0, "1", "Button 1 clicked")
            GUICtrlSendToDummy($cDummy_3) ; Fire the dummy <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        Case $Button2
            MsgBox(0, "2", "Button 2 clicked")
        Case $Button3, $cDummy_3 ; Add the dummy to the list of firing controls for this Case <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
            MsgBox(0, "3", "Button 3 clicked")
    EndSwitch
WEnd

All clear? :)

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
  • Recently Browsing   0 members

    No registered users viewing this page.

×
×
  • Create New...