How to position inputbox always to bottom right corner above taskbar?

[augustspies]

I found this code while searching through the forums

used to positon a gui to the bottom right corner just

above the taskbar.

How would I be able to alter this to work for an input

box?

#include <Array.au3>
#include <GUIConstantsEx.au3>
$aTaskbar = WinGetPos("[CLASS:Shell_TrayWnd]", "")
$GUI = GUICreate("Test", 259, 83, @DesktopWidth, @DesktopHeight)
$Text = GUICtrlCreateLabel("Test", 88, 24, 58, 36)
GUICtrlSetFont(-1, 20, 400, 0, "MS Sans Serif")
$aWin = WinGetPos($GUI)
WinMove($GUI, "", @DesktopWidth - $aWin[2] - 4, @DesktopHeight - $aWin[3] - $aTaskbar[3] - 4)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

[BrewManNH]

InputBox has a left and top parameter which tells it where to show on the screen.

[jguinch]

Hi

$aTaskbar = WinGetPos("[CLASS:Shell_TrayWnd]", "")
InputBox ( "test", "test" , "" , "" , $width , $height , @DesktopWidth - $width , @DesktopHeight - $height - $aTaskbar[3]   )

[guinness]

I use this to get the working desktop area...

#include <Array.au3>
#include <WinAPI.au3>

Local $aArray = _GetDesktopArea()
_ArrayDisplay($aArray)

; Get the working visible area of the desktop, this doesn't include the area covered by the taskbar.
Func _GetDesktopArea()
    Local Const $SPI_GETWORKAREA = 48
    Local $tWorkArea = DllStructCreate($tagRECT)
    _WinAPI_SystemParametersInfo($SPI_GETWORKAREA, 0, DllStructGetPtr($tWorkArea))
    Local $aReturn[4] = [DllStructGetData($tWorkArea, 'Left'), DllStructGetData($tWorkArea, 'Top'), _
            DllStructGetData($tWorkArea, 'Right') - DllStructGetData($tWorkArea, 'Left'), DllStructGetData($tWorkArea, 'Bottom') - DllStructGetData($tWorkArea, 'Top')]
    Return $aReturn
EndFunc   ;==>_GetDesktopArea