Small regexpreplace issue

[Chimaera]

Im trying to replace some characters which violate windows filenames with an underscore

For $i = 0 To UBound($aSubItemCSV) - 1
        If StringRegExp($aSubItemCSV[$i][0], '[\/\?<>\\\:\|\*"]') Then
            StringRegExpReplace($aSubItemCSV[$i][0], '[\/\?<>\\\:\|\*"]', '_') ;<<<<<<<<<<<<<<<<<<<<<<<<<<<
        EndIf
        $sNewPath = @ScriptDir & "\" & $sFolderName & "\" & $aSubItemCSV[$i][0] & ".csv"
        $hFile = FileOpen($sNewPath, BitOR(8, 1))
        If $hFile = -1 Then
            MsgBox(0, "", "Unable to open file")
            Exit
        EndIf

        $iSuccess = FileWrite($hFile, $aSubItemCSV[$i][1])
        FileClose($hFile)
        If $iSuccess = 0 Then
            MsgBox(0, "", "Unable to write to file")
            Exit
        EndIf
    Next

The highlighted line which ive added seems right but when the code runs and it hits a file with one of the forbidden chars it creates a folder with half the filename inside it ;(

Is the regexreplace not right? it seems to be in the helpfile

The chars im trying to change is / ? < > : | " * but czardas wrote the original so im sure thats right

Any thoughts?

[jchd]

You don't assign the result of the highlighted line.

Also the test is superfluous. Do the replace in all case.

[Chimaera]

Ok so i need to assign where it writes the filename

$sNewPath = @ScriptDir & "\" & $sFolderName & "\" & StringRegExpReplace($aSubItemCSV[$i][0], '[\/\?<>\\\:\|\*"]', '_') & ".csv"

That seems to work

Thx

[iCode]

might be worng, but an issue i'm seeing is ":" - i understand escaping the backslash, but you don't need to escape a colon AFAIK, at least not in this case

[Chimaera]

From Msdn for file creation

• The following reserved characters:

  • < (less than)
  • > (greater than)
  • : (colon)
  • " (double quote)
  • / (forward slash)
  • (backslash)
  • | (vertical bar or pipe)
  • ? (question mark)
  • * (asterisk)

Edited November 10, 2013 by Chimaera

[iCode]

that's for folder names, but why does a colon need to be escaped in the exp? he has 3 backslashes, so he is escaping 1 backslash and the colon ( :)

[jchd]

That doesn't hurt to escape any literal character.

[Chimaera]

It started as an error check for folder creation but it is now this which is only about the folder name

For $i = 0 To UBound($aSubItemCSV) - 1
        $sNewPath = @ScriptDir & "\" & $sFolderName & "\" & StringRegExpReplace($aSubItemCSV[$i][0], '[\/\?<>\\\:\|\*"]', '-') & ".csv"
        $hFile = FileOpen($sNewPath, BitOR(8, 1))
        If $hFile = -1 Then
            MsgBox(0, "", "Unable to open file")
            Exit
        EndIf

        $iSuccess = FileWrite($hFile, $aSubItemCSV[$i][1])
        FileClose($hFile)
        If $iSuccess = 0 Then
            MsgBox(0, "", "Unable to write to file")
            Exit
        EndIf
    Next

[mikell]

iCode,

In fact the backslash is the only character from this list which needs to be escaped

Local $n, $str = '<>:"/\|?*'
Do
  $n += 1
  $str = StringRegExpReplace($str, '[/?<>\\:|*"]', $n, 1)
Until not @extended
Msgbox(0,"", $str)