question about array within array

[Gianni]

From the Autoit documentation, under the "variables" link I read:

It was said that an Array contains only one datatype of the same type. But technically speaking, a Variant in AutoIt can contain anything from a number to a boolean value. So an AutoIt-Array could also contain different types, even other Arrays:

$Array[0]=1
$Array[1]=true
$Array[2]="Text"
$Array[3]=$AnotherArray

 

Well, now if I have a simple 1D array, and one element of this contains another 1D array, how can I access the elements of the "nested" array?

 

Can I access $AnotherArray[2] directly from within $Array[3] in the following example?

Dim $AnotherArray[5] = ["zero", "one", "two", "three", "four"]
Dim $Array[4]

$Array[0] = 1
$Array[1] = True
$Array[2] = "Text"
$Array[3] = $AnotherArray

ConsoleWrite($Array[3][2]) ; <-- this is obviously wrong

; is there a way to read "directly" the element [2] of the nested array from $Array[3] ?

thanks

[Melba23]

Pincopanco,

Not as far as I know - you have to extract it into a temporary variable first. Basically, how is Autoit to know that the outer array element is actually another array?

M23

Edit: See below for a solution using the Beta - I forgot all about that.

Edited August 22, 2013 by Melba23

[0xdefea7]

I do the same as Melba said, save to variable first, then access the array using the temporary variable. There is no way to do it directly.

Dim $AnotherArray[5] = ["zero", "one", "two", "three", "four"]
Dim $Array[4]
Dim $Temp

$Array[0] = 1
$Array[1] = True
$Array[2] = "Text"
$Array[3] = $AnotherArray

ConsoleWrite($Array[3][2]) ; <-- this is obviously wrong

$Temp = $Array[3] ;Grab the array and save to $Temp

ConsoleWrite($Temp[2] & @CRLF)  ;Prints 2 to the console

; is there a way to read "directly" the element [2] of the nested array from $Array[3] ?

Posted the code in case anyone else would like to follow along

[Gianni]

Thanks Melba23 and 0xdefea7 for the quick response

I was hoping that it was possible

I tried with _ArrayDisplay() .... it shows a "hole" in that position..... 

(also _ArrayDisplay() left me alone )

Edited August 22, 2013 by Pincopanco

[abberration]

This would kind of do what you want. I included an inputbox so you can see it can read the 2nd array from the first.

#include <array.au3>

Dim $AnotherArray[5] = ["zero", "one", "two", "three", "four"]
Dim $Array[4]

$input = InputBox("Enter number", "Enter number between 0 and 4")

$Array[0] = 1
$Array[1] = True
$Array[2] = "Text"
$Array[3] = $AnotherArray[$input]

_ArrayDisplay($Array)

[Gianni]

Hi Abberration

thanks for the reply, for a moment I believed in a solution ...
but in this way the $Array[3] element contains only one value and not the whole $AnotherArray
This is not an Array within an Array
thanks again for trying

[jchd]

The beta offers a solution:

Local $a[2] = ["x", "y"]
Local $b[2] = [1, $a]
ConsoleWrite(($b[1])[0] & @LF)

Use it or wait for the release.

[AdamUL]

You can do this with the AutoIt Beta.

 

Local $AnotherArray[5] = ["zero", "one", "two", "three", "four"]
Local $Array[4]

$Array[0] = 1
$Array[1] = True
$Array[2] = "Text"
$Array[3] = $AnotherArray

;~ ConsoleWrite($Array[3][2]) ; <-- this is obviously wrong
ConsoleWrite(($Array[3])[2] & @CR) ;<-- Works with AutoIt Beta v3.3.9.18
 

I don't know if you want to use the Beta version though.

Adam

Edit: jchd beat me to it.

Edited August 22, 2013 by AdamUL

[Gianni]

Thanks jchd & AdamUL

this is what I was looking for
I am using AutoIt 3.3.8.1
but I'm glad to know that the next version will allow this syntax.
thanks again to both

[jchd]

In addition you will be able to use indexing directly on the array returned by a function: ConsoleWrite("abc" & myfunc($param)[2] & @LF)

But of course you want to use such construct only when the probability is = 1 that myfunc returns a result incompatible with [2] index.