how can stop program if IE was disconnected

[bills4]

I am running program with IE , but sometimes my internet was disconnected , when internet was disconnected i want my program stop run .

Please help

[JohnOne]

I think _GetIP() fails if you are not connected to internet.

I don't think it's a function you should call in a tight loop though.

There's are other alternatives.

[Newb]

You can try run a Ping(site) and if it's equal to 0 then call a ProcessExists/ProcessClose combination on it.

[JohnOne]

There is also a Windows API which checks the state locally, via a call to system dll.

Just cannot quite remember its name.

EDIT:

Possibly InternetGetConnectedState

Edited August 31, 2013 by JohnOne

[dragan]

This will check for your internet connection state:

 

expandcollapse popup

Opt("TrayAutoPause", 0)
Global $CheckingForOffline = True

_GetInitialState()

While 1
    Sleep (250)
    _CheckInternetState()
WEnd


;========================================================================================================
;========================== Function: ===================================================================
Func _GetInitialState()
    Local $IsConnected = _ISConnectedToInternet()
    If @error Then
        ConsoleWrite('!> Error: ' & @error & ', Couldn''t access "wininet.dll", and "InternetGetConnectedState" function' & @CRLF)
        MsgBox(16, 'Error: ' & @error, 'Couldn''t access "wininet.dll", and "InternetGetConnectedState" function' & @CRLF & _
                                        @CRLF & _
                                        'Press OK to quit the script.')
        Exit
    Else
        If $IsConnected Then
            $CheckingForOffline = True
            ConsoleWrite('-> checking for internet disconnection started...' & @CRLF & @CRLF)
        Else
            $CheckingForOffline = False
            ConsoleWrite('>> checking for internet reconnection started...' & @CRLF & @CRLF)
        EndIf
    EndIf
EndFunc

Func _CheckInternetState()
    Local $IsConnected = _ISConnectedToInternet()
    If @error Then
        ConsoleWrite('!> Error: ' & @error & ', Couldn''t access "wininet.dll", and "InternetGetConnectedState" function' & @CRLF)
        MsgBox(16, 'Error: ' & @error, 'Couldn''t access "wininet.dll", and "InternetGetConnectedState" function' & @CRLF & _
                                        @CRLF & _
                                        'Press OK to quit the script.')
        Exit
    Else
        If $CheckingForOffline Then
            If NOT $IsConnected Then
                ConsoleWrite('!> Internet has just been disconnected' & @CRLF)
;~              Exit;<------------- Enable this line if you want your script to close if you get disconnected
                $CheckingForOffline = False
                ConsoleWrite('>> checking for internet reconnection started...' & @CRLF & @CRLF)
            EndIf
        Else
            If $IsConnected Then
                ConsoleWrite('+> Internet has just been reconnected' & @CRLF)
                $CheckingForOffline = True
                ConsoleWrite('-> checking for internet disconnection started...' & @CRLF & @CRLF)
            EndIf
        EndIf
    EndIf
EndFunc

Func _ISConnectedToInternet()
    Local $aDllRet = DllCall("wininet.dll", "int", "InternetGetConnectedState", "long_ptr", 0, "long", 0)
    If @error OR NOT IsArray($aDllRet) then Return SetError(1, 0, 0)
    If $aDllRet[0] > 0 Then
        Return True
    Else
        Return False
    EndIf
EndFunc
;========================================================================================================
;========================================================================================================