Event on tab out of input box

[nevodj]

Hello,

How can I detect when a user tabs out of a box in my GUI?

I have an inputbox where the user enters a number, and when they tab out of the box it needs to call a function.

This is because the value will be entered by a barcode scanner which sends a tab key.

The scanner can also send an enter key, so it may be better to send an enter key after the value is entered, and trigger the function.

So I need a way to trigger the function if an enter key is pressed, only while that inputbox is selected.

Thanks

[Melba23]

nevodj,

The simplest way would be to check if the input has keyboard focus:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Constants.au3>
#include <Misc.au3>
#include <WinAPI.au3>

Local $hDLL = DllOpen("user32.dll")

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput("", 10, 10, 200, 20)

$cButton = GUICtrlCreateButton("Dummy", 10, 100, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            DllClose($hDLL)
            Exit
    EndSwitch

    ; Is {ENTER} pressed
    If _IsPressed("0D", $hDLL) Then
        ; Does input have focus?
        If _WinAPI_GetFocus() = GUICtrlGetHandle($cInput) Then
            ; Call your function here
            MsgBox($MB_SYSTEMMODAL, "Hit", "ENTER pressed whith Input Focus")
            ; Wait for the key to be released
            While _IsPressed("0D", $hDLL)
                Sleep(10)
            WEnd
        EndIf
    EndIf

WEnd

There are more elegant methods of doing this, but this one is simple and it works.

M23