List all variable names and content in script

[michaelslamet]

So I would like to list all variable names and their contents in script for debugging.

I found this:

'?do=embed' frameborder='0' data-embedContent>>

expandcollapse popup

#include <Array.au3>
#include <File.au3>
Global Const $asAutoItOperators[21] = ['=','+=','-=','*=','/=','&=', _
                                '+','-','*','/','&','^', _
                                '==','<>','>','<','>=','<=', _
                                'and','or','not']

Global Const $asAutoItVarKeywords[5] = ['Local','Global','Dim', _
                                'Const','Enum']

Global Const $asAutoItFuncKeywords[2] = ['Func','EndFunc']

Global $sFile = @ScriptFullPath

$asVarArray = ParseVarsFromScript($sFile)

_ArrayDisplay($asVarArray)

Func ParseVarsFromScript(Const $sFileName,Const $iStartLine = 1,$iEndLine = 0)
    Local $iLineCounter

    Local $sFileContent
    Local $sCurrentLine

    Local $asScriptVars[1]

    Local $hFile = FileOpen($sFileName,0)
    If @error Then
        SetError(1)
        Return
    EndIf

    If Not $iEndLIne Then
        $iEndLIne = _FileCountLines($sFileName)
    EndIf

    Local $sFileEndName = StringRegExp($sFileName,"[^\\/]+$",1)
    If Not @error Then
        $sFileEndName = $sFileEndName[0]
    Else
        $sFileEndName = $sFileName
    EndIf
    ProgressOn("Processing",$sFileEndName)
    $nProgress = 0.0

    For $iLineCounter = $iStartLine To $iEndLine
        $sCurrentLine = FileReadLine($hFile,$iLineCounter)
        $iVarCounter = 0

        While 1
            $iVarCounter += 1
            $iVarStartPos = StringInStr($sCurrentLine,"$",0,$iVarCounter)

            If $iVarStartPos <= 0 Then
                ExitLoop
            EndIf
            If CheckQuoted($sCurrentLine,$iVarStartPos,False) == False Then
                $iVarLen = CheckQUoted($sCurrentLine,$iVarStartPos,True)
                $sVarName = StringMid($sCurrentLine,$iVarStartPos,$iVarLEn)

                ReDim $asScriptVars[$asScriptVars[0]+2]

                $asScriptVars[$asScriptVars[0]+1] = $sVarName
                $asScriptVars[0]+=1
            EndIf
        WEnd
        $nProgress = ($iLineCOunter / $iEndLine) * 100

        $sProgressSubText = "Line " & $iLineCOunter & " off " & $iEndLine & @LF
        $sProgressSubText &= "Variables Found: " & $asScriptVars[0]
        ProgressSet($nProgress,$sProgressSubText)
    Next
    FileClose($hFile)
    ProgressOff()
    Return $asScriptVars
EndFunc

Func CheckQuoted(Const $sCurrentLine,$iVarStartPos,Const $fDirection = False)
    Local $sCurrentChar
    Local $fQuoted = False
    Local $iStep
    Local $iSkippedCharCounter = 0
    Local $sVarEndRegEx

    If $fDirection == False Then
        $iStep = -1
        $iEnd = 1
        $iVarStartPos -= 1
    Else
        $iStep = 1
        $iEnd = StringLen($sCurrentLine)
        $iVarStartPos += 1
    EndIf

    For $iCharCounter = $iVarStartPos To $iEnd Step $iStep
        $sCurrentChar = StringMid($sCurrentLine,$iCharCounter,1)

        If Not StringLen($sCurrentChar) Or (Not $fQuoted And StringRegExp($sCurrentChar,"[()\[\],.\s]")) Then
            ExitLoop
        ElseIf $sCurrentChar == "'" Or $sCurrentChar = '"' Then
            $fQuoted = True
        EndIf

        If $fQuoted Then
            ContinueLoop
        EndIf

        For $iOperatorCounter = 0 To UBound($asAutoItOperators)-1
            $sCurrentOperator = $asAutoItOperators[$iOperatorCounter]
            $iCurrentOperatorLen = StringLen($sCurrentOperator)
            If $fDirection == False Then
                $sTempCompare = StringMid($sCurrentLine,$iCharCounter-$iCurrentOperatorLen+1,$iCurrentOperatorLen)
            Else
                $sTempCompare = StringMid($sCurrentLine,$iCharCounter,$iCurrentOperatorLen)
            EndIf
            If @error Or Not StringLen($sTempCompare) Then
                ContinueLoop
            ElseIf $sTempCompare == $sCurrentOperator Then
                $fQuoted = False
                ExitLoop(2)
            EndIf
        Next
    Next
    If $fDirection Then
        If $fQuoted Then
            Return 0
        Else
            Return $iCharCounter-$iVarStartPos+1
        EndIf
    Else
        Return $fQuoted
    EndIf
EndFunc

 

The problems with the code are:

1. The variables names it get are duplicate, not unique.

2. It only get the variables names, not the content of the variables.

I know I should can get the variable contents using Eval through a loop, but cant make it works

[Bowmore]

Have you tried running Tidy.exe with the /gd option. This produces a very detailed report on variables, look towards the bottom of the report, that lists all the variables, where they are declared and where they are used.

[AZJIO]

michaelslamet

'?do=embed' frameborder='0' data-embedContent>>

'?do=embed' frameborder='0' data-embedContent>>

[Gianni]

Hi michaelslamet

in reference to your script, you could use something like this to see all variables not repeated and the value within them,

$asVarArray = _ArrayUnique(ParseVarsFromScript($sFile))
_ArrayDelete($asVarArray, 0)
_ArrayDelete($asVarArray, 0)
For $i = 0 To UBound($asVarArray) - 1
    $asVarArray[$i] = $asVarArray[$i] & " = " & String(Execute($asVarArray[$i]))
Next
_ArrayDisplay($asVarArray)

but as you can see all the variables that are declared as "Local" within functions are not recognized outside of the functions and are therefore listed as empty. in addition if it is an array, also appear as empty, while the variables in the same "scope" are listed with their value (in this case only $i and $sFile)
bye

[michaelslamet]

Thank you AZJIO, thank you PincoPanco.

AZJIO, your scripts are for displaying list of vars on another scripts.

PincoPanco, the modified script seems promising when run from SciTE, but display nothing when compiled.

I wish to add this feature to all of my scripts to help debugging when run, so it can display all of the vars used and their content,

I think it's not possible, moreover in the compiled mode?

[michaelslamet]

Thank you, Bowmore Unfortunetely, using tidy.exe is not an option

[BrewManNH]

There is no way for a script to display the contents of all of its variables at runtime without a LOT of consolewrites/filewrites/msgboxs etc. What you should look at is the AutoIt debugger written by Stumpii that will help in debugging your script, other than that I can't think of any way for you to get this information.

BTW, without using a LOT of consolewrites/filewrites/msgboxs etc. you can't get this information at all with a compiled script.

[jchd]

You're barking at the wrong tree. Learn and strictly apply robust programming practices first, then 99.99% of your problems will vanish.

[michaelslamet]

You're barking at the wrong tree. Learn and strictly apply robust programming practices first, then 99.99% of your problems will vanish.

 

I'm not trying to hide any errors. I just think this is a nice feature to have.

Currently from any of my scripts, I can press hot key, enter var name is the value displayed. This is a nice feature that I "stole" from one of post lately,

then I think it will be great if we can display all the var names and their value anytime we need when run the script.

Shoudn't everybody need a debugger, no matter how roboust programming practices applied?

By that I'm not saying I apply a roboust programming practices because most of my scripts are --while can run perfectly most of the time-- messy

in variable names, logic, etc.

[michaelslamet]

There is no way for a script to display the contents of all of its variables at runtime without a LOT of consolewrites/filewrites/msgboxs etc. What you should look at is the AutoIt debugger written by Stumpii that will help in debugging your script, other than that I can't think of any way for you to get this information.

BTW, without using a LOT of consolewrites/filewrites/msgboxs etc. you can't get this information at all with a compiled script.

 

Ok noted So confirm this is not possible?

[mLipok]

yes it is possible

 

look in scite

MENU: Tools/Debug ...

MENU: Tools/Trace: ...

MENU: Tools/Debug Trace: ...

for example

MENU: Tools/Trace: Add Func trace line

 

this is something like you need

but of course this is not exactly what you need, becasue this function are not created for trace/debug variables

[MHz]

michaelslamet,
So I guess you did not see my relic >_DebugGlobalVars() from 2006. It seems to work in the beta but not 3.3.8.1. Perhaps I was ahead of my time.

Dumping Global variables from a function is easy though doing Local variables is something else. The debug code running in the script may need to be in the function of choice to get the Locals variables for that function.

Here is something more current with StringRegExp to help make it more efficient.

expandcollapse popup

#include <array.au3>
OnAutoItExitRegister('_DumpGlobalVars')

Global _
    $string = 'This is a string with a @TAB' & @TAB & 'and it ends with @CRLF' & @CRLF, _
    $array[11], _
    $binary = StringToBinary($string), _
    $bool = True, _
    $false = False, _
    $float = 12.01, _
    $hex = Hex(13), _
    $hwnd = WinGetHandle("[CLASS:Shell_TrayWnd]"), _
    $int = 14, _
    $keyword = Default, _
    $number = Number(15.01), _
    $ptr = Ptr(16), _
    $struct = DllStructCreate('char[' & 65536 & ']'), _
    $true = True

Exit

Func _DumpGlobalVars()
    Local $__content, $__string, $__variable, $__format = '%-10s%-15s%s'
    $__content =  StringRegExpReplace(FileRead(@ScriptFullPath), '(*ANYCRLF);.*', '')
    $__content =  StringRegExp($__content, '(?<=\$)\w+?\b', 3)
    If IsArray($__content) Then
        $__content = _ArrayUnique($__content)
        _ArraySort($__content)
        $__string = StringFormat($__format, 'TYPE', 'VARIABLE', 'VALUE') & @CRLF
        For $__variable In $__content
            If IsDeclared($__variable) = 1 Then
                $__string &= StringFormat($__format, VarGetType(Eval($__variable)), '$' & $__variable, Eval($__variable)) & @CRLF
            EndIf
        Next
        ConsoleWrite($__string & @CRLF)
    Else
        ConsoleWriteError('No variables found' & @CRLF)
    EndIf
EndFunc

It will dump all Globals to the console when the script has exited as the setting of OnAutoItExitRegister does this.

This is the output from the example:

TYPE      VARIABLE       VALUE
Array     $array         
Binary    $binary        0x54686973206973206120737472696E6720776974682061204054414209616E6420697420656E64732077697468204043524C460D0A
Bool      $bool          True
Bool      $false         False
Double    $float         12.01
String    $hex           0000000D
Ptr       $hwnd          0x0001007E
Int32     $int           14
Keyword   $keyword       Default
Double    $number        15.01
Ptr       $ptr           0x00000010
String    $string        This is a string with a @TAB   and it ends with @CRLF

DLLStruct $struct        
Bool      $true          True

[mLipok]

@MHz

thank you for this script, it is really very useful

 

ps.

have you thought about adding it to the "Example Scripts"

I think it's worth

 

EDIT: typo

EDIT2:

sorry I see

it is on example script

Edited September 17, 2013 by mlipok

[michaelslamet]

@MHz,

This is impressing!

Any change to display those vars name and their content when the script is compiled?

I tried it, it run well on SciTE but display only header (TYPE             VARIABLE              VALUE) when compiled

Thanks!

[MHz]

Thanks for the compliment.

The FileRead will not work well at all on a binary file. It relies on you running the source as au3. So I can not satisfy your request.

[mLipok]

 

yes it is possible

 

look in scite

MENU: Tools/Debug ...

MENU: Tools/Trace: ...

MENU: Tools/Debug Trace: ...

for example

MENU: Tools/Trace: Add Func trace line

 

this is something like you need

but of course this is not exactly what you need, becasue this function are not created for trace/debug variables

 

@michaelslamet

you need a tool what I mention

[MHz]

Any change to display those vars name and their content when the script is compiled?

I tried it, it run well on SciTE but display only header (TYPE             VARIABLE              VALUE) when compiled

As a thought. You could FileInstall the source from the compiled script and read from that one instead.

So the function would be

expandcollapse popup

#include <array.au3>
OnAutoItExitRegister('_DumpGlobalVars')

Global _
    $string = 'This is a string with a @TAB' & @TAB & 'and it ends with @CRLF' & @CRLF, _
    $array[11], _
    $binary = StringToBinary($string), _
    $bool = True, _
    $false = False, _
    $float = 12.01, _
    $hex = Hex(13), _
    $hwnd = WinGetHandle("[CLASS:Shell_TrayWnd]"), _
    $int = 14, _
    $keyword = Default, _
    $number = Number(15.01), _
    $ptr = Ptr(16), _
    $struct = DllStructCreate('char[' & 65536 & ']'), _
    $true = True

Exit

Func _DumpGlobalVars()
    Local $__content, $__path, $__string, $__variable, $__format = '%-10s%-15s%s'
    If @Compiled Then
        If FileExists(StringTrimRight(@ScriptFullPath, 4) & '.au3') Then
            $__path = StringTrimRight(@ScriptFullPath, 4) & '.au3'
        Else
            Return 0
        EndIf
    Else
        $__path = @ScriptFullPath
    EndIf
    $__content =  StringRegExpReplace(FileRead($__path), '(*ANYCRLF);.*', '')
    $__content =  StringRegExp($__content, '(?<=\$)\w+?\b', 3)
    If IsArray($__content) Then
        $__content = _ArrayUnique($__content)
        _ArraySort($__content)
        $__string = StringFormat($__format, 'TYPE', 'VARIABLE', 'VALUE') & @CRLF
        For $__variable In $__content
            If IsDeclared($__variable) = 1 Then
                $__string &= StringFormat($__format, VarGetType(Eval($__variable)), '$' & $__variable, Eval($__variable)) & @CRLF
            EndIf
        Next
        ConsoleWrite($__string & @CRLF)
    Else
        ConsoleWriteError('No variables found' & @CRLF)
    EndIf
EndFunc

So if I run that compiled where the source is in the same directory and with same base name, then running the command "compiledscript.exe > out.txt" will output the variables to the out.txt file.

[mLipok]

This script is still developing here:

'?do=embed' frameborder='0' data-embedContent>>