Need comparison help....Versions

[hogfan]

I am trying to find the best way to go about a version comparison.  I am not wanting to compare file versions or anything like that.  I need to do a comparsion on what information is in a variable.

It's for a script version tool I'm maintaining.

The current version is say 5.2.1.

I need to find a good way of future proofing this with a check.  I need to perform one action if the script version is less than 5.2.1, but if it is 5.2.1 or anything newer, I need to perform a different action.

So I am thinking I am going to have to do some kind of recursive check after splitting the script version at the "."s.  

For example, a future script version could be 5.2.5 or 7.5.4.

So I guess I could use a stringsplit function and check the first # to see if it is great than 5 and then check the second # to see if it is greater than 2., etc.

Any suggestions on the most efficient way to go about this?

-hogfan

[guinness]

_VersionCompare. Search the help file.

[iamtheky]

if they are all like strings, normal evaluation seems to also be fine

_CheckVer("7.5.4")
_CheckVer("5.2.1")
_CheckVer("5.2.0")

Func _CheckVer($ver)
    If $ver > "5.2.1" Then
        msgbox (0, '' , "newer then 5.2.1")
    Else
        msgbox(0, '' , "5.2.1 or older")
    Endif
Endfunc

[guinness]

I wouldn't recommend it just in case.

[hogfan]

They will all be strings, because I'm not using FileGetVersion to read the file version.  These different script versions will be manually added to a configuration file one of my combo boxes is populated from.  Then the user will pick the version from there.  So the _VersionCompare function will still work fine, even though I'm not dealing with a file version?  Thanks for the info.

-hogfan

[Jos]

 

if they are all like strings, normal evaluation seems to also be fine

_CheckVer("7.5.4")
_CheckVer("5.2.1")
_CheckVer("5.2.0")

Func _CheckVer($ver)
    If $ver > "5.2.1" Then
        msgbox (0, '' , "newer then 5.2.1")
    Else
        msgbox(0, '' , "5.2.1 or older")
    Endif
Endfunc

Are you sure this is fullproof?

try:

_CheckVer("7.5.4")
_CheckVer("5.2.1")
_CheckVer("25.2.1")

Func _CheckVer($ver)
    If $ver > "5.2.1" Then
        msgbox (0, '' , "newer then 5.2.1")
    Else
        msgbox(0, '' , "5.2.1 or older")
    Endif
Endfunc

Jos

Edited July 19, 2013 by Jos

[iamtheky]

Indeed, the phrase "like strings" is not foolproof.    it seems to work for evaluating this string against other strings consisting of  #.#.# 

Edited July 19, 2013 by boththose

[guinness]

Casting as numbers should solve it.

[iamtheky]

it does.  Are there still pitfalls when done that way, that _VersionCompare overcomes?

_CheckVer("25.2.0")
_CheckVer("7.5.4")
_CheckVer("5.2.1")
_CheckVer("5.2.0")


Func _CheckVer($ver)
    If number($ver) > number("5.2.1") Then
        msgbox (0, '' , "newer then 5.2.1")
    Else
        msgbox(0, '' , "5.2.1 or older")
    Endif
Endfunc

[guinness]

It steps through the numbers that are separated by , or . Actually the function could do with a re-write as it's StringInStr isn't really required.

Edit: And there is no example! Re-write time.

Edited July 19, 2013 by guinness

[Jos]

 

it does.  Are there still pitfalls when done that way, that _VersionCompare overcomes?

_CheckVer("25.2.0")
_CheckVer("7.5.4")
_CheckVer("5.2.1")
_CheckVer("5.2.0")


Func _CheckVer($ver)
    If number($ver) > number("5.2.1") Then
        msgbox (0, '' , "newer then 5.2.1")
    Else
        msgbox(0, '' , "5.2.1 or older")
    Endif
Endfunc

 

Nah try: _CheckVer("5.12.0")

 

Jos

Edited July 19, 2013 by Jos

[DXRW4E]

Hi all, must be interpreted more correctly the line written incorrectly _VersionCompareEx("5.2.3", "5,2,3") or _VersionCompareEx("5..1", "5.0.1") ect ect

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name...........: _VersionCompareEx
; Description ...: Compares two file versions for equality
; Syntax.........: _VersionCompare($sVersion1, $sVersion2)
; Parameters ....: $sVersion1   - IN - The first version
;                  $sVersion2   - IN - The second version
; Return values .: Success      - Following Values:
;                  | 0          - Both versions equal
;                  | 1          - Version 1 greater
;                  |-1          - Version 2 greater
;                  Failure      - @error will be set in the event of a catasrophic error
; Author ........: Valik
; Modified.......: DXRW4E
; Modified.......:
; Remarks .......: This will try to use a numerical comparison but fall back on a lexicographical comparison.
;                  See @extended for details about which type was performed.
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _VersionCompareEx($sVersion1, $sVersion2)
   If $sVersion1 = $sVersion2 Then Return 0
   Local $aVersion1 = StringRegExp($sVersion1, "[^,.]+", 3), $aVersion2 = StringRegExp($sVersion2, "[^,.]+", 3)
   Local $iVersion1 = UBound($aVersion1) - 1, $iVersion2 = UBound($aVersion2) - 1, $iVersion = $iVersion1
   If $iVersion2 < $iVersion Then $iVersion = $iVersion2
   For $i = 0 To $iVersion
      ; Compare this segment as numbers
      If StringIsDigit($aVersion1[$i]) And StringIsDigit($aVersion2[$i]) Then
         If Number($aVersion1[$i]) > Number($aVersion2[$i]) Then
            Return 1
         ElseIf Number($aVersion1[$i]) < Number($aVersion2[$i]) Then
            Return -1
         EndIf
      Else ; Compare the segment as strings
         SetExtended(1)
         If $aVersion1[$i] > $aVersion2[$i] Then
            Return 1
         ElseIf $aVersion1[$i] < $aVersion2[$i] Then
            Return -1
         EndIf
      EndIf
   Next
   If $iVersion1 > $iVersion2 Then Return 1
   If $iVersion1 < $iVersion2 Then Return -1
   Return SetError(2, 0, 0)
EndFunc   ;==>_VersionCompare

Ciao.

Edited July 20, 2013 by DXRW4E

[guinness]

StringSplit can be used like StringSplit($sVersion1, ",."), so no need for SRE in this example. Thanks by the way.

[DXRW4E]

StringSplit can be used like StringSplit($sVersion1, ",."), so no need for SRE in this example. Thanks by the way.

I did not know that, Thank you

however I believe SRE helps more in this case

$a = StringSplit("5..1,2", ".,", 2)
;~ [0]|5
;~ [1]|
;~ [2]|1
;~ [3]|2

$a = StringRegExp("5..1,2", "[^.,]+", 3)
;~ [0]|5
;~ [1]|1
;~ [2]|2

Ciao.

[guinness]

I did not know that, Thank you

however I believe SRE helps more in this case

$a = StringSplit("5..1,2", ".,", 2)
;~ [0]|5
;~ [1]|
;~ [2]|1
;~ [3]|2

$a = StringRegExp("5..1,2", "[^.,]+", 3)
;~ [0]|5
;~ [1]|1
;~ [2]|2

Ciao.

True. Though we can't always protect users from themselves.

[DXRW4E]

Though we can't always protect users from themselves.

you're right

Ciao.

[Jos]

Actually I would consider the output from regex wrong as I would expect that  5..1.2 translates to 5.0.1.2.

Why are we also handling the comma in versioncheck? I thought only decimal points were supported.

Jos

[DXRW4E]

Any kind of ProgramSoftware or ResHack not allows to write that line, if a line is so, then it was written in the wrong way by the user, just ignore it is better

Ciao.

Edited July 20, 2013 by DXRW4E

[guinness]

Why are we also handling the comma in versioncheck? I thought only decimal points were supported.

Jos

That has been there since it was added all the back in rev 1736 when it was called _CompareVersion.

[Jos]

That has been there since it was added all the back in rev 1736 when it was called _CompareVersion.

Understand, but you can't use any comma's in the #autoit3wrapper and #pragma directives, so that triggered my question.