Regexp detecting korean letters

[karlkar]

Hello.

I want to check if in my string exists any korean letter. According to http://jrgraphix.net/research/unicode_blocks.php the unicode characters for korean language are in 2 ranges u3130-u318F and uAC00-uD7AF

I have prepared on http://regexpal.com/ regexp that works. After moving it to autoit it doesn't work. What is wrong? Can anybody help?

Regexp that I use is:

[u3130-u318FuAC00-uD7AF]

 

test string is

※ 발생경로

 

In regexpal it detects letters as it should, but in autoit - not. Any ideas?

Edited September 9, 2013 by karlkar

[PhoenixXL]

If you check the autoit help file with the function StringRegExp , you would find that for hex character x is used rather than u

;8251, 48156, 49373, 44221, 47196 are the Unicode representing the characters you supplied on your post
;I got them using MsgBox( 0, "", AscW(ClipGet())), since SCITE didn't supported these chars.

$String = ChrW(8251) & ChrW(48156) & ChrW(49373) & ChrW(44221) & ChrW(47196)
If StringRegExp($String, "[\x{3130}-\x{318F}\x{AC00}-\x{D7AF}]") Then MsgBox(64, "Info", "Korean Alphabets Present")

$String = " Some English Text..."
If StringRegExp($String, "[\x{3130}-\x{318F}\x{AC00}-\x{D7AF}]") Then
    MsgBox(64, "Info", "Korean Alphabets Present")
Else
    MsgBox(16, "Err", "Korean Alphabet not found")
EndIf

[sahsanu]

Hello.

I want to check if in my string exists any korean letter. According to http://jrgraphix.net/research/unicode_blocks.php the unicode characters for korean language are in 2 ranges u3130-u318F and uAC00-uD7AF

I have prepared on http://regexpal.com/ regexp that works. After moving it to autoit it doesn't work. What is wrong? Can anybody help?

Regexp that I use is:

 

test string is

 

In regexpal it detects letters as it should, but in autoit - not. Any ideas?

 

Check whether this works:

[\x{3130}-\x{318F}\x{AC00}-\x{D7AF}]

Edit: PhoenixXL was faster and gave a better answer (explanation included)

Edited September 9, 2013 by sahsanu

[PhoenixXL]

This might come in handy for characters

;8251, 48156, 49373, 44221, 47196 are the Unicode representing the characters you supplied on your post
;I got them using MsgBox( 0, "", AscW(ClipGet())), since SCITE didn't supported these chars.


Func CharIsKorean($s_Char)

    Switch AscW($s_Char)
        Case 0x3130 To 0x318F, 0xAC00 To 0xD7AF
            Return 1
    EndSwitch

    Return 0

EndFunc   ;==>CharIsKorean

MsgBox(0, "Is Korean", "A? " & CharIsKorean("A"))
MsgBox(0, "Is Korean", ChrW(48156) & "? " & CharIsKorean(ChrW(48156)))  ;MsgBox is showing a Box for korean chars on my laptop
MsgBox(0, "Is Korean", ChrW(44221) & "? " & CharIsKorean(ChrW(44221)))

NOTE: Autoit uses PCRE, so when creating your regexes make sure its for PCRE.

[jchd]

The beta version has support for UCP, so you can already try language properties (or wait for the next to come release):

Local $String = "Sample english text 한국어 텍스트의 예 טקסט עברית ירושלים"
Local $res = StringRegExp($String, "(*UCP)\b(\p{Hangul}[\p{Hangul}\s]*)\b", 1)
If not @error Then MsgBox(64, "Korean text found", $res[0])
Local $res = StringRegExp($String, "(*UCP)\b(\p{Latin}[\p{Latin}\s]*)\b", 1)
If not @error Then MsgBox(64, "Latin text found", $res[0])
Local $res = StringRegExp($String, "(*UCP)\b(\p{Hebrew}[\p{Hebrew}\s]*)\b", 1)
If not @error Then MsgBox(64, "Hebrew text found", $res[0])

Since UCP support is not active by default, yu need to use the "(*UCP)" prefix. Note that for instance Hangul doesn't include digits, spaces or punctuation, so you may need to adapt to your use case.