Remove first few lines from GUICtrlCreateEdit

[thexshadow]

I have an GUICtrlCreateEdit which is full of text, I want to remove the first 5 lines at the top of it. Is there a way to do that?

Edited September 29, 2013 by thexshadow

[TheSaint]

Being on Linux at the moment, I don't have access to the Help file, and I cannot seem to find an online Link to the UDF's (User Defined Functions). It is possible the Edit UDF has what you need, but I cannot remember.

If not, then you can start with the StringSplit function, with the appropriate Carriage Return as divider/separator.

Then do a character count on the first 5 array returns (i.e $cnt = StringLen($array[1]) up to $array[5])

With the total of each five counts, use StringTrimLeft from your full read of the Edit text, then write the result back.

The only obvious problem you will have, is if you don't have the required Carriage Returns.

In that case you are out of luck, though there might be a Function that can just return the string for the width of the Edit (single visible line). Unless of course, you have an idea of what the last few words of line five will be, and they are unique enough to use StringSplit with them.

EDIT

This is just one of a few approaches that could be used. I'm sure that someone will eventually come along with others before too long, but the above should give you some ideas (and a possible solution) to start with.

Edited September 29, 2013 by TheSaint

[AutID]

Read and store your data in a variable. Remove the useless data, in your case the 5 first lines, using string function and then set the data back to the edit.

[guinness]

For the novice user, GUICtrlRead(), StringSplit() (splitting at @CRLF) and _ArrayDelete() should give you an idea.

[TheSaint]

Read and store your data in a variable. Remove the useless data, in your case the 5 first lines, using string functions and then set the data back to the edit.

If you are going to supply a simplistic summary (of essentially what I just said), then you should take care to make sure you don't confuse, by using string function, instead of string functions. Because there is a String function.

NOTE - I quite realize you probably didn't see my post until after you did yours.

[MHz]

GuiCtrlRead the data from the control.

Modify the string with StringRegExpReplace like in this example

Global $lines
For $1 = 1 To 10
    $lines &= 'line ' & $1 & @CRLF
Next
MsgBox(0, 'Step 1', $lines)

$lines = StringRegExpReplace($lines, '.*?[\r\n]+', '', 5)
MsgBox(0, 'Step 2', $lines)

and then GuiCtrlSetData to the control with the new string.

[Gianni]

or, maybe this is easier
You can search for the location of the fifth @LF, and if there is, keep only what follows the @LF, in this way:

$fifth_LF = StringInStr(GUICtrlRead($myGUICtrlEdit), @LF, 0, 5) ; find the position of fifth @LF (it mark the end of line 5)
    If $fifth_LF Then ; if there are at least 5 lines then keep only what follow
        GUICtrlSetData($myGUICtrlEdit, StringRight(GUICtrlRead($myGUICtrlEdit), StringLen(GUICtrlRead($myGUICtrlEdit)) - $fifth_LF ))
    EndIf

bye

EDIT:

opss, I missed the previous post
MHz's solution is much better!

Edited September 29, 2013 by PincoPanco

[TheSaint]

If you used the right type of font, then you could always rely on the same number of characters in a line, which would work well enough if carriage returns are missing.

All that said, there appears to be suitable functions in the GuiEdit Management section of the UDF section of th Help file.

[thexshadow]

Ok I got that workign good, is there a better way to do this? This way it scrolls all the way back to the top, which is very inconvienent.

Case $msg = $Exr
            $exrun = Run('"' & @ComSpec & '" /c "' removed, @DesktopDir, @SW_HIDE)
            While 1
               $out = StdoutRead($exrun)
               If @error then exitloop
               GUICtrlSetData($BM,$out,1)
            WEnd
            $Read = GUICtrlRead($BM)
            $StrReplace = StringRegExpReplace($Read, '.*?[\r\n]+', '', 6)
            GUICtrlSetData($BM, $StrReplace)

Also, is there a way to remove "- 1272 files found in 0 seconds
coverage file 0 75% 11547573 15236051" and then add "gutils.lua" back to "00e69000 8567 scriptsutilsaidebu". I dont know if this is possable.

00e57000 453547     scripts\network\wrld.xml
  00e69000 8567       scripts\utils\aidebu
- 1272 files found in 0 seconds
  coverage file 0    75%   11547573   15236051  
gutils.lua
  00e6a000 8778       scripts\utils\containers.lua

Edited September 29, 2013 by thexshadow

[thexshadow]

bump?

[MHz]

$text = _
'  00e57000 453547     scripts\network\wrld.xml' & @CRLF & _
'  00e69000 8567       scripts\utils\aidebu' & @CRLF & _
'- 1272 files found in 0 seconds' & @CRLF & _
'  coverage file 0    75%   11547573   15236051  ' & @CRLF & _
'gutils.lua' & @CRLF & _
'  00e6a000 8778       scripts\utils\containers.lua'

$replaced = StringRegExpReplace($text, _
    '- \d* files found in \d* seconds[\r\n]*' & _
    '\s*coverage file \d*\s*\d*%\s*\d*\s*\d*\s*[\r\n]*' _
    , '' _
)
ConsoleWrite($replaced & @CRLF)
MsgBox(0, '', $replaced)

#cs - RegExp pattern
\d*     Any digit, 0 or more
\s*     Any whitespace, 0 or more
[\r\n]* Any CR or LF, 0 or more
The rest are treated as literals
See StringRegExp in help file for concise information
#ce

ConsoleWrite Output

00e57000 453547     scripts\network\wrld.xml
  00e69000 8567       scripts\utils\aidebu
gutils.lua
  00e6a000 8778       scripts\utils\containers.lua

And remember, I am not a pinball table to be bumped.

[thexshadow]

$text = _
'  00e57000 453547     scripts\network\wrld.xml' & @CRLF & _
'  00e69000 8567       scripts\utils\aidebu' & @CRLF & _
'- 1272 files found in 0 seconds' & @CRLF & _
'  coverage file 0    75%   11547573   15236051  ' & @CRLF & _
'gutils.lua' & @CRLF & _
'  00e6a000 8778       scripts\utils\containers.lua'

$replaced = StringRegExpReplace($text, _
    '- \d* files found in \d* seconds[\r\n]*' & _
    '\s*coverage file \d*\s*\d*%\s*\d*\s*\d*\s*[\r\n]*' _
    , '' _
)
ConsoleWrite($replaced & @CRLF)
MsgBox(0, '', $replaced)

#cs - RegExp pattern
\d*     Any digit, 0 or more
\s*     Any whitespace, 0 or more
[\r\n]* Any CR or LF, 0 or more
The rest are treated as literals
See StringRegExp in help file for concise information
#ce

ConsoleWrite Output

00e57000 453547     scripts\network\wrld.xml
  00e69000 8567       scripts\utils\aidebu
gutils.lua
  00e6a000 8778       scripts\utils\containers.lua

And remember, I am not a pinball table to be bumped.

 

Thanks for that, but is there a way to combine this:

00e69000 8567       scripts\utils\aidebu
gutils.lua

So it looks like:

00e69000 8567       scripts\utils\aidebugutils.lua

But its never going to be the same, so next time it could be:

037a9000 816        char\text\i
nvertstripes.dds

Then i would want it to turn to:

037a9000 816        char\text\invertstripes.dds

And, I dont know, but is there a way to combine multiple StringRegExpReplace's?

Edited October 4, 2013 by thexshadow

[MHz]

That can be combined. I thought it was a bit odd the gutils.lua line though I could only follow the instruction. The regex pattern does not relate to the other strings so a little variation there does not matter. What matters is what it does match. So, the change you want is to also match the preceding newline characters. This is what [rn]* does so it just needs to be added to the start of the pattern.

$text = _
'  00e57000 453547     scripts\network\wrld.xml' & @CRLF & _
'  00e69000 8567       scripts\utils\aidebu' & @CRLF & _
'- 1272 files found in 0 seconds' & @CRLF & _
'  coverage file 0    75%   11547573   15236051  ' & @CRLF & _
'gutils.lua' & @CRLF & _
'  00e6a000 8778       scripts\utils\containers.lua'

$replaced = StringRegExpReplace($text, _
    '[\r\n]*- \d* files found in \d* seconds[\r\n]*' & _
    '\s*coverage file \d*\s*\d*%\s*\d*\s*\d*\s*[\r\n]*' _
    , '' _
)
ConsoleWrite($replaced & @CRLF)
MsgBox(0, '', $replaced)

00e57000 453547     scripts\network\wrld.xml
  00e69000 8567       scripts\utils\aidebugutils.lua
  00e6a000 8778       scripts\utils\containers.lua

You can have multiple StringRegExpReplace's to reuse the same variable and thus the contents in the variable change.

$var = 'dog and cat'
$var = StringRegExpReplace($var, 'and\scat', '& mouse')
$var = StringRegExpReplace($var, 'dog\s&', 'cat chases')
ConsoleWrite($var & @CRLF)
MsgBox(0, 'dog and cat', $var)

cat chases mouse

The s in the pattern matches whitespace. The rest is literal characters.

[thexshadow]

Thanks for that, One question though, If I want to combine these together.

$StrReplace1 = StringRegExpReplace(GUICtrlRead($Output), '.*?[\r\n]+', '', 8)
GUICtrlSetData($Output, $StrReplace1)
$StrReplace2 = StringRegExpReplace(GUICtrlRead($Output), '[\r\n]*- \d* files found in \d* seconds[\r\n]*' & '\s*coverage file \d*\s*\d*%\s*\d*\s*\d*\s*[\r\n]*', '')
GUICtrlSetData($Output, $StrReplace2)

Would I have to go like this, because this only reads the bottom strreplace and not the top one.

$StrReplace = StringRegExpReplace(GUICtrlRead($Output), '.*?[\r\n]+', '', 8)
$StrReplace = StringRegExpReplace(GUICtrlRead($Output), '[\r\n]*- \d* files found in \d* seconds[\r\n]*' & '\s*coverage file \d*\s*\d*%\s*\d*\s*\d*\s*[\r\n]*', '')
GUICtrlSetData($Output, $StrReplace)

Or something like this?

$StrReplace = StringRegExpReplace(GUICtrlRead($Output), '[\r\n]*- \d* files found in \d* seconds[\r\n]*' & '\s*coverage file \d*\s*\d*%\s*\d*\s*\d*\s*[\r\n]*' & '.*?[\r\n]+', '', 8)
GUICtrlSetData($Output, $StrReplace)

Edited October 5, 2013 by thexshadow

[MHz]

Removing the 1st 8 lines would best be done in a separate use of StringRegExpReplace as it has little in common with replacing the other strings.

Your 2nd code option is perhaps close with a small change of using $StrReplace from the 1st StringRegExpReplace and using it as the input of the 2nd StringRegExpReplace.

$StrReplace = StringRegExpReplace(GUICtrlRead($Output), '.*?[\r\n]+', '', 8)
$StrReplace = StringRegExpReplace($StrReplace, '[\r\n]*- \d* files found in \d* seconds[\r\n]*' & '\s*coverage file \d*\s*\d*%\s*\d*\s*\d*\s*[\r\n]*', '')
GUICtrlSetData($Output, $StrReplace)

It would the same nesting the function call like this

$StrReplace = StringRegExpReplace( _
    StringRegExpReplace(GUICtrlRead($Output), '.*?[\r\n]+', '', 8), _
    '[\r\n]*- \d* files found in \d* seconds[\r\n]*' & _
    '\s*coverage file \d*\s*\d*%\s*\d*\s*\d*\s*[\r\n]*', '' _
)
GUICtrlSetData($Output, $StrReplace)

[thexshadow]

Oh cool, I didnt know you could do it like that. Thanks!