Improved _ArrayAdd

[BrewManNH]

Here's a modification I made to the standard _ArrayAdd function from Array.au3. When used correctly, this function can drastically reduce the time needed to add multiple strings to an array without sacrificing any functionality. It has the same parameters as the standard _ArrayAdd function, but I've added a new one, which defaults to using the original if not used.

The code below is a minor modification to the example script from the help file, I just modified it to time how long the operation takes, as well as adding 10, 000 entries to an already existing array. The first loop uses the current method of adding strings to an array, one at a time. The second loop creates a single string delimited by the pipe ("|") character containing 10,000 substrings, and then adding all 10,000 entries to the array in one _ArrayAdd call instead of 10,000 of them. If you run this from SciTE you will see just how much faster this method is than the original. The timing takes into account building the 10,000 substrings so the test is at least closer to being fair.

The modified _ArrayAdd is in this demo script at the end of it, it is a drop in replacement for the original if you wanted to use it to replace it.

expandcollapse popup

#include <Array.au3>

Global $avArray[10]

$avArray[0] = "JPM"
$avArray[1] = "Holger"
$avArray[2] = "Jon"
$avArray[3] = "Larry"
$avArray[4] = "Jeremy"
$avArray[5] = "Valik"
$avArray[6] = "Cyberslug"
$avArray[7] = "Nutster"
$avArray[8] = "JdeB"
$avArray[9] = "Tylo"
Global $avArray2[10]
$avArray2[0] = "JPM"
$avArray2[1] = "Holger"
$avArray2[2] = "Jon"
$avArray2[3] = "Larry"
$avArray2[4] = "Jeremy"
$avArray2[5] = "Valik"
$avArray2[6] = "Cyberslug"
$avArray2[7] = "Nutster"
$avArray2[8] = "JdeB"
$avArray2[9] = "Tylo"

_ArrayDisplay($avArray, "$avArray BEFORE _ArrayAdd()")
$Timer = TimerInit()
For $I = 1 To 10000
    __ArrayAdd($avArray, "Test " & $I)
Next
ConsoleWrite("!Old method of _ArrayAdd = " & TimerDiff($Timer) / 1000 & @CRLF)
_ArrayDisplay($avArray, "$avArray AFTER _ArrayAdd()")
_ArrayDisplay($avArray2, "$avArray2 BEFORE _ArrayAdd()")
$Timer = TimerInit()
Global $sText = ""
For $I = 1 To 10000
    $sText &= "Test " & $I & "|"
Next
$sText = StringTrimRight($sText, 1)
__ArrayAdd($avArray2, $sText, "|")
ConsoleWrite("+New method of _ArrayAdd = " & TimerDiff($Timer) / 1000 & @CRLF)
_ArrayDisplay($avArray2, "$avArray2 AFTER _ArrayAdd()")


Func __ArrayAdd(ByRef $avArray, $vValue, $sDelim = "")
    If Not IsArray($avArray) Then Return SetError(1, 0, -1)
    If UBound($avArray, 0) <> 1 Then Return SetError(2, 0, -1)
    Local $iUBound = UBound($avArray), $aValue
    If $sDelim <> "" Then
        $aValue = StringSplit($vValue, $sDelim, 1) ;  $STR_ENTIRESPLIT
        If Not @error Then
            ReDim $avArray[$iUBound + $aValue[0]]
            For $Loop = 0 To $aValue[0] - 1
                $avArray[$iUBound + $Loop] = $aValue[$Loop + 1]
            Next
            Return $iUBound + $aValue[0] - 1
        Else
            Return SetError(3, 0, -1)
        EndIf
    Else
        ReDim $avArray[$iUBound + 1]
        $avArray[$iUBound] = $vValue
        Return $iUBound
    EndIf
EndFunc   ;==>__ArrayAdd

Enjoy!

[wraithdu]

This is a pretty cool idea for strings. I don't think it's an appropriate replacement for the UDF function though because it's only good for strings (I think you mentioned it as a replacement in the MVP forum?). You can't use this method for any other data types where you'd still need to pre-create your array and use _ArrayConcatenate. You could argue proper usage of the $sDelim parameter, etc etc, but I'm not sure it's worth the confusion.

Edited December 17, 2013 by wraithdu

[BrewManNH]

What other type of data are you referring to?

EDIT: I just thought of a case dealing with handles, which my modification would change to a string instead of a handle. This function would still work just as well with handles, if there were a disclaimer mentioning that you'd need to use HWnd($array[#]) to convert it back to a handle prior to needing a handle reference.

 

n.b.: If you use this function without the delimiter, so that you add each item one at a time, handles stay handles and there's no conversion necessary when referencing it. You can intermix adding items one at a time and in bulk into the same array this way.

Edited December 17, 2013 by BrewManNH

[mLipok]

Enjoy!

 

like lightning

thanks

[wraithdu]

What other type of data are you referring to?

 

Any other data type, even numbers. I guess my point is this... _ArrayAdd is a general purpose function that can take any data type as its second parameter, and preserves that data in the array. You're introducing a feature which is only good for strings. In my mind that muddies the water. Users should either use _ArrayAdd as it is intended, or concatenate two arrays (which is really what your function is doing) with _ArrayConcatenate. You've basically written a new function, intended only to add a delimited string as array elements, which you could aptly name _ArrayAddDelimitedString.

Please don't think I'm bashing your function, it's definitely super efficient for its intended purpose. I just don't think it's a feature that should exist in the standard _ArrayAdd function.

[BrewManNH]

Why wouldn't it work for numbers?

[guinness]

StringSplit() casts all data to a string. Or have I misunderstood how this function works?

[BrewManNH]

But in a comparison, it's still going to compare as a number. If numbers are needed, check to see if the string is a number, and cast it to a number when adding it.

[guinness]

But if I add this 1000 & '|' & 1001 & '|' & 1002 then I expect the values to be numbers in the array, compared to this '1000|1001|1002', which I expect to be a string. This is the point I believe wraithdu is trying to make.

Keep _ArrayAdd() and add a new function if you see it's worthy to the masses.

Edited December 18, 2013 by guinness

[BrewManNH]

I wasn't planning on changing the standard _ArrayAdd, just was playing around with it and came up with it.

I did come up with a modification to it that allowed numbers to stay as numbers, but it converts numbers like "0001" to 1 and hex numbers to decimal (which isn't a major problem), so it's not working correctly 100% of the time. You'd still need to add handles one at a time, otherwise they get converted to numbers.

Func __ArrayAdd(ByRef $avArray, $vValue, $sDelim = "")
    If Not IsArray($avArray) Then Return SetError(1, 0, -1)
    If UBound($avArray, 0) <> 1 Then Return SetError(2, 0, -1)
    Local $iUBound = UBound($avArray), $aValue
    If $sDelim <> "" Then
        $aValue = StringSplit($vValue, $sDelim, 1) ;  $STR_ENTIRESPLIT
        If Not @error Then
            ReDim $avArray[$iUBound + $aValue[0]]
            For $Loop = 0 To $aValue[0] - 1
                If $aValue[$Loop + 1] == "0" Then $aValue[$Loop + 1] = Number($aValue[$Loop + 1]) ; <<<<<<<<<<<<<<<<<<<<<<<<< If the incoming number is string 0 then convet it to a number
                If $aValue[$Loop + 1] / 1 <> 0 Then $aValue[$Loop + 1] = Number($aValue[$Loop + 1]) ; <<<<<<<<<<<<<<<<<<<<<<<<< This checks to see if the incoming string is numeric and converts it to a number before adding it to the array
                $avArray[$iUBound + $Loop] = $aValue[$Loop + 1]
            Next
            Return $iUBound + $aValue[0] - 1
        Else
            Return SetError(3, 0, -1)
        EndIf
    Else
        ReDim $avArray[$iUBound + 1]
        $avArray[$iUBound] = $vValue
        Return $iUBound
    EndIf
EndFunc   ;==>__ArrayAdd

Maybe I'll figure it out, or just leave this as an exercise for someone else to tackle.

[guinness]

It's a good idea for strings at least, but retaining the original variable type is a different matter. That modification assumes that values which are numbers were passed as just that. Though my example shows that it's not always the case.

[BrewManNH]

No, that modification assumes that if the value passed can be evaluated to a number, even though it's a string, it will be converted to a number. One of the problem is if you wanted to keep a string that is a number as a string. If the string passed is divisible by 1 and the result isn't 0, then it gets converted to a number. One of the problems with that test though is that 1Dog would get converted to 1. It's one of the many problems this has when dealing with mixed contents.

As it is, it's an interesting method, but definitely not something worth including except for specific purposes.

[guinness]

Agreed!