GUI, recording inputted text?

[lava]

Hi, i'm still a really big newbie with autoit and any scripting language, and i'm having trouble figuring out how to do what I want with a GUI.

Okay, I want to be able to make a GUI that records input into the boxes, and enters the input into a msgbox. But I want it to be able to record it in the same msgbox everytime I enter new input, is that possible?

If there is already another topic like this or if i'm doing something wrong just tell me please

     Thanks

[Melba23]

lava

Welcome to the AutoIt forum.

This should give you an idea of how to go about it:

#include <GUIConstantsEx.au3>
#include <Constants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput("", 10, 10, 480, 20)

$cButton = GUICtrlCreateButton("Read", 10, 100, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            $sText = GUICtrlRead($cInput)
            If $sText <> "" Then
                MsgBox($MB_SYSTEMMODAL, "Text", $sText)
                GUICtrlSetData($cInput, "")
            EndIf
            GUICtrlSetState($cInput, $GUI_FOCUS)
    EndSwitch

WEnd

Try to follow the code by using the Help file - but please ask if you have any questions.

M23

[lava]

Thanks so much for your help I can get what I need with this, thanks again!

[Melba23]

lava,

Glad I could help.

M23

[lava]

#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode")  ; Changes to OnEvent mode
$mainwindow = InputBox("Kick Manager","Who did you kick?","","",250,250); Would enter what needs to be recorded.

GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked")
GUICtrlCreateLabel("Kick manager", 30, 10)
$okbutton = GUICtrlCreateButton("OK", 70, 50, 60); Creates the OK button
GUICtrlSetOnEvent($okbutton, "OKButton")
GUISetState(@SW_SHOW)

While 1
  Sleep(1000)  ; Idle around
WEnd

Func OKButton(); This is what happens when The Okay button is pressed.
  GUIGetMsg ($mainwindow) ;Wouldn't this get the input from the InputBox?
MsgBox (5,"kicked","you kicked..."&$mainwindow) ; Then this would display it.
EndFunc

Func CLOSEClicked();exits the gui
  Exit
EndFunc

Okay it didn't work as I planned, but I looked at the help file and decided to start from scratch, and I worked off the example, and it's not doing what I want, It displays the input box and nothing afterwards, :/ I feel like the answer is in front of me but I cant see it, help please?

[Melba23]

lava,

in that example you are creating an InputBox which creates a dialog to do most of the work for you - but you were mixing code for a user-created GUI in there too.

Here is your script modified to work with an InputBox:

#include <Constants.au3>

While 1
    ; InputBox is a standalone dialog which pauses the script until you press a button
    $sText = InputBox("Kick Manager","Who did you kick?","","",250,250); Would enter what needs to be recorded.
    ; Was there any text?
    If $sText Then
        ; Yes
        MsgBox ($MB_SYSTEMMODAL,"kicked","you kicked..." & $sText) ; Then this would display it.
    Else
        ; No
        Exit
    EndIf
WEnd

And here with a user-created GUI:

#include <GUIConstantsEx.au3>
#include <Constants.au3>

Opt("GUIOnEventMode", 1)  ; Changes to OnEvent mode  <<<<<<< Do not forget the parameter

$mainwindow = GUICreate("Kick Manager", 250, 250) ; Create a GUI <<<<<<<<<<<<<<<<<<<<
 GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked")
$cInput = GUICtrlCreateInput("", 10, 30, 230, 20) ; Create an input <<<<<<<<<<<<<<<<<<<<<
$okbutton = GUICtrlCreateButton("OK", 70, 70, 60); Creates the OK button
GUICtrlSetOnEvent($okbutton, "OKButton")
GUISetState(@SW_SHOW)

While 1
  Sleep(1000)  ; Idle around
WEnd

Func OKButton(); This is what happens when The Okay button is pressed.
    ;GUIGetMsg ($mainwindow) ;Wouldn't this get the input from the InputBox?
    $sText = GUICtrlRead($cInput) ; Read the input <<<<<<<<<<<<<<
    ; Was ther any input?
    If $sText Then
        ; Yes
        MsgBox ($MB_SYSTEMMODAL,"kicked","you kicked..." & $sText) ; Then this would display it.
    Else
        ; No
        Exit
    EndIf
EndFunc

Func CLOSEClicked();exits the gui
  Exit
EndFunc

As you are really new to all this (which is not a problem as we all were at some point) reading the Help file (at least the first few sections - Using AutoIt, Tutorials and the first couple of References) will help you enormously. You should also look at this excellent tutorial - you will find other tutorials in the Wiki (the link is at the top of the page). There are even video tutorials on YouTube if you prefer watching to reading.

M23

[lava]

Oh   Gah I must've stared at it so long it went to my head. Thanks again you're the best I can surely work off of these , and I have read over the examples in the help file but it's hard for me to learn without seeing it myself and learning from error, i'm not too bad at actual mouse/cursor scripts but GUIs got the best of me 

[Bert]

is this for a game? I see "kick manager" in your script and wonder if you intend this for a game server.

[BrewManNH]

You're fishing in a year old posting? 

[Melba23]

DarthCookieMonster,

As I helped the OP I am pretty sure I did not think it was a game at the time - and I still do not. I lock threads when there is proof that they are game-related, not just mere suspicion - going down that road is not a direction I, or I hope anyone else here, wants to take.

M23