_FileWriteFromArray not working as expected

[charon]

I just want to write the contents of a 2D array to a file with _FileWriteFromArray but the results are missing column 3

I have a 2D Array called $Before_Array which contains just one row and 4 columns counting zero. 

Here are the contents:   _ArrayDisplay($Before_Array, "Before: ")

Row 0   

Col 0:  |

Col 1:  Adobe Flash Player 11 Plugin   

Col 2:  C:WindowsSysWOW64MacromedFlashFlashUtil32_11_8_800_168_Plugin.exe -maintain plugin

Col 3:  11.8.800.168

;_FileWriteFromArray($output, $Before_Array)

_FileWriteFromArray($output, $Before_Array,0,0,",")

Results in output file:

|, Adobe Flash Player 11 Plugin,C:WindowsSysWOW64MacromedFlashFlashUtil32_11_8_800_168_Plugin.exe -maintain plugin

Why am I missing column 3 in the results?

[water]

IIRC this is a know bug. Can you download the latest beta and try again?

[BrewManNH]

_FileWriteFromArray prior to some of the beta versions has a bug in it. Below is the corrected function from the beta version.
 

expandcollapse popup

Func _FileWriteFromArray($sFilePath, Const ByRef $aArray, $iBase = Default, $iUBound = Default, $sDelimeter = "|")
    ; Check if we have a valid array as input
    If Not IsArray($aArray) Then Return SetError(2, 0, 0)

    ; Check the number of dimensions
    Local $iDims = UBound($aArray, 0)
    If $iDims > 2 Then Return SetError(4, 0, 0)

    ; Determine last entry of the array
    Local $iLast = UBound($aArray) - 1
    If $iUBound = Default Or $iUBound > $iLast Then $iUBound = $iLast
    If $iBase < 0 Or $iBase = Default Then $iBase = 0
    If $iBase > $iUBound Then Return SetError(5, 0, 0)
    If $sDelimeter = Default Then $sDelimeter = "|"

    ; Open output file for overwrite by default, or use input file handle if passed
    Local $hFileOpen = $sFilePath
    If IsString($sFilePath) Then
        $hFileOpen = FileOpen($sFilePath, $FO_OVERWRITE)
    EndIf
    If $hFileOpen = -1 Then Return SetError(1, 0, 0)

    ; Write array data to file
    Local $iError = 0
    Switch $iDims
        Case 1
            For $i = $iBase To $iUBound
                If FileWrite($hFileOpen, $aArray[$i] & @CRLF) = 0 Then
                    $iError = 3
                    ExitLoop
                EndIf
            Next
        Case 2
            Local $sTemp
            Local $iCols = UBound($aArray, 2)
            For $i = $iBase To $iUBound
                $sTemp = $aArray[$i][0]
                For $j = 1 To $iCols - 1
                    $sTemp &= $sDelimeter & $aArray[$i][$j]
                Next
                If FileWrite($hFileOpen, $sTemp & @CRLF) = 0 Then
                    $iError = 3
                    ExitLoop
                EndIf
            Next
    EndSwitch

    ; Close file only if specified by a string path
    If IsString($sFilePath) Then FileClose($hFileOpen)

    ; Return results
    If $iError Then Return SetError($iError, 0, 0)
    Return 1
EndFunc   ;==>_FileWriteFromArray

[Melba23]

charon,

Have you tried using the Beta version of the UDF? The function has been rewritten as follows:

expandcollapse popup

Func _FileWriteFromArray($sFilePath, Const ByRef $aArray, $iBase = Default, $iUBound = Default, $sDelimeter = "|")
    ; Check if we have a valid array as input
    If Not IsArray($aArray) Then Return SetError(2, 0, 0)

    ; Check the number of dimensions
    Local $iDims = UBound($aArray, 0)
    If $iDims > 2 Then Return SetError(4, 0, 0)

    ; Determine last entry of the array
    Local $iLast = UBound($aArray) - 1
    If $iUBound = Default Or $iUBound > $iLast Then $iUBound = $iLast
    If $iBase < 0 Or $iBase = Default Then $iBase = 0
    If $iBase > $iUBound Then Return SetError(5, 0, 0)
    If $sDelimeter = Default Then $sDelimeter = "|"

    ; Open output file for overwrite by default, or use input file handle if passed
    Local $hFileOpen = $sFilePath
    If IsString($sFilePath) Then
        $hFileOpen = FileOpen($sFilePath, $FO_OVERWRITE)
    EndIf
    If $hFileOpen = -1 Then Return SetError(1, 0, 0)

    ; Write array data to file
    Local $iError = 0
    Switch $iDims
        Case 1
            For $i = $iBase To $iUBound
                If FileWrite($hFileOpen, $aArray[$i] & @CRLF) = 0 Then
                    $iError = 3
                    ExitLoop
                EndIf
            Next
        Case 2
            Local $sTemp
            Local $iCols = UBound($aArray, 2)
            For $i = $iBase To $iUBound
                $sTemp = $aArray[$i][0]
                For $j = 1 To $iCols - 1
                    $sTemp &= $sDelimeter & $aArray[$i][$j]
                Next
                If FileWrite($hFileOpen, $sTemp & @CRLF) = 0 Then
                    $iError = 3
                    ExitLoop
                EndIf
            Next
    EndSwitch

    ; Close file only if specified by a string path
    If IsString($sFilePath) Then FileClose($hFileOpen)

    ; Return results
    If $iError Then Return SetError($iError, 0, 0)
    Return 1
EndFunc   ;==>_FileWriteFromArray

The parameters are now as follows:

Parameters
$sFilePath Path of the file to write to, or a file handle returned by FileOpen(). 
$aArray The array to be written to the specified file. 
$iBase [optional] Start array index to read, normally set to 0 or 1. Default is the Default keyword. 
$iUbound [optional] Set to the last record you want to write to the File. Default is the Default keyword (whole array.) 
$sDelimeter [optional] Delimiter character(s) for 2-dimension arrays. Default is "|".

Does that work?

M23

[charon]

IIRC this is a know bug. Can you download the latest beta and try again?

Where do I get the beta version or UDF. I am currently using  AutoIt v3.3.8.1   I will google it.

[BrewManNH]

Where do I get the beta version or UDF. I am currently using  AutoIt v3.3.8.1   I will google it.

You need new glasses, it's been posted here twice now.

[charon]

charon,

Have you tried using the Beta version of the UDF? The function has been rewritten as follows:

expandcollapse popup

Func _FileWriteFromArray($sFilePath, Const ByRef $aArray, $iBase = Default, $iUBound = Default, $sDelimeter = "|")
    ; Check if we have a valid array as input
    If Not IsArray($aArray) Then Return SetError(2, 0, 0)

    ; Check the number of dimensions
    Local $iDims = UBound($aArray, 0)
    If $iDims > 2 Then Return SetError(4, 0, 0)

    ; Determine last entry of the array
    Local $iLast = UBound($aArray) - 1
    If $iUBound = Default Or $iUBound > $iLast Then $iUBound = $iLast
    If $iBase < 0 Or $iBase = Default Then $iBase = 0
    If $iBase > $iUBound Then Return SetError(5, 0, 0)
    If $sDelimeter = Default Then $sDelimeter = "|"

    ; Open output file for overwrite by default, or use input file handle if passed
    Local $hFileOpen = $sFilePath
    If IsString($sFilePath) Then
        $hFileOpen = FileOpen($sFilePath, $FO_OVERWRITE)
    EndIf
    If $hFileOpen = -1 Then Return SetError(1, 0, 0)

    ; Write array data to file
    Local $iError = 0
    Switch $iDims
        Case 1
            For $i = $iBase To $iUBound
                If FileWrite($hFileOpen, $aArray[$i] & @CRLF) = 0 Then
                    $iError = 3
                    ExitLoop
                EndIf
            Next
        Case 2
            Local $sTemp
            Local $iCols = UBound($aArray, 2)
            For $i = $iBase To $iUBound
                $sTemp = $aArray[$i][0]
                For $j = 1 To $iCols - 1
                    $sTemp &= $sDelimeter & $aArray[$i][$j]
                Next
                If FileWrite($hFileOpen, $sTemp & @CRLF) = 0 Then
                    $iError = 3
                    ExitLoop
                EndIf
            Next
    EndSwitch

    ; Close file only if specified by a string path
    If IsString($sFilePath) Then FileClose($hFileOpen)

    ; Return results
    If $iError Then Return SetError($iError, 0, 0)
    Return 1
EndFunc   ;==>_FileWriteFromArray

The parameters are now as follows:

Parameters
$sFilePath Path of the file to write to, or a file handle returned by FileOpen(). 
$aArray The array to be written to the specified file. 
$iBase [optional] Start array index to read, normally set to 0 or 1. Default is the Default keyword. 
$iUbound [optional] Set to the last record you want to write to the File. Default is the Default keyword (whole array.) 
$sDelimeter [optional] Delimiter character(s) for 2-dimension arrays. Default is "|".

Does that work?

M23

 

got it thanks...