Rename \ Adjusting file names

[MPHillier]

So I have a pptx file w 30 slides that I convert to .jpg monthly.  Working on renaming the 9 slides that have single digits by adding a 0 to the file name. I have the get file to array and file rename etc...

- Example script shows the logic used - wondering how  possibly make it smaller...

Local $sInput = "Slide1.jpg"                        ;-- File name
Local $len = StringLen($sInput)                     ;-- Get string length
if $len = 10 then                           ;-- If string = 10 continue - "else"
   Local $var = StringRight($sInput, 5)                 ;-- Hold right 5 places
   Local $result = StringTrimRight($sInput, 4)              ;-- Trim right 4 placed
   Local $sOutput = StringRegExpReplace($result, "[123456789]", "0")    ;-- replace digits with 0
   MsgBox(0, "Result", $sInput & " - is now - " & $sOutput & $var )     ;-- put back together
else
   MsgBox(0, "Results", "Incorrect target Length" )             ;-- If not string length = 10
EndIf

Luv Autoit - Use it daily.

Much Thanks

[JohnOne]

Local $sInput = "Slide1.jpg"                        ;-- File name
Local $len = StringLen($sInput)                     ;-- Get string length
if $len = 10 then                           ;-- If string = 10 continue - "else"
   ;Local $var = StringRight($sInput, 5)                 ;-- Hold right 5 places
  ; Local $result = StringTrimRight($sInput, 4)              ;-- Trim right 4 placed
   Local $sOutput = StringRegExpReplace($sInput, "[123456789]", "0")    ;-- replace digits with 0
   MsgBox(0, "Result", $sInput & " - is now - " & $sOutput & $var )     ;-- put back together
else
   MsgBox(0, "Results", "Incorrect target Length" )             ;-- If not string length = 10
EndIf

[MPHillier]

I should have stated that the out put should be -

Slide1.jpg = Slide01.jpg

Slide2.jpg = Slide02.jpg

and so on - through the 9 slides.

note todays surf report

- North Shore - 6-8ft  8-15ft face  slight side on shore wind..  little choppy -  I'm going surfing....

[BrewManNH]

Try this on your file names.
 

Local $sOutput = StringRegExpReplace("Slide1.jpg", "([a-zA-Z]+)(\d{1})(\..+)", "${1}0$2$3") ;-- add a 0 before single digit
MsgBox(4096, "Test", $sOutput)

You'll get the file name, followed by at least 2 digits, followed by ".jpg", if the file name already contains more than 1 digit (Slide11.jpg for example), it will return the file name as-is, if the digits are less than 2 it adds a zero in front of the digit.

[MPHillier]

Bunch of thanks - BrewManNH - Set me on a path learning more StringRegExp and patterns... From what I've learned I've been able to use StringRegExpReplace often in my schedule project. Project is running well after two days of tests. Still learning and crunching my codes down in size. Mahalo...

[kylomas]

BrewmanNH - I don't get the curly braces in the first replacement group.  Can you explain?

I also don't get why it works with the following

Local $sOutput = StringRegExpReplace("Slide1A9.jpg", "([a-zA-Z]+)(\d{1})(\..+)", "${1}0$2$3") ;-- add a 0 before single digit
MsgBox(4096, "Test", $sOutput)

It seems like the pattern should fail at the first digit not followed by a period.

kylomas

Edited March 8, 2014 by kylomas

[mikell]

An other way

$string = "Slide1A9.jpg"
Local $sOutput = Execute(StringRegExpReplace($string, '(.+\D)(\d+)(\..+)', "'$1' & StringFormat('%02i', '$2') & '$3' & ") & "''")
MsgBsox(4096, "Test", $sOutput)

Slightly different from BrewMaNH's if you apply on "Slide1A.9.jpg" or "Slide1.A.9.jpg" or "Slide1A_9.jpg" etc

Edit

kylomas,

${1}0 is used to avoid a possible confusion with $10

Edited March 8, 2014 by mikell

[jchd]

MPHillier,

See links in my signature for regexp tutorials. Beware that there are a number of slightly different regexp engines floating around. AutoIt engine is called PCRE (Perl Compatible Regular Expressions).

You can also put StringFormat to good use:

For $i = 1 To 30
    ConsoleWrite(StringFormat("Slide%02i.jpg", $i) & @LF)
Next

[mikell]

jc,

Like kylomas  I don't understand why

StringRegExpReplace("Slide1A9.jpg", "([a-zA-Z]+)(\d{1})(\..+)", "${1}0$2$3")

grabs the "1" in the first backref  $1 with a capturing group like ([a-zA-Z]+)

[jchd]

There is no black magic here, just backtracking:

this part ([a-zA-Z]+)(\d{1}) first matches Slide1 but then (\..+) fails as the next character is A and not a dot.
So we backtrack, thus leaving Slide1 untouched and not affected (hence it will get verbatim in the output) and get
([a-zA-Z]+)(\d{1}) match A9, then (\..+) matches .jpg and we're done.

The output now is:
Slide1       (verbatim because not involved in the match)
A            as $1
0            inserted in replacement pattern
9            as $2
.jpg         as $3

Does the mud clear now?

Edited March 8, 2014 by jchd

[mikell]

Understood, thanks 

So for a better use shouldn't this expression have been like this ?

StringRegExpReplace($string, "(\D)(\d{1})(\..+)", "${1}0$2$3")

Edited March 8, 2014 by mikell

[jchd]

I'd say:

Local $sOutput = StringRegExpReplace("Slide1A9.jpg", "((?<!\d)\d)(\..+)", "0$1$2")
MsgBox(4096, "Test", $sOutput)

[mikell]

Thanks this makes a lot of sense now