Send key problem

[crislivinitup]

I am using an autoIt program to send hotkeys (registered as hotkeys by another program) and I am having an odd problem. The key combination I am trying to send is Ctrl + insert.

Send("^{insert}")

;~ Have also tried the following:
;~ Send("{LCTRL DOWN}")
;~ Send("{insert down}")
;~ Send("{insert up}")
;~ Send("{LCTRL UP}")

It seems to work the first time, then I find that the ctrl or the insert key sticks. I.e. after the program has fired due to recieving the hotkey, I can press insert and it will fire again since the ctrl key hasn't been released. Any ideas or suggestions?

[AutID]

I had the same problem yesterday. Left ctrl stuck pressed down but I thought scite was messing things up because of the memory leak of some things I was trying so I didn't pay attention.

I would like to see what is going on as well

[kaotkbliss]

Maybe after you do the

Send("^{insert}")

you could do an

if _ispressed(11) then

send("^")

endif

if _ispressed(2D) then

send("{insert}")

endif

 

I can't quite remember offhand, but I believe just hitting the keys again would get them unstuck, so something like this may work.

[crislivinitup]

Hmmm, doesn't seem to work, I've tried sending various other keys afterwards (with the send command) and it didn't seem to null out the sticky control

[kaotkbliss]

hmm, that's how I've fixed the issue in my scripts. (I'm at work now and can look through what I have)

So I'm not sure where to go from there.

[JLogan3o13]

I would suggest bringing up the On-Screen Keyboard and watching it while your script runs, to determine if the key is actually sticking or if it is something else.

[Iczer]

Send() is not very reliable, but _WinAPI_Keybd_Event() never go wrong, so:

Func Press_CTRL_C_Macross($t = 8)
    _WinAPI_Keybd_Event(0x11, 0) ; CTRL Down
    _WinAPI_Keybd_Event(0x43, 0) ; c Down
    Sleep($t)
    _WinAPI_Keybd_Event(0x43, 2) ; c Up
    _WinAPI_Keybd_Event(0x11, 2) ; CTRL Up
EndFunc   ;==>Press_CTRL_C_Macross

you can customise this for you needs

[crislivinitup]

Hey thanks guys for the advice. I tried Iczer's solution and it seemed to work! The snippet was very easy to use

[crislivinitup]

I came across this problem again in another script of mine and I figured out a great way to get past it that I thought I would share. The problem seems to happen when a send command is in a function that is activated by a hotkey. Moreover, it happens when the send command executes before the user has a chance to lift his finger off of the hotkey keys. I haven't tested all of the keys with which this happens, but the best solution I found is as follows:

#include <Misc.au3>

Opt("WinTitleMatchMode", 2)

If WinExists("Todo") == 0 Then
    Run(@WindowsDir & "\Notepad.exe '" & "D:\Library\Documents\Todo.txt'", @WindowsDir)
    WinWait("Todo")
Else
    WinActivate("Todo")
EndIf

HotKeySet("^t", "dateStr")
HotKeySet("^q", "quit")

WinWaitClose("Todo")
Exit

Func dateStr()
    While(_IsPressed("11"))
        Sleep(50)
    WEnd
    If WinActive("Todo") Then
        Local $str
        $str = @YEAR & "/" & @MON & "/" & @MDAY & "/   " & @HOUR & ":" & @MIN
        Send($str)
    EndIf
EndFunc   ;==>dateStr

Func quit()
    Exit
EndFunc

I introduced a while loop check for the key being pressed so that the function (which is initiated by the hotkey) does not continue until the user has lifted his/her finger.

[somdcomputerguy]

It seems to work the first time, then I find that the ctrl or the insert key sticks.

Read this, maybe it'll help you.

http://www.autoitscript.com/wiki/FAQ#Why_does_the_Ctrl_key_get_stuck_down_after_I_run_my_script.3F