Checking for an installed program

[austin55]

Hello i am writing an script that checks whether an a program is installed or not.  I am using the command prompt to run commands to see if the service is running or not. 

 

CheckForInstall()

 

Func CheckforInstall()

; checks to see if software is installed

;new software

Local $Service = "Software"

;new program

Local $pidSoftware = RunWait(@comspec & " /c sc query" &$Service, "",@SW_HIDE)

 

Local $Client = RunWait(@comspec & " /c sc query Client", "",@SW_HIDE)

 

Local $pidOldSoftware = RunWait(@comspec & " /c sc query OldSoftwareName", "",@SW_Hide)

Global $Data

 

 

If $Service = $pidSoftware Then

 

 ; checks to make sure old service is stop and disabled and if not disables

 Do

 $Data &= StdOutRead($pidNewProgram)

 Until @error

 If StringInStr($data,"running") Then

 Software_Stop_Disable()

 Exit

 EndIf

   Else

 

; does installer

install()

EndIf

 

the problem I am getting is that my variables are not getting filled with the data from the command prompt. I am a little loss on how to do this

[someone]

Do you have to check if the software is installed by the service?  Does the software drop a GUID or uninstall key you can query? Beyond that if you search around you will find some examples of WMI to check if a service is running.

Trying to read the stdout stream won't work the way you are doing it... but I wouldn't suggest that route unless you need to.  If you can't use WMI or uninstall key I'll help you out with stdout.

[JLogan3o13]

I'm confused. As was commented on, are you looking to see if an application is installed, or a service is running? If you're looking for whether something is installed, you can do something like this:

$sPrompt = InputBox("Search installed software", "Please enter part of the software name")
$sKey  = "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"

   For $j = 1 To 500
        $AppKey = RegEnumKey($sKey, $j)
        If @error <> 0 Then Exitloop
        If StringInStr(RegRead($sKey & "\" & $AppKey, "DisplayName"), $sPrompt) Then
            MsgBox(0, $AppKey, RegRead($sKey & "\" & $AppKey, "DisplayName"))
        EndIf
    Next

Edit: Or if you want to go really big, you could add uninstall options:

expandcollapse popup

#include <GuiListView.au3>
Opt("TrayAutoPause", 0)
Opt('GUIOnEventMode', 1)
Opt('GUICloseOnEsc' , 1)



Global $i
Local $sSft
Global $sGui = GUICreate('Currently Installed Software', 810, 650, -1, -1)
Global $sLvw = GUICtrlCreateListView('#|Installed Software|Display Version|Publisher|Uninstall String', 5, 5, 800, 600)
_ComputerGetSoftware($sSft)



For $i = 1 To ubound($sSft) - 1
    GUICtrlCreateListViewItem($i & '|' & $sSft[$i][0] & '|' & $sSft[$i][1] & '|' & $sSft[$i][2] & '|' & $sSft[$i][3], $sLvw)
Next
GUICtrlSendMsg($sLvw, 0x101E, 1, 175)
GUICtrlSendMsg($sLvw, 0x101E, 2, 65)
GUICtrlSendMsg($sLvw, 0x101E, 3, 150)
GUICtrlSendMsg($sLvw, 0x101E, 4, 350)
Local $mMen = GUICtrlCreateContextMenu($sLvw)
Local $CopI = GUICtrlCreateMenuItem('Uninstall Current Selection', $mMen)
GUICtrlSetOnEvent($CopI, '_Uninstall')
Local $exp = GUICtrlCreateButton('  Expand  ', 720, 615)
GUICtrlSetOnEvent($exp, '_Expand')
GUISetOnEvent(-3, '_AllExit')
GUISetState(@SW_SHOW, $sGui)

While 1
    Sleep(10)
WEnd
;
Func _AllExit()
    GUIDelete($sGui)
    Exit
EndFunc
;
Func _Uninstall()
    Local $proc = StringSplit(GUICtrlRead(GUICtrlRead($sLvw)), '|', 1)
    If $proc[1] == 0 Then Return -1
    If $proc[5] Then ShellExecuteWait ($proc[5])
        exit
EndFunc
;
Func _Copy2Clip()
    Local $proc = StringSplit(GUICtrlRead(GUICtrlRead($sLvw)), '|', 1)
    If $proc[1] == 0 Then Return -1
    If $proc[5] Then ClipPut($proc[5])
EndFunc
;
; Author JSThePatriot - Modified June 20, 2010 by ripdad
Func _ComputerGetSoftware(ByRef $aSoftwareInfo)
    Local Const $UnInstKey = "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"
    Local $i = 1
    Dim $aSoftwareInfo[1][4]
    $input = inputbox ("Which Software" , "Which Software would you like to view?", 'ALL')
    If @Error = 1 Then Exit
    If $input = 'ALL' Then
    For $j = 1 To 500
        $AppKey = RegEnumKey($UnInstKey, $j)
        If @error <> 0 Then Exitloop
        If RegRead($UnInstKey & "\" & $AppKey, "DisplayName") = '' Then ContinueLoop
        ReDim $aSoftwareInfo[UBound($aSoftwareInfo) + 1][4]
        $aSoftwareInfo[$i][0] = StringStripWS(StringReplace(RegRead($UnInstKey & "\" & $AppKey, "DisplayName"), " (remove only)", ""), 3)
        $aSoftwareInfo[$i][1] = StringStripWS(RegRead($UnInstKey & "\" & $AppKey, "DisplayVersion"), 3)
        $aSoftwareInfo[$i][2] = StringStripWS(RegRead($UnInstKey & "\" & $AppKey, "Publisher"), 3)
        $aSoftwareInfo[$i][3] = StringStripWS(RegRead($UnInstKey & "\" & $AppKey, "UninstallString"), 3)
        $i = $i + 1

    Next
    $aSoftwareInfo[0][0] = UBound($aSoftwareInfo, 1) - 1
    If $aSoftwareInfo[0][0] < 1 Then SetError(1, 1, 0)
    Return _ArraySort($aSoftwareInfo)

Else

    For $j = 1 To 500
        $AppKey = RegEnumKey($UnInstKey, $j)
        If @error <> 0 Then Exitloop
        $Reg = RegRead($UnInstKey & "\" & $AppKey, "DisplayName")
        $string = stringinstr($Reg, $input)
        If $string = 0 Then Continueloop
        ReDim $aSoftwareInfo[UBound($aSoftwareInfo) + 1][4]
        $aSoftwareInfo[$i][0] = StringStripWS(StringReplace(RegRead($UnInstKey & "\" & $AppKey, "DisplayName"), " (remove only)", ""), 3)
        $aSoftwareInfo[$i][1] = StringStripWS(RegRead($UnInstKey & "\" & $AppKey, "DisplayVersion"), 3)
        $aSoftwareInfo[$i][2] = StringStripWS(RegRead($UnInstKey & "\" & $AppKey, "Publisher"), 3)
        $aSoftwareInfo[$i][3] = StringStripWS(RegRead($UnInstKey & "\" & $AppKey, "UninstallString"), 3)
        $i = $i + 1

    Next
    $aSoftwareInfo[0][0] = UBound($aSoftwareInfo, 1) - 1
    If $aSoftwareInfo[0][0] < 1 Then SetError(1, 1, 0)
    Return _ArraySort($aSoftwareInfo)

    Endif
EndFunc
;
Func _Expand()
    _GUICtrlListView_SetColumnWidth($sLvw, 1, $LVSCW_AUTOSIZE)
    _GUICtrlListView_SetColumnWidth($sLvw, 2, $LVSCW_AUTOSIZE)
    _GUICtrlListView_SetColumnWidth($sLvw, 3, $LVSCW_AUTOSIZE)
    _GUICtrlListView_SetColumnWidth($sLvw, 4, $LVSCW_AUTOSIZE)
EndFunc

Edited April 14, 2014 by JLogan3o13

[ZombieKillz]

austin55,

Check out this UDF (_NTServices.au3) - '?do=embed' frameborder='0' data-embedContent>>

[guinness]

JLogan3o13,

What is 0x101E?

[JLogan3o13]

guinness, my bad - old script that still has some magic number goodness in it. 0x101E is LVM_SETCOLUMNWIDTH, IIRC

[jguinch]

JLogan3o13, I think your registry list method is a good solution.

I have just two little things to add:
 - don't forget the HKLM64 hive if needed

 - replace For $j = 1 To 500 by

    Local $j = 1
    While 1
    $j += 1

(just if the user has over 500 programs installed )

Edited April 14, 2014 by jguinch

[guinness]

Variables declared inside a loop will signigficantly slow down the script's execution.

[austin55]

Hello, sorry for the confusion, I was mistakenly thinking i could check to see if a service is installed and then i could go off of that whether the program is installed or not. But that wouldn't work in this..

Here's what i am looking for: to a create a script to tell me if a program is is installed or not and if not then run through an installer, I have the installer already scripted. The software that I am checking for a server monitoring software called Nagios. 

 

I have modified the code above in ( JLogan3o13) post to this:

; Checks to see if new nagios client is installed
    ;new nagios client
    $sPrompt1 = "NSClient++"
    $sNagiosNewClient = "HKEY_LOCAL_MACHINE\SOFTWARE\"

    ; used for Old Nagios Client
    $sPrompt = "Nagios"
   ; NSClient 2.0
   $sNagiosOldClient =  "HKEY_LOCAL_MACHINE\SOFTWARE\NSClient"
    For $j = 1 To 500
        $AppKey = RegEnumKey($sNagiosNewClient, $j)

        If @error <> 0 Then Exitloop

        If StringInStr(RegRead($sNagiosNewClient & "\" & $AppKey, "DisplayName"), $sPrompt1) Then

            MsgBox(0, $AppKey, RegRead($sNagiosNewClient & "\" & $AppKey, "DisplayName"))
            ; it is installed
         Else
            ; checks to see if old client is installed

         $AppKey = RegEnumKey($sNagiosOldClient, $j)

        If @error <> 0 Then Exitloop

        If StringInStr(RegRead($sNagiosOldClient & "\" & $AppKey, "DisplayName"), $sPrompt) Then

            MsgBox(0, $AppKey, RegRead($sNagiosOldClient & "\" & $AppKey, "DisplayName"))
         Else
            MsgBox(0,"Exiting", "Old Nagios Installed, Continueing with installation")

        EndIf
        EndIf
   Next
 

My question is, am i able to run it like this with having both checking in the same for statement?

Edited April 21, 2014 by austin55