Use two variable at same time

[Terenz]

Hi all, it's hard for me to explain what i need so i have create an example:

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("TestForm", 414, 271, 196, 132)
$Label1 = GUICtrlCreateLabel("Label1", 8, 8, 404, 153)
GUICtrlSetFont(-1, 100, 400, 0, "Arial")
$Label2 = GUICtrlCreateLabel("Label2", 0, 160, 285, 108)
GUICtrlSetFont(-1, 70, 400, 0, "Arial")
GUISetState(@SW_SHOW)

;~ _Change_Size($Label1, 10)
;~ _Change_Size($Label2, 10)
Sleep(1000)
_Change_Size(BitOR($Label1, $Label2),10)
_Change_Size(BitXOR($Label1, $Label2),10)
_Change_Size(BitAND($Label1, $Label2),10)
Sleep(1000)

Func _Change_Size($MyLabel, $Size)
    GUICtrlSetFont($MyLabel, $Size, 400, 0, "Arial")
EndFunc

I know i can call 2 times the function, but there is't a way to perform the same operation using only one function? I have try with Bit operator but not work. Is possible or not?

Thanks

Edited November 29, 2013 by Terenz

[BrewManNH]

Use an array, pass the array to the function, loop through the array to find what labels you're wanting to set.

[Terenz]

Using an array does mean i need to rewrite a lot of code. I need to store it in this way:

$Label[1] = GUICtrlCreateLabel("Label1", 8, 8, 404, 153)
$Label[2] = ;etc

Why i can't store directly the variable?

[BrewManNH]

I'm afraid I have no idea what you mean by "store directly the variable".

[Terenz]

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("TestForm", 414, 271, 196, 132)
$Label1 = GUICtrlCreateLabel("Label1", 8, 8, 404, 153)
GUICtrlSetFont(-1, 100, 400, 0, "Arial")
$Label2 = GUICtrlCreateLabel("Label2", 0, 160, 285, 108)
GUICtrlSetFont(-1, 70, 400, 0, "Arial")
GUISetState(@SW_SHOW)

Sleep(1000)
Local $MyArr[3] = [$Label1, $Label2]
_Change_Size($MyArr, 10)
Sleep(1000)

Func _Change_Size($MyLabel, $Size)
    If IsArray($MyLabel) Then
        For $i = 0 To UBound($MyLabel) - 1
            GUICtrlSetFont($MyLabel[$i], $Size, 400, 0, "Arial")
        Next
    Else
        GUICtrlSetFont($MyLabel, $Size, 400, 0, "Arial")
    EndIf
EndFunc   ;==>_Change_Size

Seems work, i think there isn't a way to declare the Local $MyArray when i call the function in one line instead of two.

Edited November 29, 2013 by Terenz

[l3ill]

Hi Terenz

I think you may be looking for a loop?

you want to call the same function over and over again with slight adjustments?

then put it in a  loop...once we know we are on the right track we can come up with some examples...

Bill

[martin]

Using an array is more versatile, but you could do the following to pass the variables the way you want.

 
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("TestForm", 414, 271, 196, 132)
$Label1 = GUICtrlCreateLabel("Label1", 8, 8, 404, 153)
GUICtrlSetFont(-1, 100, 400, 0, "Arial")
$Label2 = GUICtrlCreateLabel("Label2", 0, 160, 285, 108)
GUICtrlSetFont(-1, 70, 400, 0, "Arial")
GUISetState(@SW_SHOW)

Sleep(1000)

_Change_Size($Label1, 10, $Label2, 20);as many IDs and sizes up to 8 pairs
Sleep(1000)

Func _Change_Size($lab1, $Size1, $lab2 = 0, $size2 = 0, $lab3 = 0, $Size3 = 0, $lab4 = 0, $size4 = 0, $lab5 = 0, $Size5 = 0, $lab6 = 0, $size6 = 0, $lab7 = 0, $Size7 = 0, $lab8 = 0, $size8 = 0)
    Local $ii, $iPairs = Floor(@NumParams / 2)

    For $ii = 1 To $iPairs
        GUICtrlSetFont(Eval("lab" & $ii), Eval("Size" & $ii), "Arial")
    Next
EndFunc   ;==>_Change_Size
 

Edit: Removed  Call("_Change_Size".. and just used _ChangeSize. (Don't know why I used call - proably thinking about Eval)

Edited November 29, 2013 by martin

[DW1]

Alternatively:

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("TestForm", 414, 271, 196, 132)
$Label1 = GUICtrlCreateLabel("Label1", 8, 8, 404, 153)
GUICtrlSetFont(-1, 100, 400, 0, "Arial")
$Label2 = GUICtrlCreateLabel("Label2", 0, 160, 285, 108)
GUICtrlSetFont(-1, 70, 400, 0, "Arial")
GUISetState(@SW_SHOW)

Sleep(1000)
_Change_Size("Label1|10|Label2|20");as many IDs and sizes as you would like
Sleep(1000)

Func _Change_Size($SizeString)
    Local $aSplit = StringSplit($SizeString, '|')
    For $ii = 1 To Floor($aSplit[0] / 2) * 2 Step 2
        GUICtrlSetFont(Eval($aSplit[$ii]), $aSplit[$ii + 1], "Arial")
    Next
EndFunc   ;==>_Change_Size

Edited November 29, 2013 by danwilli