Software Metric: Variable Span -- [07/20/2015]

[jaberwacky]

Note: Requires a version of AutoIt3 which supports the newest syntax such as ternary operators, etc.

I have started the initial foray into making a collection of scripts which will attempt to quantify various measurable aspects of AutoIt scripts.  This script measures the span of variables in functions.  Variable span is a count of how many lines are between references to a variable.  To quote "Code Complete" by Steve McConnell:

The code between references to a variable is a "window of vulnerability."  In the window, new code might be added, inadvertantly altering the variable, or someone reading the code might forget the value the variable is supposed to contain.

...

When you keep references to variables close together, you enable the person reading your code to focus on one section at a time.  If the references are far apart, you force the reader to jump around in the program.

Basically the higher the Span Average of a function the more that you would want to look into refactoring that function.  But there are no hard and fast rules.

So this script only works on functions currently.  Try it out and tell me what you think!

Update: [07/20/2015] -- Uses Andreik's Charts.au3 to create a chart displaying the top candidates for refactoring. Pie Chart

Update: [06/24/2014] -- A minor improvement which increases accuracy by not counting lines with variable declarations.

Update: [05/15/2014] -- Now works with the Volatile keyword.  Also updated Stream Functions.au3 to the latest version.

Zip which includes required dependencies:   Variable Span & Live Time.zip 

Previous: 56

Edited July 21, 2015 by jaberwacky

[guinness]

Where is Stream Functions?

[jaberwacky]

I edited the post.

[guinness]

I just tried using @ScriptFullPath and _line_contains_variable() reports!Func Average: -1.#IND, shouldn't that be 0?

[jaberwacky]

Try now.

[jaberwacky]

Actually, it acts strangely when run on itself.  I used date.au3 during testing which works normal.

[guinness]

Thanks.

Edit: I tried on the Date.au3 and it reported...

-Function: _Now
"C:\Users\guinness\Desktop\Test.au3" (60) : ==> Variable must be of type "Object".:
For $variable In $variables_list
For $variable In $variables_list^ ERROR

Edited January 15, 2014 by guinness

[jaberwacky]

That's really weird because it runs fine for me.

Try this please:

expandcollapse popup

#AutoIt3Wrapper_AU3Check_Parameters=-w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7 -d

; ================================================================================
; Author ....: Jaberwacky
; Credit(s) .: jchd for the function body regexps
; Resources .: Code Complete 2nd edition by Steve McConnell
; ================================================================================

#include-once

#include "Stream Functions.au3"

#include <File.au3>

#include <Array.au3>

_main("C:\Program Files (x86)\AutoIt3\Include\Date.au3")

#region ; Variable Span
Func _main(Const $source_path)
  Local Const $au3_source = FileRead($source_path)
  
  Local Const $function_bodies = StringRegExp($au3_source, "(?imsx)^\s*func\s+\w*\(\N*?\).*?^\s*endfunc", 3) ; alternate version that leaves out func/endfunc -- (?imsx)^\s*func\s+\w*\(\N*?\)\N*(.*?)^\s*endfunc
  
  Local Const $function_names = StringRegExp(StringRegExpReplace($au3_source, "(?ims)#c[^#]+#c", ''), "(?ims)^\s*func\s*([^(]*)", 3)
  
  Local $i = 0
  
  For $func_body In $function_bodies
    ConsoleWrite("=================================================================" & @CRLF & _ 
                 "-Function: " & $function_names[$i] & @CRLF)
    
    $i += 1
                 
    _analyze_function($func_body)
  Next
EndFunc

Func _analyze_function(Const $func_body)  
  Local Const $variables_list = _get_variables_list($func_body)
  
  Local $line = ''
  
  Local $var_span_count = 0
  
  Local $func_span_count = 0
  
  Local $span_line_count = 0
  
  Local $var_span_average = 0
  
  Local $func_span_average = 0
  
  Local $var_span_total = 0
  
  Local $func_span_total = 0
  
  Local $span_flag = False
  
  For $variable In $variables_list
    ConsoleWrite("+  Variable: " & $variable & @CRLF)
    
    Do 
      $line = string_stream_read_line($func_body)
      
      If @error Then ExitLoop
      
      Switch _line_contains_variable($line, $variable)
        Case True
          Switch $span_flag
            Case True
              $var_span_total += $span_line_count
              
              $func_span_total += $var_span_total
              
              $span_line_count = 0
              
              $var_span_count += 1
              
              $func_span_count += 1
              
              $span_flag = False
            
            Case False
              $span_flag = True
          EndSwitch
          
        Case False
          Switch StringInStr($line, "EndFunc")
            Case True
              $var_span_average = (($var_span_total > 0) ? Round($var_span_total / $var_span_count, 2) : 0)
              
              $func_span_average = (($func_span_total > 0) ? Round($func_span_total / $func_span_count, 2) : 0)
              
              ConsoleWrite("    $span_count : " & $var_span_count        & @CRLF & _
                           "    $span_total : " & $var_span_total        & @CRLF & _ 
                           "    Span Average: " & $var_span_average      & @CRLF & @CRLF) 
              
              $var_span_total = 0
              
              $span_line_count = 0
              
              $var_span_count = 0        
              
              $span_flag = False
          EndSwitch                 
              
          Switch $span_flag
            Case True
              $span_line_count += 1
            
              ;ConsoleWrite("  " & "$span_line_count: " & $span_line_count & @TAB & $line)
          EndSwitch
      EndSwitch
    Until False
  Next
  
  ConsoleWrite("!Func Average: " & $func_span_average & @CRLF & _ 
               "=================================================================" & @CRLF & @CRLF)
EndFunc

Func _line_contains_variable(Const $line, Const $variable)
  Return StringInStr($line, $variable) And Not StringInStr($line, ';')
EndFunc

Func _get_variables_list(Const $func_body)
  Local Const $variables = StringRegExp($func_body, "\$\w+", 3)
  Return _ArrayUnique($variables, 1, 0, 0, 0)
EndFunc
#endregion

Edited January 15, 2014 by jaberwacky

[guinness]

I am still getting the same error using 64-bit AutoIt v3.3.10.2.

[jaberwacky]

Wow, back to the drawing board.  It runs really weird when ran on itsself.  Go figure.

[jaberwacky]

I am still getting the same error using 64-bit AutoIt v3.3.10.2.

I tried it on that au3 version just now with Win7 x64.  Runs as expected.  Well, this is going to keep me up for a while.  =)

Edited January 15, 2014 by jaberwacky

[guinness]

You can see it fails on _Now().

[jaberwacky]

I see now.  That's the first function without parameters.  But why would it run right on my machine is what baffles me.

[jaberwacky]

Mmkay, may have found the issue.  If no variables were found then _analyze_function is skipped and the script seems to continue on its merry way.

Edited the OP.

[BrewManNH]

If you change the return from _analyze_function to return 1 on finding no variables, you can modify the output to use something like this.

 

If Not _analyze_function($func_body) Then ConsoleWrite($function_names[$i] & " has no variables." & @CRLF)
$i += 1 ; moved this to after the function call to _analyze_function

This prints out that the function has no variables, so you don't get a blank output for that function which might confuse some users.

[czardas]

Interesting idea. Nowadays I reuse variables quite a lot to reduce memory use. I generally add comments to indicate the change of use to prevent confusion.

Edit

Note to self - Must read code complete.

Edited January 15, 2014 by czardas

[jaberwacky]

Note to self - Must read code complete.

I highly recommened it.  I picked up my copy at a thrift store for less than two dollars!

[guinness]

Fixed. No error now.

[jaberwacky]

Implemented BrewManNH's suggestion and updated OP.

It seems to work well so far except when ran on itself.  So don't do that.  =P

[BrewManNH]

One other thing, instead of including File.au3 you should only need to include FileConstants.au3. You're not using any of the functions in File, you are only using the variables. This way you're also not including Array.au3 and StringConstants.au3 which aren't needed unless you're using the main script and not the UDF file.