GUICtrlCreateListViewItem limit ?

[incepator]

Hello guys,

I have a question, if you can help me ...

I made this script, for testing:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
GUICreate("", 500, 550)
$nr = GUICtrlCreateInput("80000", 10, 30, 320, 20)
$button = GUICtrlCreateButton("Genereaza", 40, 50, 320, 20)
$List = GUICtrlCreateListView("val1", 10, 90, 400, 450)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            For $i = 1 To GUICtrlRead($nr)
                GUICtrlCreateListViewItem($i, $List)
                _GUICtrlListView_Scroll($List, 0, $i*50)
            Next
    EndSwitch
WEnd

the problem is ListViewItems limited to 65530 line, can solve this somehow?

 

[JohnOne]

Create another listview control.

[incepator]

there is no solution to this problem using a single ListView?

[Kidney]

i tested out your script but made some adjustments.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
GUICreate("", 500, 550)
$nr = GUICtrlCreateInput("80000", 10, 30, 320, 20)
$button = GUICtrlCreateButton("Genereaza", 40, 50, 320, 20)
$List = GUICtrlCreateListView("val1", 10, 90, 400, 450)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            $i = 1
            Do
                GUICtrlCreateListViewItem($i, $List)
                $i = $i + 1
            Until _GUICtrlListView_GetItemCount($List) = GUICtrlRead($nr)
            _GUICtrlListView_Scroll($List, 0, $i*50)
    EndSwitch
WEnd

 

since the _GUICtrlListView_Scroll is outside the loop, you can see when it exits the loop. with this script, it never leaves the loop. just confirms that there is something limiting the list. i think it has to do with memory tho. if its not, dont bite my head off.

[kylomas]

Per the Help File

AutoIt3 Limits/defaults

 

AutoIt3 limits Value Description MAX_LINESIZE 4095 Maximum size for a line of script. MAX_ENVSIZE 32767 Maximum size for an ENV variable. WINTEXTBUFFER 32767 GetWindowText fails under 95 if>65535, WM_GETTEXT randomly fails if > 32767. MAXCALLRECURSE 5100 Maximum number of times the Call() function can recurse to itself. MAXEXECUTERECURSE 5100 Maximum number of times the Execute() function can recurse to itself. GUI_MAXCONTROLS 65532 Maximum number of controls in GUI box. GUI_MAXPOINTS 256 Maximum number of points by graphic info page. COM_MAXEVENT 64 Maximum number of COM events that can be buffered. VAR_SUBSCRIPT_MAX 64 Maximum number of subscripts for an array. MAIN_TIMER_DELAY 750 ms Tray icon hiding/flashing/drawing is checked every 750ms. CMDLINEPARAM_MAXLEN 4096 Each parameter can be this many characters. TRAY_MAXITEMS 505 Maximum number of items in the tray menu. TRAY_MAXEVENT 32 Maximum number of events that can be buffered. TRAY_TOOLTIPWIDTH 64 Maximum number of characters displayed in a tray tooltip.

 

Default Value Description ADLIB delay 250 ms Default delay in ms between ADLIB triggers. Can be defined in AdlibRegister().     Following defaults can be changed with Opt() MouseClickDelay 10 ms Time between mouse clicks. MouseClickDownDelay 10 ms Time the click is held down. MouseClickDragDelay 250 ms The delay at the start and end of a drag operation. TCPTimeout 100 ms Time after a TCP function is aborted.

 

kylomas

[BrewManNH]

Use _GUICtrlListview_AddItem instead of the native function (GUICtrlCreateListViewItem), AutoIt control IDs are limited to 65532 Windows handles are not.

[Kidney]

Use _GUICtrlListview_AddItem instead of the native function (GUICtrlCreateListViewItem), AutoIt control IDs are limited to 65532 Windows handles are not.

hey would you look at that. worked just fine haha.

[incepator]

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
GUICreate("", 500, 550)
$nr = GUICtrlCreateInput("100000", 10, 30, 320, 20)
$button = GUICtrlCreateButton("Genereaza", 40, 50, 320, 20)
$List = GUICtrlCreateListView("val1" &"|"& "val2" &"|"& "val3" &"|"& "val4", 10, 90, 400, 450)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            $i = 1
            Do
                _GUICtrlListView_AddItem($List, $i)
                _GUICtrlListView_AddSubItem($List, $i-1, "test", 1, 1)
                _GUICtrlListView_AddSubItem($List, $i-1, "test3", 2, 2)
                _GUICtrlListView_AddSubItem($List, $i-1, "test4", 3, 3)

                _GUICtrlListView_Scroll($List, 0, $i)

                $i = $i + 1
            Until _GUICtrlListView_GetItemCount($List) = GUICtrlRead($nr)
    EndSwitch
WEnd

Thanks guys, solved this problem