Jump to content

XML Can't Read Attributes


someone
 Share

Go to solution Solved by jdelaney,

Recommended Posts

Hey everyone,

This is driving me crazy I'm hoping someone can help me out.  I am trying to read from an XML that is created by a MS program (so I can't change anything about the file structure) but everytime I try to read attributes (or anything else) while the xmlns="" exists in the XML I can't get anything to work.

Reproducer;

Global $strFile
Global $DOMVERSION = -1
Global $objDoc

$sPath_PackageXML = ".\UserDeploymentConfiguration.xml"

$sret = _XMLFileOpen($sPath_PackageXML);, 'xmlns="http://schemas.microsoft.com/appv/2010/deploymentconfiguration"')
MsgBox(0, $sret, @error & " : " & @extended)
;the open ALWAYS works, have both used the namespace argument and not used

$temp_attrib = _XMLGetAttrib("/DeploymentConfiguration", "DisplayName")
MsgBox(0, "debug test : " & @error & " : " & @extended, $temp_attrib)
;this should work

; #FUNCTION# ===================================================================
; Name ..........: _XMLGetAttrib
; Description ...: Get XML Field based on XPath input from root node.
; Syntax.........:  _XMLGetAttrib($strXPath, $strAttrib[, $strQuery = ""])
; Parameters ....: $strXPath      - XML tree path from root node (root/child/child..)
;                  $strAttrib     - The attribute node to read.
;                  $strQuery      - The query string in xml format
; Return values .: Success        - The attribute value.
;                  Failure        - -1 and sets @Error to:
;                  |0 - No error
;                  |1 - Attribute not found.
;                  |2 - No object
; Author ........: Stephen Podhajecki <gehossafats@netmdc.com>
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........;
; Example .......; [yes/no]
; ==============================================================================
Func _XMLGetAttrib($strXPath, $strAttrib, $strQuery = "")
    If Not IsObj($objDoc) Then
        MsgBox(0, "Error", "No object passed to function _XMLGetAttrib")
        ;_XMLError("No object passed to function _XMLGetAttrib")
        Return SetError(2, 0, -1)
    EndIf
    ;Local $objNodeList, $arrResponse[1], $i, $xmlerr, $objAttr
    Local $objNodeList, $arrResponse, $i, $xmlerr, $objAttr
    $objNodeList = $objDoc.documentElement.selectNodes($strXPath & $strQuery)
    ;_DebugWrite("Get Attrib length= " & $objNodeList.length)
    If $objNodeList.length > 0 Then
        For $i = 0 To $objNodeList.length - 1
            $objAttr = $objNodeList.item($i).getAttribute($strAttrib)
            $arrResponse = $objAttr
            ;_DebugWrite("RET>>" & $objAttr)
        Next
        Return $arrResponse
    EndIf
    $xmlerr = "\nNo qualified items found"
    MsgBox(0, "Error", "Attribute " & $strAttrib & " not found for: " & $strXPath & $xmlerr)
    ;_XMLError("Attribute " & $strAttrib & " not found for: " & $strXPath & $xmlerr)
    Return SetError(1, 0, -1)
EndFunc   ;==>_XMLGetAttrib

; #FUNCTION# ===================================================================
; Name ..........: _XMLFileOpen
; Description ...: Creates an instance of an XML file.
; Syntax.........:  _XMLFileOpen($strXMLFile[, $strNameSpc = ""[, $iVer = -1[, $fValOnParse = True]]])
; Parameters ....: $strXMLFile    - the XML file to open
;                  $strNameSpc    - the namespace to specifiy if the file uses one.
;                  $iVer          - specifically try to use the version supplied here.
;                  $fValOnParse   - validate the document as it is being parsed
; Return values .: Success        - 1
;                  Failure        - -1 and set @error to:
;                  |0 - No error
;                  |1 - Parse error, @Extended = MSXML reason
;                  |2 - No object
; Author ........: Stephen Podhajecki <gehossafats@netmdc.com>
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........;
; Example .......; [yes/no]
; ==============================================================================
Func _XMLFileOpen($strXMLFile, $strNameSpc = "", $iVer = -1, $fValOnParse = True)
    ;==== pick your poison
    If $iVer <> -1 Then
        If $iVer > -1 And $iVer < 7 Then
            $objDoc = ObjCreate("Msxml2.DOMDocument." & $iVer & ".0")
            If IsObj($objDoc) Then
                $DOMVERSION = $iVer
            EndIf
        Else
            MsgBox(266288, "Error:", "Failed to create object with MSXML version " & $iVer)
            SetError(1)
            Return 0
        EndIf
    Else
        For $x = 8 To 0 Step -1
            If FileExists(@SystemDir & "\msxml" & $x & ".dll") Then
                $objDoc = ObjCreate("Msxml2.DOMDocument." & $x & ".0")
                If IsObj($objDoc) Then
                    $DOMVERSION = $x
                    ExitLoop
                EndIf
            EndIf
        Next
    EndIf
    If Not IsObj($objDoc) Then
        MsgBox(0, "Error", "Error: MSXML not found. This object is required to use this program.")
        ;_XMLError("Error: MSXML not found. This object is required to use this program.")
        SetError(2)
        Return -1
    EndIf
    ;Thanks Lukasz Suleja
    $oXMLMyError = ObjEvent("AutoIt.Error")
    If $oXMLMyError = "" Then
        $oXMLMyError = ObjEvent("AutoIt.Error", "_XMLCOMEerr") ; ; Initialize SvenP 's error handler
    EndIf
    $strFile = $strXMLFile
    $objDoc.async = False
    $objDoc.preserveWhiteSpace = True
    $objDoc.validateOnParse = $fValOnParse
    If $DOMVERSION > 4 Then $objDoc.setProperty("ProhibitDTD", False)
    $objDoc.Load($strFile)
    $objDoc.setProperty("SelectionLanguage", "XPath")
    $objDoc.setProperty("SelectionNamespaces", $strNameSpc)
    If $objDoc.parseError.errorCode > 0 Then ConsoleWrite($objDoc.parseError.reason & @LF)
    If $objDoc.parseError.errorCode <> 0 Then
        MsgBox(0, "Error", "Error opening specified file: " & $strXMLFile & @CRLF & $objDoc.parseError.reason)
        ;_XMLError("Error opening specified file: " & $strXMLFile & @CRLF & $objDoc.parseError.reason)
        ;Tom Hohmann 2008/02/29
        SetError(1, $objDoc.parseError.errorCode, -1)
        $objDoc = 0
        Return -1
    EndIf
    ;Tom Hohmann 2008/02/29
    Return 1
EndFunc   ;==>_XMLFileOpen

I included the functions from the UDF for easier reproduction -- UDF found here ()

This XML doesn't work;

<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname" xmlns="http://schemas.microsoft.com/appv/2010/deploymentconfiguration"></DeploymentConfiguration>
 

This XML does;

<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname" ></DeploymentConfiguration>
 

I'm not against using something else other then the XML DOM, so any suggestions welcome.  I'm at the point I might go back to fileread operations.

Thanks in advance.

UserDeploymentConfiguration.xml

While ProcessExists('Andrews bad day.exe')
	BlockInput(1)
	SoundPlay('Music.wav')
	SoundSetWaveVolume('Louder')
WEnd
Link to comment
Share on other sites

  • Solution

Both work for me:

$oXML = ObjCreate("Microsoft.XMLDOM")

$xml = '<?xml version="1.0"?><DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname1" xmlns="http://schemas.microsoft.com/appv/2010/deploymentconfiguration"></DeploymentConfiguration>'
$oXML.loadxml($xml)
ConsoleWrite($oXML.xml & @CRLF)
For $oConfig in $oXML.selectNodes("//DeploymentConfiguration")
    $sDisplayName = $oConfig.getAttribute('DisplayName')
    ConsoleWrite($sDisplayName & @CRLF)
Next

$xml = '<?xml version="1.0"?><DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname2" ></DeploymentConfiguration>'
$oXML.loadxml($xml)
ConsoleWrite($oXML.xml & @CRLF)
For $oConfig in $oXML.selectNodes("//DeploymentConfiguration")
    $sDisplayName = $oConfig.getAttribute('DisplayName')
    ConsoleWrite($sDisplayName & @CRLF)
Next

output:

<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname1" xmlns="http://schemas.microsoft.com/appv/2010/deploymentconfiguration"></DeploymentConfiguration>

testDisplayname1
<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname2"></DeploymentConfiguration>

testDisplayname2

IEbyXPATH-Grab IE DOM objects by XPATH IEscriptRecord-Makings of an IE script recorder ExcelFromXML-Create Excel docs without excel installed GetAllWindowControls-Output all control data on a given window.
Link to comment
Share on other sites

Hey jdelaney,

Thanks a lot!  I tried using microsoft.xmldom (actually from one of your posts) but turns out I missed that you have to pass the XML as a string... I kept feeding it a filename...Doh!  >_<  .  Is the Microsoft.XMLDOM better/worse, newer or older compared to Msxml2.DOMDocument I am using from eltorro's UDF?

Any ideas on why it only works with Microsoft.XMLDOM?

 

Thanks so much for the help, really appreciate it.

Edited by someone
While ProcessExists('Andrews bad day.exe')
	BlockInput(1)
	SoundPlay('Music.wav')
	SoundSetWaveVolume('Louder')
WEnd
Link to comment
Share on other sites

You can load an XML file, just pass in the file as the param, and change .xmlload to .xml...or maybe just .load...I forget (your own quick google search if interested)

For my samples, I don't do that, so it's a stand alone script

Edited by jdelaney
IEbyXPATH-Grab IE DOM objects by XPATH IEscriptRecord-Makings of an IE script recorder ExcelFromXML-Create Excel docs without excel installed GetAllWindowControls-Output all control data on a given window.
Link to comment
Share on other sites

The MSXML2 version 3.0 works, none of the others do though:

$oXML = ObjCreate("Microsoft.XMLDOM")

$xml = '<?xml version="1.0"?><DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname1" xmlns="http://schemas.microsoft.com/appv/2010/deploymentconfiguration"></DeploymentConfiguration>'
$oXML.loadxml($xml)
ConsoleWrite($oXML.xml)
For $oConfig in $oXML.selectNodes("//DeploymentConfiguration")
    $sDisplayName = $oConfig.getAttribute('DisplayName')
    ConsoleWrite($sDisplayName & @CRLF & @CRLF & @CRLF)
Next

$xml = '<?xml version="1.0"?><DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname2" ></DeploymentConfiguration>'
$oXML.loadxml($xml)
ConsoleWrite($oXML.xml & @CRLF)
For $oConfig in $oXML.selectNodes("//DeploymentConfiguration")
    $sDisplayName = $oConfig.getAttribute('DisplayName')
    ConsoleWrite($sDisplayName & @CRLF)
Next


For $i = 8 To 0 Step -1
    If FileExists(@SystemDir & "\msxml" & $i & ".dll") Then
        $oXML = ObjCreate("Msxml2.DOMDocument." & $i & ".0")
        If IsObj($oXML) Then
            $DOMVERSION = "Msxml2.DOMDocument." & $i & ".0"
            ConsoleWrite($DOMVERSION & @CRLF)
        Else
            ContinueLoop
        EndIf
    Else
        ContinueLoop
    EndIf

    $xml = '<?xml version="1.0"?><DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname' & $DOMVERSION & '-a" xmlns="http://schemas.microsoft.com/appv/2010/deploymentconfiguration"></DeploymentConfiguration>'
    $oXML.loadxml($xml)
    ConsoleWrite($oXML.xml)
    For $oConfig in $oXML.selectNodes("//DeploymentConfiguration")
        $sDisplayName = $oConfig.getAttribute('DisplayName')
        ConsoleWrite($sDisplayName & @CRLF)
    Next

    $xml = '<?xml version="1.0"?><DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname' & $DOMVERSION & '-b" ></DeploymentConfiguration>'
    $oXML.loadxml($xml)
    ConsoleWrite($oXML.xml)
    For $oConfig in $oXML.selectNodes("//DeploymentConfiguration")
        $sDisplayName = $oConfig.getAttribute('DisplayName')
        ConsoleWrite($sDisplayName & @CRLF)
    Next

    ConsoleWrite(@CRLF & @CRLF)
Next

no idea why...output:

<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname1" xmlns="http://schemas.microsoft.com/appv/2010/deploymentconfiguration"></DeploymentConfiguration>
testDisplayname1


<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplayname2"></DeploymentConfiguration>

testDisplayname2
Msxml2.DOMDocument.6.0
<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplaynameMsxml2.DOMDocument.6.0-a" xmlns="http://schemas.microsoft.com/appv/2010/deploymentconfiguration"></DeploymentConfiguration>
<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplaynameMsxml2.DOMDocument.6.0-b"></DeploymentConfiguration>
testDisplaynameMsxml2.DOMDocument.6.0-b


Msxml2.DOMDocument.4.0
<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplaynameMsxml2.DOMDocument.4.0-a" xmlns="http://schemas.microsoft.com/appv/2010/deploymentconfiguration"></DeploymentConfiguration>
<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplaynameMsxml2.DOMDocument.4.0-b"></DeploymentConfiguration>
testDisplaynameMsxml2.DOMDocument.4.0-b


Msxml2.DOMDocument.3.0
<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplaynameMsxml2.DOMDocument.3.0-a" xmlns="http://schemas.microsoft.com/appv/2010/deploymentconfiguration"></DeploymentConfiguration>
testDisplaynameMsxml2.DOMDocument.3.0-a
<?xml version="1.0"?>
<DeploymentConfiguration PackageId="testID" DisplayName="testDisplaynameMsxml2.DOMDocument.3.0-b"></DeploymentConfiguration>
testDisplaynameMsxml2.DOMDocument.3.0-b
Edited by jdelaney
IEbyXPATH-Grab IE DOM objects by XPATH IEscriptRecord-Makings of an IE script recorder ExcelFromXML-Create Excel docs without excel installed GetAllWindowControls-Output all control data on a given window.
Link to comment
Share on other sites

Thanks for going this far with it... I'm trying to figure out the difference of why it would work in 3 but not 6, and I'll post back on this thread if I get anywhere.  And PS you were right , using just load() I can load up an XML based on filepath, instead of passing a string with loadxml().

While ProcessExists('Andrews bad day.exe')
	BlockInput(1)
	SoundPlay('Music.wav')
	SoundSetWaveVolume('Louder')
WEnd
Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

×
×
  • Create New...