Help with ReadOnly fields

[montyali]

Hi all, can anyone help plz...
What command can I use to make a ReadOnly field editable?

#include <Misc.au3>
#include <GUIConstants.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>

_Singleton(@ScriptName)
$gui_main = GUICreate("Temp", 400, 250)
GUISetBkColor(0xEEEEFF)
$font = "Century Gothic"
GUISetFont(10, 400, 0, $font)
$edit = GUICtrlCreateEdit("", 10, 10, 380, 180, BitOR($ES_WANTRETURN, $ES_READONLY, $WS_VSCROLL))
$edit_yes = GUICtrlCreateButton("Edit", 10, 200, 70, 20)
GUICtrlSetFont(-1, 8, 400, 0, $font)
$edit_no = GUICtrlCreateButton("Read Only", 83, 200, 70, 20)
GUICtrlSetFont(-1, 8, 400, 0, $font)
$exit = GUICtrlCreateButton("Exit", 320, 200, 70, 35)
GUISetState()
Do
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $GUI_EVENT_CLOSE Or $nMsg = $exit
            GUIDelete($gui_main)
        Case $nMsg = $edit_yes
            ;?????????????

        Case $nMsg = $edit_no
            ;?????????????

    EndSelect
Until Not WinExists($gui_main)

[Melba23]

montyali,

Welcome to the AutoIt forum.

Just change the required style for the edit like this:

#include <Misc.au3>
#include <GUIConstants.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>

_Singleton(@ScriptName)

$gui_main = GUICreate("Temp", 400, 250)
GUISetBkColor(0xEEEEFF)
$font = "Century Gothic"
GUISetFont(10, 400, 0, $font)
$edit = GUICtrlCreateEdit("", 10, 10, 380, 180, BitOR($ES_WANTRETURN, $ES_READONLY, $WS_VSCROLL))
$edit_yes = GUICtrlCreateButton("Edit", 10, 200, 70, 20)
GUICtrlSetFont(-1, 8, 400, 0, $font)
$edit_no = GUICtrlCreateButton("Read Only", 83, 200, 70, 20)
GUICtrlSetFont(-1, 8, 400, 0, $font)
$exit = GUICtrlCreateButton("Exit", 320, 200, 70, 35)
GUISetState()
Do
    $nMsg = GUIGetMsg()
    Select
        Case $nMsg = $GUI_EVENT_CLOSE Or $nMsg = $exit
            GUIDelete($gui_main)
        Case $nMsg = $edit_yes
            GUICtrlSetStyle($edit, BitOR($ES_WANTRETURN, $WS_VSCROLL))
            MsgBox(0, "State", "Editable")
        Case $nMsg = $edit_no
            GUICtrlSetStyle($edit, BitOR($ES_WANTRETURN, $ES_READONLY, $WS_VSCROLL))
            MsgBox(0, "State", "Read-Only")
    EndSelect
Until Not WinExists($gui_main)

This works for most styles, but alas some cannot be changed dynamically.

M23

[montyali]

Excellent, exactly what I was looking for.

THANKS HEAPS!!!