Special Char

[MyEarth]

I want to check if a string has special char ( all the special char like .+*@ etc., i want only numbers and letters and nothing else ) so i have try with StringInString but seems not work

$string = "fdaafsdfsafa@"
$a = StringInStr($string, '!"£$%/\(|)=?^ìè+òàù,.-é*ç°§;:_@#')
ConsoleWrite($a)

I don't want to replace it, but give an error if found a special char in the string

Thanks

[M4n0x]

Hi,

Try with StringRegEx

like this :

$sStr = "test@"
$result = StringRegExp($sStr, "[@éèà]")
MsgBox(0, "Result", $result)

take a look here :

http://www.autoitscript.com/autoit3/docs/functions/StringRegExp.htm

Edited July 4, 2013 by M4n0x

[jchd]

It might be even easier to specify what character range are allowable in the regexp.

[MyEarth]

Pratically in StringRegEx i need to use the: 

[\W]

For matching any special char? I'd like to have only letters and numbers in my string, or maybe i can do the opposite and search for digit and letters?

Edited July 4, 2013 by MyEarth

[M4n0x]

@jchd,

Un français ! La communauté francophone est bien présente, ça fait plaisir

perhaps, somethings like this :

$sStr = "fdaafsdfsaf@a"
$iResult = StringRegExp($sStr, "^(?-i)[a-z\s0-9]*$")

if $iResult Then
    Msgbox(0,"","Value OK")
Else
    Msgbox(0,"","Value KO")
EndIf

Edited July 4, 2013 by M4n0x

[orbs]

"i want only numbers and letters and nothing else" - StringIsAlNum() should do it.

[Malkey]

Apparently, the regexp matching character "W" and the 'StringIsAlNum' function both allow the underscore character "_" in their list of alphanumeric characters.

@ M4n0x
"(?-i)" is the default and therefore an unnecessary case-sensitivity flag.  So your example is calling the capital A to Z letters unwanted special characters.
You probably meant to use "(?i)" for case-insensitivity.


This example below is labelling all non-letters (upper and lower case) and non-numbers as unwanted special characters.
Other unwanted special characters include the underscore, horizontal and vertical whitespace characters, and a decimal point or fullstop.

Local $string = "fBa0a1fAsd_fs2a"
If StringRegExp($string, '[^a-zA-Z0-9]') Then
    MsgBox(0, "Results", "String has a special character", 3)
Else
    MsgBox(0, "Results", "String does not have any special characters present.", 3)
EndIf

[jchd]

M4n0X,

There are even more French users on the French forum!

[M4n0x]

@Malkey,

apologize !

i would meant "(?i)" for insensitive case as you say.

so, corrected here, thanks

$sStr = "fdaafsdfk#safa"
$iResult = StringRegExp($sStr, "^(?i)[a-z0-9]*$")
if $iResult Then
Msgbox(0,"","Value OK")
Else
    Msgbox(0,"","Value KO")
EndIf

[Mat]

 

@Malkey,

apologize !

i would meant "(?i)" for insensitive case as you say.

so, corrected here, thanks

$sStr = "fdaafsdfk#safa"
$iResult = StringRegExp($sStr, "^(?i)[a-z0-9]*$")
if $iResult Then
Msgbox(0,"","Value OK")
Else
    Msgbox(0,"","Value KO")
EndIf

Or Just:

$sStr = "fdaafsdfk#safa"
$iResult = StringRegExp($sStr, "^[A-z0-9]*$")
if $iResult Then
Msgbox(0,"","Value OK")
Else
    Msgbox(0,"","Value KO")
EndIf

[MyEarth]

I'm confused, which one i need to use?

For what i have understand:

^[A-z] is equal to [^a-zA-Z]

Match any "word" character, lower or upper. Right?

But what does mean:

*$

I can't see nothing in the help about the dollar simbol

Edited July 4, 2013 by MyEarth

[Mat]

I'm confused, which one i need to use?

For what i have understand:

^[A-z] is equal to [^a-zA-Z]

Match any "word" character, lower or upper. Right?

But what does mean:

*$

I can't see nothing in the help about the dollar simbol

No, outside of [], ^ matches the start of the string. Word characters are A-z 0-9 and underscore

Basically you are matching the start of the string (^), followed by zero or more (that's what the star does) alphanumeric characters ([A-z0-9], followed by the end of the string ($).

 

This can only match if all the characters in the string are alphanumeric characters.

Edited July 4, 2013 by Mat

[MyEarth]

Ok, understood. I'll check better the helpfile, for now i think i'll use the Malkey's script, i don't want to allow the underscore in the string

Strange the point is a special char but the underscore not

[jchd]

Beware: [A-z] includes [ ] ^ _ ` which are not wanted IFUC.

[orbs]

underscore is not alpha-numeric and will make StringIsAlNum("_") return 0. try it.

[M4n0x]

underscore is not alpha-numeric and will make StringIsAlNum("_") return 0. try it.

Correct, but if you try with special characters as "éèéàöüä" it doesn't work.

[orbs]

Correct, but if you try with special characters as "éèéàöüä" it doesn't work.

 

these are alpha-numeric, although not in English. i doubt that the original intention of the requester is to exclude non-English strings.

[MyEarth]

Maybe i wasn't clear. I want a string with:

0123456789

abcdefghijklmnopqrstuvwxyz

ABCDEFGHIJKLMNOPQRSTUVWXYZ

I want to avoid any special character and non printable character. I'm usign the Malkey's script and check the help of StringRegEx

Edited July 4, 2013 by MyEarth

[AZJIO]

To do case insensitive

'?do=embed' frameborder='0' data-embedContent>>

Edited July 4, 2013 by AZJIO

[Malkey]

Here is a script to test all characters individually to see if they are special characters or not.

; Testing the StringIsAlNum() function
; A returns of "1" means all the characters in string being tested are only alphanumeric characters.
; A returns of "0" means a non-alphanumeric character is in the string being tested.
ConsoleWrite("éèéàöüä  returns " & StringIsAlNum("éèéàöüä") & @LF) ; returns 1
; Note: The underscore character is not an alphanumeric character, contrary to what I said in Post #7.

ConsoleWrite("---- StringIsAlNum() ----" & @LF)
For $i = 0 To 255
    ConsoleWrite(">" & $i & " = " & @TAB & "0x" & Hex($i, 2) & " " & ChrW($i) & @TAB & StringIsAlNum(ChrW($i)) & @LF)
Next

ConsoleWrite(@LF & "---- StringRegExp($string, '[^a-zA-Z0-9]') ----" & @LF) ; From post #7
For $i = 0 To 255
    ConsoleWrite(">" & $i & "  " & ChrW($i) & @TAB & StringRegExp(ChrW($i), '[^a-zA-Z0-9]') & @TAB & _ ; Returns "0" (False) if tested character is a-z, A-Z, or 0-9
            (StringRegExp(ChrW($i), '[^a-zA-Z0-9]') = 0) & @LF) ; <------------------------------------  Returns "True"      if tested character is a-z, A-Z, or 0-9
Next

Hopefully you are using SciTE to run this script, as ConsoleWrite() displays in the lower output panel of the SciTE window.

Edit: Added Note about StringIsAlNum() in script example.

Edited July 5, 2013 by Malkey