Better way to create GUI with close button only AND without taskbar entry and without Icon in title bar

[ngskicker]

Just wondering, this is always in my mind, how to create a gui that has only close button and does not have taskbar entry, I now i can make one with:

GUICreate("Form1", 373, 263, 192, 124, Default, $WS_EX_TOOLWINDOW)

that reproduce something like this:

I'ts perfect except the close button is shrinking, I took the screenshoot above on Windows 8, as I recall in previous windows version (maybe XP) close button is smaller than that, one work around I found is create GUI using:

GUICreate("Form2", 367, 510, -1, -1, BitXOR($GUI_SS_DEFAULT_GUI, $WS_MINIMIZEBOX))

and then add this code (found in help) to delete taskbar entry:

; Declare the CLSID, IID and interface description for ITaskbarList.
Local Const $sCLSID_TaskbarList = "{56FDF344-FD6D-11D0-958A-006097C9A090}"
Local Const $sIID_ITaskbarList = "{56FDF342-FD6D-11D0-958A-006097C9A090}"
Local Const $sTagITaskbarList = "HrInit hresult(); AddTab hresult(hwnd); DeleteTab hresult(hwnd); ActivateTab hresult(hwnd); SetActiveAlt hresult(hwnd);"

; Create the object.
Local $oTaskbarList = ObjCreateInterface($sCLSID_TaskbarList, $sIID_ITaskbarList, $sTagITaskbarList)

; Initialize the iTaskbarList object.
$oTaskbarList.HrInit()

; Delete window entry from the Taskbar.
$oTaskbarList.DeleteTab($Form2)

GUISetState(@SW_SHOW)

this one produce nicer close button,

No taskbar entry, but the icon still there, after doing forum search i found >this code by rover and modified by guiness to remove the icon, but, is there a better way to do this without so much code

[BrewManNH]

Use the search, it's been discussed about half a dozen times with solutions posted.

[ngskicker]

Use the search, it's been discussed about half a dozen times with solutions posted.

 

Can you find one for me sir, I was so stupid, I can not find it.

[Valuater]

Here is a possibility...

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
$Dummy = GUICreate("")
GUISetState(@SW_HIDE, $Dummy)
$GUI = GUICreate("Form2", 367, 510, -1, -1, BitXOR($WS_CAPTION,
$WS_POPUP), -1,  $Dummy)
$Btn = GUICtrlCreateButton("X",344,-1,25,25)
;GUICtrlSetFont($Btn, 10, 400)
GUICtrlSetColor($Btn, 0xffffff)
GUICtrlSetBkColor($Btn, 0xdd0000)
GUISetState()
while 1
 if GUIGetMsg() = $Btn then Exit
WEnd

8)

Edited September 9, 2013 by Valuater

[ngskicker]

Thanks, but that's create a weird GUI not the one that I want

[TheSaint]

Can't you just create a popup window with no buttons or caption bar, then add your own button and maybe a label for title.

[UEZ]

What about this here?

AutoIt version 3.3.9.x is needed:

#include <GUIConstantsEx.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>

#NoTrayIcon

$hGUI = GUICreate("Form 1", 300, 200, -1, -1, BitOR($WS_CAPTION, $WS_SYSMENU), $WS_EX_DLGMODALFRAME)
$hIcon = _WinAPI_GetClassLongEx($hGUI, $GCL_HICON)
_WinAPI_DestroyIcon($hIcon)
_WinAPI_SetClassLongEx($hGUI, $GCL_HICON, 0)
_WinAPI_SetClassLongEx($hGUI, $GCL_HICONSM, 0)

GUISetState()


Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Br,

UEZ

Edited September 9, 2013 by UEZ

[Mat]

Here's a little trick to remove the entry from the taskbar without getting it to flash.

#include <GUIConstantsEx.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>

#NoTrayIcon

$hGUI = GUICreate("Form 1", 300, 200, -1, -1, BitOR($WS_CAPTION, $WS_SYSMENU), $WS_EX_DLGMODALFRAME, WinGetHandle(AutoItWinGetTitle()))
$hIcon = _WinAPI_GetClassLongEx($hGUI, $GCL_HICON)
_WinAPI_DestroyIcon($hIcon)
_WinAPI_SetClassLongEx($hGUI, $GCL_HICON, 0)
_WinAPI_SetClassLongEx($hGUI, $GCL_HICONSM, 0)


GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

[UEZ]

Indeed, I forgot to hide the taskbar  . Can also be done with $WS_EX_TOOLWINDOW style.

Br,

UEZ

[PlayHD]

Instead use this :

BitXOR($GUI_SS_DEFAULT_GUI, $WS_MINIMIZEBOX)

you can use this :

$WS_SYSMENU

[Wombat]

You could always draw you're own exit button and title by hand (manually) with labels, or use GUICtrlCreatePic to import custom graphics and set the window to either borderless or just a small frame.

Edited September 11, 2013 by Wombat

[Valuater]

I was trying to do something like this a while back and ended up designing this

8)

[ngskicker]

Everyone thanks, too bad we have to wait for the beta in order to do this, one question that may not be related, whether autoit beta has been running well?

[FireFox]

The beta is needed for the _WinAPI functions and/or the constants.

Nothing related to the internal stuff.

Br, FireFox.

[PhoenixXL]

To expand upon what Wombat and TheSaint said

Example

expandcollapse popup

#include-once
#include <WinAPI.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <StaticConstants.au3>
#NoTrayIcon

Local $hGUI = GUICreate("", -1, -1, -1, -1, $WS_POPUP, $WS_EX_TOOLWINDOW)
Local $iClose = CreateNCRegion($hGUI, "M y  W i n d o w")

GUISetState()

Local $nMsg
Do
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $iClose
            Exit
    EndSwitch

Until $nMsg = $GUI_EVENT_CLOSE











Func CreateNCRegion($hWnd, $s_Title)

    Local Const $aPos = WinGetPos($hWnd)
    Local Const $iHeight = _WinAPI_GetSystemMetrics($SM_CYSIZE)
    Local Const $iWidth = _WinAPI_GetSystemMetrics($SM_CXFRAME)
    Local Const $iHeight_H = _WinAPI_GetSystemMetrics($SM_CYFRAME)

    ;the title
    GUICtrlCreateLabel($s_Title, 0, 0, $aPos[2], $iHeight, $SS_CENTER, $GUI_WS_EX_PARENTDRAG)
    GUICtrlSetBkColor(-1, 0x63B4FB)
    GUICtrlSetFont(-1, 10, 550, 0, "Tahoma")
    _GuiHole(GUICtrlGetHandle(-1),  $aPos[2] - $iWidth - 15, 2, 15, $iHeight - 4, $aPos[2], $aPos[3])

    ;left/right frame
    GUICtrlCreateLabel("", 0, $iHeight, $iWidth, $aPos[3] - $iHeight)
    GUICtrlSetBkColor(-1, 0x63B4FB)
    GUICtrlCreateLabel("", $aPos[2] - $iWidth, $iHeight, $iWidth, $aPos[3] - $iHeight)
    GUICtrlSetBkColor(-1, 0x63B4FB)
    GUICtrlCreateLabel("", $iWidth, $aPos[3] - $iHeight_H, $aPos[2] - $iHeight_H - $iHeight_H, $iHeight_H)
    GUICtrlSetBkColor(-1, 0x63B4FB)

    ;Close button
    Local Const $iCloseBtn = GUICtrlCreateLabel("X", $aPos[2] - $iWidth - 15, 2, 15, $iHeight - 4, $SS_CENTER)
;~  GUICtrlSetState(-1, $GUI_ONTOP)  <<<<< Don't know why this doesn't work.. therefore I had to add _GuiHole
    GUICtrlSetBkColor(-1, 0xC75050)
    GUICtrlSetColor(-1, 0xFFFFFF)
    GUICtrlSetFont(-1, 10, 550, 0, "Tahoma")

    Return $iCloseBtn
EndFunc   ;==>CreateNCRegion

; make inner transparent area
Func _GuiHole($h_win, $i_x, $i_y, $i_sizew, $i_sizeh, $width, $height)
    Local $outer_rgn, $inner_rgn, $combined_rgn

    $outer_rgn = _WinAPI_CreateRectRgn(0, 0, $width, $height)
    $inner_rgn = _WinAPI_CreateRectRgn($i_x, $i_y, $i_x + $i_sizew, $i_y + $i_sizeh)
    $combined_rgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
    _WinAPI_CombineRgn($combined_rgn, $outer_rgn, $inner_rgn, $RGN_DIFF)
    _WinAPI_DeleteObject($outer_rgn)
    _WinAPI_DeleteObject($inner_rgn)
    _WinAPI_SetWindowRgn($h_win, $combined_rgn)
EndFunc   ;==>_GuiHole 

Regards

Edited September 20, 2013 by PhoenixXL

[kylomas]

 how to create a gui that has only close button and does not have taskbar entry

 

Could be this simple...

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

local $button_size = 30
local $offset = 5

local $gui010   =   guicreate('',-1,-1,-1,-1,$ws_popup)
local $aSize    =   wingetclientsize($gui010)
local $button   =   guictrlcreatebutton('X',$aSize[0]-$button_size-$offset,$offset,$button_size,$button_size)
                    guictrlsetfont(-1,$button_size*.6,800)
                    guisetstate()

while 1
    switch guigetmsg()
        Case $gui_event_close
            Exit
    EndSwitch
wend