RegEx Help Needed (find some text)

[michaelslamet]

I have a txt file that contain something like this:

blablabla

blablabla

blablabla

Lock files:

blablabla

blablabla

blablabla

blablabla

!!autoit~~

//AUTOITaaa

--autoIT//aaa

blablabla

blablbla

blablba

</pre>

blablabla

blablabla

AUTOIT

I would like to count home many word "AUTOIT" (case insensitive) between word "Lock files:" (case insensitive) until first </pre>

(on example above, it's 3>

How can I do that?

Thanks

[guinness]

Is there a <pre> at the start of the file? If there is then something like this...

#include <Constants.au3>

Local $aSRE = StringRegExp(FileRead('myLog.txt'), '(?s)Lock files:.*</pre>', 3)
If @error = 0 Then
    StringReplace($aSRE[0], 'autoit', '')
    Local $iReplaced = @extended
    MsgBox($MB_SYSTEMMODAL, '', 'Replaced; ' & $iReplaced)
EndIf

Edited July 27, 2013 by guinness

[guinness]

Sometimes people overthink the problem and believe regexp is the answer, but just a little bit of lateral thinking and you can use native string functions e.g.

#include <Constants.au3>
#include <File.au3>

Local $aArray = 0, _
    $fInPre = False
    $iReplaced = 0
    
_FileReadToArray('myLog.txt', $aArray) ; This is basically StringSplit with @CRLF as the delim.
For $i = 1 To $aArray[0]
    Switch $aArray[$i]
        Case 'Lock files:'
            $fInPre = True
        Case '</pre>'
            If $fInPre Then ExitLoop
        Case Else
            If $fInPre Then
                StringReplace($aArray[$i], 'autoit', '')
                $iReplaced += @extended
            EndIf
    EndSwitch   
Next
MsgBox($MB_SYSTEMMODAL, '', 'Replaced; ' & $iReplaced)

Edited July 27, 2013 by guinness

[Malkey]

guinness

I believe you meant to use "Lock files:" instead of "<pre>" in both of your examples. See post  #1.

Here is a method of using two native string functions.

#cs
    blablabla
    AUTOIT
    blablabla
    blablabla
    Lock files:
    blablabla
    blablabla
    blablabla
    blablabla
    !!autoit~~
    //AUTOITaaa
    --autoIT//aaa
    blablabla
    blablbla
    blablba
    </pre>
    blablabla
    blablabla
    AUTOIT
#ce

;local $sTestString = FileRead('myLog.txt')
;or
Local $sTestString = StringRegExpReplace(FileRead(@ScriptFullPath), "(?is)^.*?#cs(.+?)#ce.*$", "\1")

;ConsoleWrite($sTestString & @LF)
Local $sTempStr = StringRegExpReplace($sTestString, "(?is)(^.*?Lock files:)(.+?)(</pre>.*?$)", "\2") ; Get all text between "Lock files:" and "</pre>".
;ConsoleWrite($sTempStr & @LF)
StringReplace($sTempStr, "AUTOIT", "")
MsgBox(0, "", 'Number of "AutoIt" replacements between "Lock files:" and first following occurrence of "</pre>" = ' & @extended & @LF) ; Returns 3

[michaelslamet]

Thank you, Guinness, thank you Malkey

Your code running great. However, what if the scenario is this:

Text file content:

blablabla

blablabla

blablabla

Lock files:

blablabla

blablabla

blablabla

blablabla

cccc autoit

bbbb AUTOIT aaa

  --autoIT //aaa

  !autoitxxx

blablabla

blablbla

blablba

</pre>

blablabla

blablabla

AUTOIT

I would like to grab between word "Lock files:" (case insensitive) until first </pre> (case insensitive)

word autoit until (to left side) first space BEFORE IT and how many the occurance.

For example, from above text, we will get:

autoit --> 2 occurances (from line "cccc autoit" and line bbbb AUTOIT aaa

--autoIT --> 1 occurances (from line "  --autoIT //aaa")

!autoit --> 1 occurances (from line "  !autoitxxx")

So the result is in 2D array where index [0] is the variation of word "autoit" and index [1] store how many times that variation occur

Seems pretty difficult that is

[michaelslamet]

 

Sometimes people overthink the problem and believe regexp is the answer, but just a little bit of lateral thinking and you can use native string functions e.g.

#include <Constants.au3>
#include <File.au3>

Local $aArray = 0, _
    $fInPre = False
    $iReplaced = 0
    
_FileReadToArray('myLog.txt', $aArray) ; This is basically StringSplit with @CRLF as the delim.
For $i = 1 To $aArray[0]
    Switch $aArray[$i]
        Case '<pre>'
            $fInPre = True
        Case '</pre>'
            If $fInPre Then ExitLoop
        Case Else
            If $fInPre Then
                StringReplace($aArray[$i], 'autoit', '')
                $iReplaced += @extended
            EndIf
    EndSwitch   
Next
MsgBox($MB_SYSTEMMODAL, '', 'Replaced; ' & $iReplaced)

 

Yes, that is me

Most of the time I think too hard for something actually simple

[guinness]

Ah, I changed my example(s).