Write/Delete two control at the same time

[Terenz]

Hi

Inspired by another thread i was curious about write information fron one input to another one

I have do this and work:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GuiEdit.au3>

$hGUI = GUICreate("Test", 300, 200, -1, -1)
$cInput = GUICtrlCreateInput("", 0, 0, 300, 20)
$sEdit = GUICtrlCreateEdit("", 0, 20, 300, 200, $ES_READONLY)
GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
    Local $iCode = BitShift($wParam, 16) ;HiWord
    If $iIDFrom = $cInput And $iCode = $EN_CHANGE Then
        GUICtrlSetData($cInput, GUICtrlRead($cInput))
        GUICtrlSetData($sEdit, GUICtrlRead($cInput))
    EndIf
EndFunc   ;==>_WM_COMMAND

Cool but i want to add a permanent random phrase to the edit control and i don't want to delete, example:

$sInput = GUICtrlCreateEdit("I'm a random string ", 0, 20, 300, 200, $ES_READONLY)

So if i'll write a word it will like:

And if i'll delete from the input:

I'm clear enought?

Thanks

[Melba23]

Terernz,

 

I'm clear enought?

If this is the solution - then "Yes":

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GuiEdit.au3>

Global $sRandom = "I'm a random string "

$hGUI = GUICreate("Test", 300, 200, -1, -1)
$cInput = GUICtrlCreateInput("", 0, 0, 300, 20)
$sEdit = GUICtrlCreateEdit($sRandom, 0, 20, 300, 200, $ES_READONLY)
GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
    Local $iCode = BitShift($wParam, 16) ;HiWord
    If $iIDFrom = $cInput And $iCode = $EN_CHANGE Then
        GUICtrlSetData($sEdit, $sRandom & GUICtrlRead($cInput))
    EndIf
EndFunc   ;==>_WM_COMMAND

If not, then "No".

M23

[Terenz]

So is No

Jocking apart, i don't know the "random string" so i can't store it directly in a variable but i need read it from the $sEdit

[BrewManNH]

How about this.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GuiEdit.au3>

Global $aRandom = StringSplit("I'm a random string |I'm another random string|I'm a third random string", "|")
$sRandom = $aRandom[Random(1, 3, 1)]
$hGUI = GUICreate("Test", 300, 200, -1, -1)
$cInput = GUICtrlCreateInput("", 0, 0, 300, 20)
$sEdit = GUICtrlCreateEdit($sRandom, 0, 20, 300, 200, $ES_READONLY)
GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
Switch GUIGetMsg()
  Case $GUI_EVENT_CLOSE
   Exit
EndSwitch
WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
Local $iCode = BitShift($wParam, 16) ;HiWord
If $iIDFrom = $cInput And $iCode = $EN_CHANGE Then
  GUICtrlSetData($sEdit, $sRandom & GUICtrlRead($cInput))
EndIf
EndFunc   ;==>_WM_COMMAND

This chooses a random string from an array, and uses that as the default text in the edit box.

[Melba23]

Terenz,

Then can you explain what exactly you are trying to do. How does this "random text" get into the read-only edit? Why do you wish to concatenate the input content to this text?

Rather than just produce code which will probably not do what you want, I would prefer to understand what exactly is going on so that the solution matches the overall problem.

M23

[Terenz]

Well i think i need to create some reproducible code based on your examples, thanks for the effort

@Melba were is your old avatar?! When users change the avatar is like a plastic surgery

[Melba23]

Terenz,

Take a look at the forum logo and Jos' avatar as well - it is getting close to Xmas.

You will see my old dragon avatar back once the holidays are over.

M23