GUICtrlCreateUpdown() with zero

[broliukaz]

Hi,

I have a problem, there is some simple script with GUI:

;~   ---------- display year ---------------------
GUICtrlCreateLabel("Date:    Year:", 5,12)
Global $yearinput = GUICtrlCreateInput(@YEAR, 70, 10, 50, 20)
GUICtrlCreateUpdown($yearinput)
;~ ------------display month --------------------
GUICtrlCreateLabel("Month:", 130,12)
Global $moninput = GUICtrlCreateInput(@MON, 165, 10, 50, 20)
GUICtrlCreateUpdown($moninput)
;~ -------------- display day -------------------   
GUICtrlCreateLabel("Day:", 230,12)
Global $dayinput = GUICtrlCreateInput(@MDAY, 255, 10, 50, 20)
GUICtrlCreateUpdown($dayinput)


$readyear = GUICtrlRead($yearinput)
$readmon = GUICtrlRead($moninput)
$readday = GUICtrlRead($dayinput)

I need that month and day values will be with two simbols.

Example: Now if I choose 1st month,  $readmon value is "1", but I need "01". or should I manually add "0" when writting to file?

 

[Jfish]

There may be a better way to do this but in the past I have measured the length and if it was <2 I add the 0 manually.

[BrewManNH]

Use StringFormat to append the single digit numbers with a zero.

[Melba23]

broliukaz,

You can do it very easily like this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <EditConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput("01", 10, 10, 200, 40)
GUICtrlSetFont($cInput, 20)
$cUD = GUICtrlCreateUpdown($cInput)
GUICtrlSetLimit($cUD, 12, 1)

GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_COMMAND($hWHnd, $iMsg, $wParam, $lParam)
    If _WinAPI_HiWord($wParam) = $EN_CHANGE And _WinAPI_LoWord($wParam) = $cInput Then
        GUICtrlSetData($cInput, StringFormat("%02i", GUICtrlRead($cInput)))
    EndIf
EndFunc   ;==>WM_COMMAND

If you are not too familar with GUIRegisterMsg I recommend the GUIRegisterMsg tutorial in the Wiki.

Please ask if you have any questions.

M23

[mikell]

Depending of the use Brewmanh's StringFormat can suffice

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 350, 100)
GUICtrlCreateLabel("Date:    Year:", 5,12)
Global $yearinput = GUICtrlCreateInput(@YEAR, 70, 10, 50, 20)
GUICtrlCreateUpdown($yearinput)
;~ ------------display month --------------------
GUICtrlCreateLabel("Month:", 130,12)
Global $moninput = GUICtrlCreateInput(@MON, 165, 10, 50, 20)
GUICtrlCreateUpdown($moninput)
GUICtrlSetLimit(-1, 12, 1)
;~ -------------- display day -------------------   
GUICtrlCreateLabel("Day:", 230,12)
Global $dayinput = GUICtrlCreateInput(@MDAY, 255, 10, 50, 20)
GUICtrlCreateUpdown($dayinput)
GUICtrlSetLimit(-1, 31, 1)

$display = GUICtrlCreateInput("", 100, 50, 100, 20, 1)
GUISetState()


While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $yearinput, $moninput, $dayinput
            $readyear = GUICtrlRead($yearinput)
            $readmon = StringFormat("%02i", GUICtrlRead($moninput))
            $readday = StringFormat("%02i", GUICtrlRead($dayinput))
            GuiCtrlSetData($display, $readyear & "/" & $readmon & "/" & $readday)
    EndSwitch
WEnd

[broliukaz]

 

Depending of the use Brewmanh's StringFormat can suffice

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 350, 100)
GUICtrlCreateLabel("Date:    Year:", 5,12)
Global $yearinput = GUICtrlCreateInput(@YEAR, 70, 10, 50, 20)
GUICtrlCreateUpdown($yearinput)
;~ ------------display month --------------------
GUICtrlCreateLabel("Month:", 130,12)
Global $moninput = GUICtrlCreateInput(@MON, 165, 10, 50, 20)
GUICtrlCreateUpdown($moninput)
GUICtrlSetLimit(-1, 12, 1)
;~ -------------- display day -------------------   
GUICtrlCreateLabel("Day:", 230,12)
Global $dayinput = GUICtrlCreateInput(@MDAY, 255, 10, 50, 20)
GUICtrlCreateUpdown($dayinput)
GUICtrlSetLimit(-1, 31, 1)

$display = GUICtrlCreateInput("", 100, 50, 100, 20, 1)
GUISetState()


While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $yearinput, $moninput, $dayinput
            $readyear = GUICtrlRead($yearinput)
            $readmon = StringFormat("%02i", GUICtrlRead($moninput))
            $readday = StringFormat("%02i", GUICtrlRead($dayinput))
            GuiCtrlSetData($display, $readyear & "/" & $readmon & "/" & $readday)
    EndSwitch
WEnd

Thank You! 

This is exactly what I need