Why is close event not ignored...

[netman74501]

expandcollapse popup

#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example")
    Local $iOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iOK
               If _exit() Then
                  ExitLoop
               EndIf
;~                WinActivate($hGUI)
        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _exit()
         $pass = "test"
         $input = InputBox("Password", " ", "", "*", 190, 115, Default, Default, 0, WinGetHandle(AutoItWinGetTitle()) * WinSetOnTop(AutoItWinGetTitle(), '', 1))
         If $input == $pass Then
            $Return = True
         Else
            $Return = False
         EndIf
   Return $Return
EndFunc

If I use Alt+F4, cancel the password prompt and immediately use Alt+F4 again, the window closes. However, if I click on the window between canceling the password prompt and pressing Alt+F4 for the second time or uncomment the WinActivate line, the window does not close (as intended). Why is this?

Edited February 28, 2014 by netman74501

[mLipok]

maybe this can explain this:

this

WinGetHandle(AutoItWinGetTitle())

is not the same 

WinGetHandle("Example")

try this to see what happens:

expandcollapse popup

#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example")
    Local $iOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iOK
                If _exit() Then
                    ExitLoop
                EndIf
                WinActivate($hGUI)
                ConsoleWrite('!TEST 1 WinGetTitle("[ACTIVE]") = ' & WinGetTitle("[ACTIVE]") & @CRLF)
        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _exit()
    Local $Return
    Local $pass = "test"
;~  Local $input = InputBox("Password", " ", "", "*", 190, 115, Default, Default, 0, WinGetHandle(AutoItWinGetTitle()) * WinSetOnTop(AutoItWinGetTitle(), '', 1))
    ; Here I change your script to show you what's going on
    Local $param1 = WinGetHandle(AutoItWinGetTitle())
    ConsoleWrite('!TEST AutoItWinGetTitle() = ' & AutoItWinGetTitle() & @CRLF)
    ConsoleWrite('!TEST WinGetHandle("Example") = ' & WinGetHandle("Example") & @CRLF)
    ConsoleWrite('!TEST $param1 = ' & $param1 & @CRLF)
    Local $param2 = WinSetOnTop(AutoItWinGetTitle(), '', 1)
    Local $param = $param1 * $param2 ; I do not know why You using this kind of code as a parameter in InputBox
    ConsoleWrite('!TEST $param = ' & $param & @CRLF)
    Local $input = InputBox("Password", " ", "", "*", 190, 115, Default, Default, 0, $param)
    ConsoleWrite('!TEST @error = ' & @error & @CRLF)
    ConsoleWrite('!TEST $input = ' & $input & @CRLF)
    ConsoleWrite('!TEST 2 WinGetTitle("[ACTIVE]") = ' & WinGetTitle("[ACTIVE]") & @CRLF)
    ; end
    If $input = $pass Then
        $Return = True
    Else
        $Return = False
    EndIf
    ConsoleWrite('!TEST $Return = ' & $Return & @CRLF)
    Return $Return
EndFunc   ;==>_exit

Edited February 28, 2014 by mLipok

[mLipok]

this is working one:

expandcollapse popup

;~ http://www.autoitscript.com/forum/topic/159387-why-is-close-event-not-ignored/

#include <GUIConstantsEx.au3>

Example()
Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example")
    Local $iOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iOK
                If _Exit($hGUI) Then
                    ExitLoop
                EndIf
;~              WinActivate($hGUI)
        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _Exit($hGUI)
    Local $fReturn
    Local $sPass = "test"
    Local $sInput = InputBox("Password", " ", "", "*", 190, 115, Default, Default, 0, WinGetHandle($hGUI))
    If $sInput == $sPass Then
        $fReturn = True
    Else
        $fReturn = False
    EndIf
    Return $fReturn
EndFunc   ;==>_Exit

 

 

and

I encourage you to study

Best coding practices

[netman74501]

Thank you!

WinGetHandle(AutoItWinGetTitle()) * WinSetOnTop(AutoItWinGetTitle(), '', 1)

This tidbit was what I had found here on the forums to make the input box always on top. However, I see now that by setting the parent window handle parameter, the input box is on top of the window as I intended. While I believed I needed to have the input box always on top, I now realize that using the parameter provided will suffice.

[guinness]

I think I did something like that previously.

[mLipok]

I think I did something like that previously.

So can you bring what would be the point? Even if it would not be yours, but supposed your goal

[guinness]

I meant I think that was my "titbit".