GUISetAccelerators with disabled control

[binhnx]

I wonder how GuiSetAccelerators work with disabled control.

In Win32 world, if control (button, menu) is disabled, the acclerator is also disabled. But in AutoIt, it seems that disabling a control does not affect accelerator, so event associated with control is still fired.

I wonder if this is a 'feature' in AutoIT or it's just a bug?

Edited November 16, 2013 by binhnx

[Melba23]

binhnx,

I imagine this was a design decision when Accel keys were added to Autoit. It is not uncommon in AutoIt for the user to have to monitor the state of controls programatically - look at the Tabs tutorial in the Wiki to see how complex it can get.

It is not too complicated to monitor the control state:

#include <GUIConstantsEx.au3>
#include <Constants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cButton = GUICtrlCreateButton("Test", 10, 10, 80, 30)
$cState = GUICtrlCreateButton("Disable", 10, 100, 80, 30)

GUISetState()

Local $aAccelKeys[1][2] = [["^y", $cButton]]
GUISetAccelerators($aAccelKeys)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            If BitAnd(GUICtrlGetState($cButton), $GUI_ENABLE) Then ; <<<<<<<<<<<<<<<<<<<<<<<<
                MsgBox($MB_SYSTEMMODAL, "Hi", "Button fired")
            EndIf
        Case $cState
            Switch GUICtrlRead($cState)
                Case "Enable"
                    GUICtrlSetState($cButton, $GUI_ENABLE)
                    GUICtrlSetData($cState, "Disable")
                Case Else
                    GUICtrlSetState($cButton, $GUI_DISABLE)
                    GUICtrlSetData($cState, "Enable")
            EndSwitch
    EndSwitch
WEnd

But if you feel strongly that AutoIt should automatically match Accel keys to the associated control state, I suggest opening a Trac ticket (perhaps as a "Feature Request" rather than a "Bug" ) and see what Jon thinks about it. No doubt the answer will depend on the difficulty of implementation.

M23

[binhnx]

@Melba23

Thanks for your reply.

I've opened a ticket, as a 'Feature Request'