check if there is special char input

[MRXTO09]

Hello everyone

1) I wanted to ask if there is a way to find special characters in a string and if it finds them re-do the input. Is there a way?

2) And if there is a space for example "      " re-do th input.

thanks in advance

Edited February 1, 2014 by MRXTO09

[l3ill]

MRXT009,

  1. yes, it's called StringReplace

  2. also have a look at StringStripWS

all under String Management in the help file.

Bill

[Melba23]

MRXTO09,

Here is a simple way to do it:

expandcollapse popup

#include <GUIConstantsEx.au3>

; List the banned characters
Global $sChars = " *a$"
; Escape SRE operators
$sChars = StringRegExpReplace($sChars, "[][$^.{}()+\-]", "\\$0")
Global $sPrevious_Text = ""

$hGUI = GUICreate("Test", 500, 500)

$cInput = GUICtrlCreateInput("", 10, 10, 200, 20)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Read input
    $sText = GUICtrlRead($cInput)
    ; Has text changed?
    If $sText = $sPrevious_Text Then
        ; No so clear tooltip
        ToolTip("")
    Else
        ; Yes so see if it contains any of the banned characters
        If StringRegExp($sText, "[" & $sChars & "]") Then
            ; if so then remove them
            GuiCtrlSetData($cInput, StringRegExpReplace($sText, "[" & $sChars & "]", ""))
            ; And tell the user
            Beep(500, 100)
            $aInputPos = WinGetPos(GUICtrlGetHandle($cInput))
            ToolTip("You entered a banned character", $aInputPos[0] + 10, $aInputPos[1] + 15, Default, Default, 3)
            Sleep(2000)
            ToolTip("")
            $sPrevious_Text = GuiCtrlRead($cInput)
        EndIf
    EndIf
WEnd

The script could be made better by using a message handler to detect when the input has been altered rather than polling the input in the loop - search the forum for EN_CHANGE to see how that is done.

Please ask if anything is unclear.

M23

[jchd]

It all depends on which Unicode character range(s) you classify as "special".