What do people find easier? Ternary or If...Else?

[guinness 1,541]

What do people find easier to understand? Personally I prefer code number 1.

 

1:

#include <MsgBoxConstants.au3>

Local $bIsTrue = True
Local $sMessage =  'This is ' & ($bIsTrue ? 'True' : 'False')
MsgBox($MB_SYSTEMMODAL, '', $sMessage)

2:

#include <MsgBoxConstants.au3>

Local $bIsTrue = True
Local $sMessage
If $bIsTrue Then
    $sMessage = 'This is True'
Else
    $sMessage = 'This is False'
EndIf
MsgBox($MB_SYSTEMMODAL, '', $sMessage)

Edited June 25, 2014 by guinness

[kylomas 418]

Ditto...

[JohnOne 1,626]

Both pretty easy to understand.

I use 2.

[MyEarth 11]

The second, the 1° isn't explicative like the 2°

P.S. My "proposal" of make possible to have If...Then...Else on the same line:

If <expression> Then statement1 Else statement2 

Was "voted down" as confusing and complicated, imho for the same logic i can say the same for ternary

[guinness 1,541]

P.S. My "proposal" of make possible to have If...Then...Else on the same line:

Your brain just needs to switch between ? and:, not difficult really.

[BrewManNH 1,316]

Except ternary doesn't work in some cases where an If/Else statement would. Such as discussed in trac ticket #2589. Not saying it should work that way, just saying that if/else inline would work differently than ternary.

[Gianni 846]

 

What do people find easier to understand? Personally I prefer code number 1.

1:

#include <MsgBoxConstants.au3>

Local $bIsTrue = True
Local $sMessage = ($bIsTrue) ? 'This is True' : 'This is False'
MsgBox($MB_SYSTEMMODAL, '', $sMessage)

2:

#include <MsgBoxConstants.au3>

Local $bIsTrue = True
Local $sMessage
If $bIsTrue Then
    $sMessage = 'This is True'
Else
    $sMessage = 'This is False'
EndIf
MsgBox($MB_SYSTEMMODAL, '', $sMessage)

 

3:

#include <MsgBoxConstants.au3>

Local $sMessage[2] = ["This is False", "This is True"]
Local $bIsTrue = True
MsgBox($MB_SYSTEMMODAL, "", $sMessage[$bIsTrue])

also an option 3: could be considered

Edited March 1, 2014 by PincoPanco

[guinness 1,541]

PincoPanco,

True, as it's something I do quite often, though don't know if it's good practice or not.

[guinness 1,541]

Except ternary doesn't work in some cases where an If/Else statement would. Such as discussed in trac ticket #2589. Not saying it should work that way, just saying that if/else inline would work differently than ternary.

Actually you're right.

 

MyEarth,

They are two separate things actually.

[czardas 1,286]

I believe the ternary operator is just returning one of two values; on the other hand, If...Else is more for general use, where you might want to include many lines of code depending on the outcome of the condition. Using the ternary operator is definately much neater if you can get away with doing so.

Edited March 1, 2014 by czardas

[UEZ 1,433]

I'm using both - for very simple check I use 1., for the rest 2.

Br,

UEZ

[Sori 9]

I use #2.

[jchd 1,810]

Ternary is an operator acting on right handed term, while If is a block construct enclosing statement(s). Both are useful.

In the post #1 case, I favor:

#include <MsgBoxConstants.au3>

Local $bIsTrue = 1
Local $sMessage =  'This is ' & ($bIsTrue ? 'True' : 'False')
MsgBox($MB_SYSTEMMODAL, '', $sMessage)

And, even (in case I insist on True/False keywords):

#include <MsgBoxConstants.au3>

Local $bIsTrue = 1
Local $sMessage =  'This is ' & ($bIsTrue = (0=0))
MsgBox($MB_SYSTEMMODAL, '', $sMessage)

[JohnOne 1,626]

ternary has it's uses, but it's not this.

If 1 = 2 Then
    ;blah
ElseIf 1 = 3 Then
    ;blah
Else
    ;blah
EndIf

[Gianni 846]

...

And, even (in case I insist on True/False keywords):

#include <MsgBoxConstants.au3>

Local $bIsTrue = 1
Local $sMessage =  'This is ' & ($bIsTrue = (0=0))
MsgBox($MB_SYSTEMMODAL, '', $sMessage)

nice,

maybe is clearer like this

Local $sMessage = 'This is ' & ($bIsTrue = True)

[jaberwacky 335]

I think they are both easy to understand.  I do like using switch though when speed isn't that big of a deal.  Just looks cleaner imho.

[FireFox 261]

though don't know if it's good practice or not.

You can't do this in typed languages without having to cast the boolean to a number.

Hence I would say it's not a good practice (it's not clearly explicit then).

And for the ternary IMO you can use it as much as you want while your code is quickly readable (returns to the point of code maintainability).

[Malkey 243]

Where I used to use _Iif for inline use, now I would use the ternary statement.

#include <Misc.au3> ; _Iif is still here, but not in help file.

Local $i_Count, $i_Index

For $i_Index = 1 To 2
    MsgBox(4096, "Count (_Iif)", "This dialog has displayed " & String($i_Index) & _
            " time" & _Iif($i_Index > 1, "s", "") & " so far")
Next

For $i_Index = 1 To 2
    MsgBox(4096, "Count (Ternary)", "This dialog has displayed " & String($i_Index) & _
            " time" & ($i_Index > 1 ? "s" : "") & " so far")
Next

[this-is-me 7]

Since I originally came from javascript, where you could do an if(this=so_n_so){dosomething} all on one line, and where ternary was normal, I am more than thrilled that ternary support is here in AutoIt now.

[JohnOne 1,626]

You know you can do that in AutoIt?

If 1 = 1 Then MsgBox(0,0,0)