run script and then delete itself from current location

[Briandr]

Hi,

 

Can someone tell me what I would need add to the end of this AutoIT script so the file gets deleted from it's current location after it ran sucessfully? It current location will vary with the logged user because it is being copied over to individual profile Start Menu->Programs->Start Up folders in Windows 7.

expandcollapse popup

; This program will set firefox to not auto-update itself

$debug=False

; wait for Firefox to close because the prefs.js will be overwritten when Firefox closes and the changes we make will be lost
ProcessWaitClose("firefox.exe")

If FileExists( @AppDataDir & "\Mozilla\Firefox\profiles.ini" ) Then
    $var = IniRead(@AppDataDir & "\Mozilla\Firefox\profiles.ini", "Profile0", "Path", "NotFound")
Else
    Exit
EndIf

; replace the / in the Path with a backslash
$var = StringReplace($var,"/","\")
$preffile = @AppDataDir & "\Mozilla\Firefox\" & $var & "\prefs.js"

; if the file exists then open it
if FileExists( $preffile ) Then
    $fh = FileOpen( $preffile, 0 )
    $message = FileRead( $fh )
    FileClose( $fh )
    ; if the string doesn't exist we need to add it otherwise we make sure it is set to false
    If StringInStr( $message, "app.update.enabled" ) Then
        ; check to see if it is already false... if so just Exit
        If StringInStr( $message, "user_pref(""app.update.enabled"", true);" ) Then
            $message = StringReplace( $message, "user_pref(""app.update.enabled"", true)", "user_pref(""app.update.enabled"", false)")
            $update=True
        Else
            ; it is already false so just Exit
            Exit
        EndIf
    Else
        $message = StringReplace( $message, " */" & @CRLF & @CRLF,  " */" & @CRLF & @CRLF & "user_pref(""app.update.enabled"", false);" & @CRLF )
        $update=True
    EndIf
Else
    Exit
    ; $message = "Prefs file does not exist."
EndIf

If $debug Then MsgBox(4096, "Result", $message)

If $update Then
    ; we need to update the file
    $fh = FileOpen($preffile, 2)
    ; Check if file opened for writing OK
    If $fh = -1 Then
        MsgBox(0, "Error", "Unable to open file.")
        Exit
    EndIf
    FileWrite($fh, $message)
    FileClose($fh)
EndIf

 

Thanks.

Edited April 15, 2014 by Melba23
Added code tags

[Melba23]

Briandr,

In future, please post in the correct section of the forum and use code tags.

M23

[BrewManNH]

guinness wrote a SelfDelete function that should do what you need. It's posted in the Examples section.

[Exit]

Here a simple solution.

OnAutoItExitRegister(_Exit)

Exit MsgBox(Default, "", "Press ENTER to exit")

Func _Exit()
    if @compiled then Run(@ComSpec & " /c PING -n 5 127.0.0.1 && DEL  " & '"' & @ScriptFullPath & '"', "", @SW_HIDE)
EndFunc   ;==>_Exit

Edited April 15, 2014 by Exit

[Briandr]

Thanks all to who responded. Sorry moderator didn't realize I was in wrong forum.

[someone]

guinness wrote a SelfDelete function that should do what you need. It's posted in the Examples section.

 

I know if you go into Scite, type the word selfdelete and hit space you get a self delete function.

[BrewManNH]

That's interesting to learn, I didn't know that was in the abbreviations listing. But then, 99% of what's in that list I have never used or looked at.

[someone]

Haha I didn't even know there was an abbreviates listing!  I had to remember the selfdelte thing from an old post.  The things you learn...