How to convert a string into AutoIt code

[leuce]

Hello everyone

I have this string:

 

$foo = 'one="apple" two="berry" three="cherry"'

And I want to convert it to this set of variables:

 

$one = "apple"
$two = "berry"
$three = "cherry"

Is there is a simple (potentially one-line) way of accomplishing it?

Thanks

Samuel

Edited January 8, 2014 by leuce

[leuce]

Hello everyone

[This question is for solving the same problem as mentioned in this forum post.]

Is it possible to convert a string that is essentially a chunk of AutoIt code into actual AutoIt code that is executed by the script? For example, if I have this:

 

$foo = '$one = "apple"'

can I tell the script to treat $foo as if it is the following AutoIt instruction:

 

$one = "apple"

Thanks

Samuel

Edited January 8, 2014 by leuce

[iamtheky]

;~ Global $one , $two , $three

$foo = 'one="apple" two="berry" three="cherry"'

$Afoo = stringsplit(StringStripWS($foo, 8) , '" ')

for $i = 1 to $Afoo[0] - 1 step 2
Assign(stringtrimright($Afoo[$i], 1), $Afoo[$i+1])
next

;~ msgbox(0, '' , $one)
;~ msgbox(0, '' , $two)
;~ msgbox(0, '' , $three)

Edited January 8, 2014 by boththose

[Gianni]

take a look to these functions:
Assign, Execute, Eval

[leuce]

...

Thanks, Boththose, that goes a long way to solve my problem. I notice, however, that it must be known beforehand that there will have to be variables named $one, $two and $three. In other words, if I as the script writer doesn't know beforehand that the string will contain "one", "two" and "three", then I would not be able to do this, right?

[iamtheky]

nope, that was only for the msgbox, i realized that and commented them out in the above.  Though i see not quickly enough.  It is not necessary to declare, it just fails au3check.

[leuce]

Take a look to these functions:

Assign, Execute, Eval

Yes, I was looking at those, thanks. However, "Execute" only executes an expression, not code, as in this non-working example:

 

$foo = '$bar="hello"'
Execute ($foo)
MsgBox (0, "", $bar, 0)
; Expected: get message box that says 'hello'

Do you know of a different function that I could use instead of "Execute" that would work exactly like this?

==

Added:

I tried #include, but it would seem that #include only works if the file already exists at the time that the script is run. This, for example, does not work:

FileWrite (FileOpen ("hello.au3", 130), '$bar="hello"')
#include "hello.au3"
MsgBox (0, "", $bar, 0)

Thanks

Samuel

Edited January 8, 2014 by leuce

[guinness]

Why the double post?

[leuce]

Why the double post?

It's not a double post. It's two potentially different solutions to a single problem. Yes, I have one problem, but I can think of two ways to solve it, and I'm therefore asking two separate questions about the two separate potential solutions.

[Melba23]

leuce,

 

Yes, I have one problem

Then stick to the one thread - threads merged.

M23

[iamtheky]

Nope.  Its the same question twice.  That discussion should include all potential answers.  Search would be ridiculous if I had to do so by potential solution and not by the question.

[leuce]

Yes, I have one problem...

Then stick to the one thread - threads merged.

No problem, thanks for the merge.

 

Nope.  Its the same question twice.  That discussion should include all potential answers.  Search would be ridiculous if I had to do so by potential solution and not by the question.

I see your point.

==

So, in this thread, my the one question (i.e. how to convert a string into a variable) has been answered by boththose -- thanks! That solution will simplify matters considerably.

I'm still wondering about the second question, though... is it possible to execute the content of a variable? I suppose I could split what I'm trying to do into two scripts -- one to create an #include file and the second to use the #include file.

Samuel

Edited January 8, 2014 by leuce

[leuce]

$foo = 'one="apple" two="berry" three="cherry"'
$Afoo = stringsplit(StringStripWS($foo, 8) , '" ')
for $i = 1 to $Afoo[0] - 1 step 2
Assign(stringtrimright($Afoo[$i], 1), $Afoo[$i+1])
next

Thanks again. The string I had contained spaces that had to be preserved, so I could not use your exact solution in the end, but it really helped me to get to what I ended up with:

$properties1 = 'ConcID="1" value="xyz" ProdName="xyz" LingInf="Noun | Full Form" Desc="xyz." Stat="Approved" '

$properties2 = StringSplit($properties1, '" ', 1)

For $k = 1 to $properties2[0] - 1
$properties3 = StringSplit($properties2[$k], '="', 1)
If $properties3[0] = 2 Then
Assign($properties3[1], $properties3[2])
EndIf
Next

[l3ill]

 

is it possible to execute the content of a variable?

 

Yes, but it will be a different command depending on what the vaiable contains, for instance:

Path - FileOpen

EXE - ShellExecute

PDF - Run

Etc...

[leuce]

Yes, but it will be a different command depending on what the variable contains, for instance:

Path - FileOpen

EXE - ShellExecute

PDF - Run

Etc...

I'm intriged by your answer. Could you please give me an example? In my case, the variable contains a string, and the string is: $foo = '$bar="hello"'.

[jdelaney]

$properties1 = 'ConcID="1" value="xyz" ProdName="xyz" LingInf="Noun | Full Form" Desc="xyz." Stat="Approved" '
$a = StringRegExp($properties1,"(?U)\s?(\w+)=""([^""]+)""",4)
For $i = 0 To UBound($a) - 1
    $aTemp = $a[$i]
    Assign($aTemp[1],$aTemp[2],2)
Next

ConsoleWrite("ConcID=[" & Eval("ConcID") & "]" & @CRLF)
ConsoleWrite("value=[" & Eval("value") & "]" & @CRLF)
ConsoleWrite("ProdName=[" & Eval("ProdName") & "]" & @CRLF)
ConsoleWrite("LingInf=[" & Eval("LingInf") & "]" & @CRLF)
ConsoleWrite("Desc=[" & Eval("Desc") & "]" & @CRLF)
ConsoleWrite("Stat=[" & Eval("Stat") & "]" & @CRLF)

Output:

ConcID=[1]

value=[xyz]

ProdName=[xyz]

LingInf=[Noun | Full Form]

Desc=[xyz.]

Stat=[Approved]

Edited January 8, 2014 by jdelaney

[l3ill]

There are plenty of goo-roos here that can answer this better than I but you have the suggestion from PincoPanco in post # 4.

These are some of the functions that can execute a string.

The execute command itself does not look like it is designed for this particular jumble as it executes the expression which as I understand it is some sort of a value (number math etc).

My post was not necessarily confining the execution of the variable to the actual command known as "execute".

Bill

[Celtic88]

I'm interested in can be used to protect script   

[Gianni]

.....

I suppose I could split what I'm trying to do into two scripts -- one to create an #include file and the second to use the #include file.

Samuel

 

Hi leuce

using your script from post >#13 you could create your "include" containing the declarations of your variables  in this way:

$properties1 = 'ConcID="1" value="xyz" ProdName="xyz" LingInf="Noun | Full Form" Desc="xyz." Stat="Approved" '

$properties2 = StringSplit($properties1, '" ', 1)
$path = FileOpen("hello.au3", 130)
For $k = 1 To $properties2[0] - 1
    $properties3 = StringSplit($properties2[$k], '="', 1)
    If $properties3[0] = 2 Then
        FileWriteLine($path, "$" & $properties3[1] & ' = "' & $properties3[2] & '"')
    EndIf
Next
FileClose($path)

and then include the generated hello.au3 in your second script.

[BrewManNH]

I'm interested in can be used to protect script   

No, you can't protect your script. You can make it harder to decode it, but your script will never be 100% safe.