A customized menu and toolbar

[EKY32]

Hey there, i'm using Win 7 and this window's menu seems to be themed as Win 8 style how is that?

and how to create exactly such toolbar with search bar in it?

 

thank you.

[EKY32]

Any help of any kind please about customizing gui theme or creating controls like the above?

Edited September 25, 2013 by EKY32

[JLogan3o13]

The only thing close that I am aware of is Trancexx's Ribbon UDF in the Examples section.

 

Edit:

Edited September 25, 2013 by JLogan3o13

[EKY32]

thank you, but it's soo far than a Ribbon.

[JLogan3o13]

The point was that is as close as I have seen to modifying the menu system on the forum. Most everything else relies on the standard-issue Windows menu. Someone may wander along and prove me wrong however.

[Melba23]

EKY32,

You could do something like this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <WinAPI.au3>

; Create main GUI
$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput("", 330, 0, 150, 20)
$cButton = GUICtrlCreateButton("Go", 480, 0, 20, 20)

; Create menu GUI
$hMenu_Win = GUICreate("", 330, 20, -1, -1, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)

$mFile = GUICtrlCreateMenu("File")
$mFile_Exit = GUICtrlCreateMenuItem("Exit", $mFile)
$mOptions = GUICtrlCreateMenu("Options")
$mOptions_Test = GUICtrlCreateMenuItem("Test", $mOptions)
$mHelp = GUICtrlCreateMenu("Help")
$mHelp_About = GUICtrlCreateMenuItem("About", $mHelp)
; Move to correct position
$aMain_Pos = WinGetPos($hGUI)
Global $iBorder = _WinAPI_GetSystemMetrics(8) ; Border width
Global $iBar = _WinAPI_GetSystemMetrics(4) ; Title bar height
WinMove($hMenu_Win, "", $aMain_Pos[0] + $iBorder, $aMain_Pos[1] + $iBorder + $iBar)
GUISetState(@SW_SHOW, $hMenu_Win)

; Show main GUI
GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mFile_Exit
            Exit
        Case $mOptions_Test
            MsgBox($MB_SYSTEMMODAL, "Test", "Testing")
        Case $mHelp_About
            MsgBox($MB_SYSTEMMODAL, "Hi", "Any use at all?")
        Case $cButton
            $sSearch_Text = GUICtrlRead($cInput)
            If $sSearch_Text Then
                MsgBox($MB_SYSTEMMODAL, "Search", $sSearch_Text)
            EndIf
    EndSwitch
WEnd

Any use?

M23