Strange issue with arrays being created in one. Cannot manually access

[Morthawt]

#include <String.au3>
#include <Array.au3>
Global $test[2]
$test[0] = _StringBetween(1231293, 1, 3)
$test[1] = _StringBetween('1Hello3', 1, 3)

_ArrayDisplay($test[0])
_ArrayDisplay($test[1])

ConsoleWrite($test[0][0] & @CRLF)

I can access the contents via array display but when I try and manually pull a single entry out of the array I cannot find them. It always crashes. I have tried $test[0][0] $test[0][1] I just do not know how to find the entries manually. What am I doing wrong?

Thanks.

[vkrisz81]

ehm

i am not pro ! but if you have a one dimensional array why do you read 2 dimensional?

if you have test[2] why do you want reach test[0][0]???

 

ooops somebody was faster :S

Edited January 6, 2014 by vkrisz81

[jdelaney]

Ooops, deleted my last post, but yes, you are using not using a 2D array, you are using an array of arrays.

You need to create a temp array, to access it's elements.

#include <String.au3>
#include <Array.au3>
Global $test[2]
$test[0] = _StringBetween(1231293, 1, 3)
$test[1] = _StringBetween('1Hello3', 1, 3)

_ArrayDisplay($test[0])
_ArrayDisplay($test[1])

$aTemp = $test[0]

ConsoleWrite($aTemp[0] & @CRLF)

example with 2D array (requires a lot of failure handling|redimming, which I didn't include for simplicity):

#include <String.au3>
#include <Array.au3>
Global $test[2][2]
$aTemp = _StringBetween(1231293, 1, 3)
For $i = 0 To UBound($aTemp)-1
    $test[0][$i] = $aTemp[$i]
Next
$aTemp = _StringBetween('1Hello3', 1, 3)
For $i = 0 To UBound($aTemp)-1
    $test[1][$i] = $aTemp[$i]
Next
ConsoleWrite($test[0][0] & @CRLF)

Edited January 6, 2014 by jdelaney

[vkrisz81]

i found a q what i could answer.. i have hope ^^

[l3ill]

An even simpler look at it:

Your variables dont need element numbers until you are declaring the element:

#include <String.au3>
#include <Array.au3>
;Global $test[2]
$test_1 = _StringBetween(1231293, 1, 3)
$test_2 = _StringBetween('1Hello3', 1, 3)

_ArrayDisplay($test_1)
_ArrayDisplay($test_2)

ConsoleWrite("$test_1[0] =  " & $test_1[0] & @CRLF)
ConsoleWrite("$test_2[0] =  " & $test_2[0] & @CRLF)

[MilesAhead]

i found a q what i could answer.. i have hope ^^

 

That's just to give you a false sense of security. 

[Morthawt]

 

An even simpler look at it:

Your variables dont need element numbers until you are declaring the element:

#include <String.au3>
#include <Array.au3>
;Global $test[2]
$test_1 = _StringBetween(1231293, 1, 3)
$test_2 = _StringBetween('1Hello3', 1, 3)

_ArrayDisplay($test_1)
_ArrayDisplay($test_2)

ConsoleWrite("$test_1[0] =  " & $test_1[0] & @CRLF)
ConsoleWrite("$test_2[0] =  " & $test_2[0] & @CRLF)

Right, but I am trying to do something that is dynamic. I have no idea how many times I will need to cycle through so I am planning on using an array that increments to store the information, that way I hope to process everything and be able to dynamically count how many array entries need processing. Now that I know it is an array that is stored inside an array entry that makes sense. Thanks everyone. If I need any more clarification I will reply again.

Thanks!

[jchd]

#include <String.au3>
#include <Array.au3>
Global $test[2]
$test[0] = _StringBetween(1231293, 1, 3)
$test[1] = _StringBetween('1Hello3', 1, 3)

_ArrayDisplay($test[0])
_ArrayDisplay($test[1])

ConsoleWrite($test[0][0] & @CRLF)

I can access the contents via array display but when I try and manually pull a single entry out of the array I cannot find them. It always crashes. I have tried $test[0][0] $test[0][1] I just do not know how to find the entries manually. What am I doing wrong?

Thanks.

You can use the newly introduced syntax:

#include <String.au3>
#include <Array.au3>
Global $test[2]
$test[0] = _StringBetween(1231293, 1, 3)
$test[1] = _StringBetween('1Hello3', 1, 3)

_ArrayDisplay($test[0])
_ArrayDisplay($test[1])

ConsoleWrite(($test[0])[0] & @CRLF)

[jdelaney]

That's awesome.  Might have to upgrade.

 

You can use the newly introduced syntax:

#include <String.au3>
#include <Array.au3>
Global $test[2]
$test[0] = _StringBetween(1231293, 1, 3)
$test[1] = _StringBetween('1Hello3', 1, 3)

_ArrayDisplay($test[0])
_ArrayDisplay($test[1])

ConsoleWrite(($test[0])[0] & @CRLF)

[Morthawt]

omg.. will that do what I think it does? No need to assign a temporary variable because ($var[0])[2] will get access to the third entry on the array that was stored inside the first one??

[Melba23]

Morthawt,

Exactly.

M23

[vkrisz81]

That's just to give you a false sense of security. 

i wish say u u are so kind, but you are not ^^

[Morthawt]

Morthawt,

Exactly.

M23

Wow.. I would never have realised that from the changelog. That is nice.

[wraithdu]

Word of warning, you cannot use that syntax to assign values to the inner arrays.

Global $a[1] = [1]
Global $b[1] = [$a]
ConsoleWrite(($b[0])[0] & @CRLF)
($b[0])[0] = 2
ConsoleWrite(($b[0])[0] & @CRLF)

[Morthawt]

 

Word of warning, you cannot use that syntax to assign values to the inner arrays.

Global $a[1] = [1]
Global $b[1] = [$a]
ConsoleWrite(($b[0])[0] & @CRLF)
($b[0])[0] = 2
ConsoleWrite(($b[0])[0] & @CRLF)

Thats fine, as long as you can retrieve the values that's perfect.