Sleep with other operations

[yogesh87]

Hi All

I am very new to autoit programming

started my script just today, i have successfully created a program of my own with the help n forums, it works perfectly fine

But i want to repeat the operation after 3 hrs for which i will use sleep

but while it is sleeping i want it to switch to other operations, i am not finding a script for this please help me with this

Sorry for my bad english

Regards,

Yogesh

PS: srry if i posted in wrong section feel free to move the thread n leave a reply so that i can post my question there

Edited August 18, 2013 by yogesh87

[Melba23]

yogesh87,

Welcome to the AutoIt forum.

As you have discovered, Sleep pauses the script completely. I suggest you look at TimerInit/TimerDiff in the Help file - using them will allow your script stay active and still react after the correct time period. Give it a go yourself - you know where we are if you run into difficulties.

M23

P.S. And I moved your thread into the correct place.

Edited August 18, 2013 by Melba23

[yogesh87]

Thx for the fast reply

i actually dont get how it works, can you please explain how it works

would also like to know how i could incorporate internet explorer to my program so that i can run my program even if it is minimized and is there is a command where I could pause the script and resume it where it was paused

srry if i asked too many questions, since i am new have lots of doubts will try to find answers myself or post here

[Melba23]

yogesh87,

This should explain how to use TimerInit/TimerDiff:

#include <GUIConstantsEx.au3>
#include <Constants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cButton = GUICtrlCreateButton("Test", 10, 10, 80, 30)

GUISetState()

; Run the timed function
_Timed_Function()
; Get a timestamp
$nBegin = TimerInit()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            ; The button will still be active while you wait
            MsgBox($MB_SYSTEMMODAL, "Hello", "I work all the time!")
    EndSwitch

    ; Check the timestamp and see if the required time has elapsed
    If TimerDiff($nBegin) > 1000 * 10 Then ; This is a 10 sec delay
        ; Run the timed function
        _Timed_Function()
        ; Reset the timestamp
        $nBegin = TimerInit()
    EndIf
WEnd

Func _Timed_Function()
    MsgBox($MB_SYSTEMMODAL, "Hi!", "Timed function")
EndFunc

As for your other questions:

 

- 1. Look at the IE Management functions in the Help file - they let you control IE from your script.

- 2. Pause and Resume - this has been asked (and answered) many, many times on the forum. Use the Search facilty at top right and you will soon see how it is done.

M23