Creating a StringBuffer

[Robinson1]

Is there an other way like this: 

dim $myStringBuff=StringBuff(3)
MsgBox(0, "StringBuff(5)=", $myStringBuff)


;-------------------------------------------------
Func StringBuff( $size, $FillChar="0")
    Local $StringBuffer

    For $i = 1 To $size
        $StringBuffer = $StringBuffer & $FillChar
    Next
    Return $StringBuffer
EndFunc

to easily create a String in Autoit?

Especially 

$StringBuffer = $StringBuffer & $FillChar

is a really bad way to do so regarding the performance.

(each time in the Loop a new string is created and the old one is discarded)

 

Maybe something like this

Local $StringBuffer[$size]
    For $i = 1 To $size
        $StringBuffer[$i] = $FillChar
    Next
        Return $StringBuffer

^-Sample Doesn't work

 

...or

Local $StringBuffer

    For $i = 1 To $size
        _StringAppend($StringBuffer, $FillChar)
    Next
    Return $StringBuffer

were '_StringAppend()' is some Interpreter optimised version that does some kind of redim to $StringBuffer and then append $FillChar

 

[Melba23]

Robinson1,

Have you come across _StringRepeat in the Help file? if not, I suggest taking a look.

M23

[Robinson1]

Robinson1,

Have you come across _StringRepeat in the Help file? if not, I suggest taking a look.

M23

Wow cool _StringRepeat  that's it. Thanks.

I actually looked how it's implementated:

Func _StringRepeat($sString, $iRepeatCount)
;...
            For $iCount = 1 To $iRepeatCount
                $sResult &= $sString
            Next

            Return $sResult
EndFunc

So the core part is this:

$sResult &= $sString

Hmm I guess the  operator '&=' on a string is already linked like to some kinda StringConcat.

Anyway

$sResult &= $sString is more nice than

$sResult = $sResult & $sString.

...so I'll use that construct or _StringRepeat in future.

Edited November 30, 2013 by Robinson1

[Melba23]

Robinson1,

The function in the Beta version is rather more advanced - and much quicker I am told:

Func _StringRepeat($sString, $iRepeatCount)
    ; Casting Int() takes care of String/Int, Numbers.
    $iRepeatCount = Int($iRepeatCount)
    ; Zero is a valid repeat integer.
    If StringLen($sString) < 1 Or $iRepeatCount < 0 Then Return SetError(1, 0, "")
    Local $sResult = ""
    While $iRepeatCount > 1
        If BitAND($iRepeatCount, 1) Then $sResult &= $sString
        $sString &= $sString
        $iRepeatCount = BitShift($iRepeatCount, 1)
    WEnd
    Return $sString & $sResult
EndFunc   ;==>_StringRepeat

M23

[Robinson1]

I see it's blowing up da string exponentially now.

Nice idea. I'll keep that idea for other languages.

Its a little hard to see on the first glance  - Maybe that will be a little better readable

Func _StringRepeat($sString, $iRepeatCount)

    ; Casting Int() takes care of String/Int, Numbers.
    $iRepeatCount = Int($iRepeatCount)

    ; Zero is a valid repeat integer.
    If (StringLen($sString) < 1) Or _
       ($iRepeatCount < 0) Then _
            Return SetError(1, 0, "")

    ; Blow up string exponentially
    Local $sResult = ""
    While $iRepeatCount > 1

        ; when RepeatCount is uneven; store rest in $sResult
        If mod($iRepeatCount, 2) Then
            $sResult &= $sString
        EndIf

        ; Concat string exponentially
        $sString &= $sString

        ; Next
        $iRepeatCount = int($iRepeatCount / 2)
    WEnd

    Return $sString & $sResult
EndFunc   ;==>_StringRepeat

^-I also took out that bit crafting stuff even if that might tiny slow down the function.