Question about simple script?

[UserMane]

Hello,

I would like to write a small program/script and am looking for advice on how to do so. I do not have a preference about which method or language to use, hopefully looking for the simplest way to do this (if it works with Windows or DOS command line this is preferable).

I have a program that runs on text files e.g. "program file1.txt file2.txt"

I have 20 folders that each have 5-10 text files. I want to automatically get the name of the largest size text file from each of the 20 folders, and then run the program on these 20 files as described above.

Ideally I could point my script to a folder, and it will automatically find the largest .txt file in each of the subdirectories and run "program file1.txt file2.txt file3.txt ..."

Any ideas on how to most efficiently accomplish this? Ideas or links to tutorials if applicable are helpful.

Thank you

Edited April 19, 2014 by UserMane

[somdcomputerguy]

Welcome to the forum. http://www.autoitscript.com/autoit3/docs/ - Good place to start.

[Melba23]

UserMane,

Welcome to the AutoIt forum.

But please pay attention to where you post - the "Dev Chat" section where you started this thread is not for general support questions. I have moved it for you, but would ask you to be more careful in future.

M23

[sahsanu]

Here just an example to get an array for file with max size in each of the 20 dirs. The first part of the script is just to create 20 dirs and files inside them with random text to make them different in size. The script is commented, anyway if you have any doubt don't hesitate to ask. Of course, if someone can show any easy way to perform the task, he/she will be welcome (all os us are here to learn) ;-)

expandcollapse popup

#include <String.au3>
#include <Array.au3>
#include <File.au3>

Local $aListDirsToSearchIn[20] ;You should create this array with the list of dirs you want to search in

;This part is just to create 20 dirs and 5 to 10 files with random size per directory just for the example
For $i = 1 To 20
    $sDirectory = @ScriptDir & "\directory" & StringFormat("%02d", $i)
    DirCreate($sDirectory)
    For $j = 1 To Random(5, 10, 1)
        $sFile = $sDirectory & "\file" & StringFormat("%02d", $j) & ".txt"
        $sString = StringReplace(_StringRepeat("Filling file " & $sFile & @CRLF, Random(1, 1000, 1)), @CRLF, "", -1)
        FileWrite($sFile, $sString)
    Next
    $aListDirsToSearchIn[$i - 1] = $sDirectory
Next
;End of creating the dirs and files structure for the example


Local $aResultList[UBound($aListDirsToSearchIn)][2] ;Define the array where the max size file on each dir will be stored
For $i = 1 To UBound($aListDirsToSearchIn) ;Loop each dir to search the files inside it
    Local $aListFiles = _FileListToArray($aListDirsToSearchIn[$i - 1], "*.txt", 1, True) ;Retrieve the files in dir
    Local $aSortingFiles[$aListFiles[0]][2];Define a 2D array where we will store the file name on column 0 ans size in column 1
    For $j = 1 To UBound($aSortingFiles) - 1 ;Loop the 2D array filling the rows and columns with file name and size
        Local $iSize = FileGetSize($aListFiles[$j])
        $aSortingFiles[$j - 1][0] = $aListFiles[$j]
        $aSortingFiles[$j - 1][1] = $iSize
    Next
    _ArraySort($aSortingFiles, 1, Default, Default, 1) ;Sort the column 1 (size) descencing
    $aResultList[$i - 1][0] = $aSortingFiles[0][0] ;Fill the final array with file name that has max file in dir
    $aResultList[$i - 1][1] = $aSortingFiles[0][1] ;Fill the final array with size for that file name
Next

_ArrayDisplay($aResultList) ;The resulting array will have a list with the max size file per directory and you could use for your needs


;This part is to remove the dirs and files created on @Scriptdir for the example, un commented them if you want to delete the dirs created
#cs
    For $i = 1 To 20
    $directory = @ScriptDir & "\directory" & StringFormat("%02d", $i)
    DirRemove($directory, 1)
    Next
#ce

The part to do whatever you want with the max size files list is up to you ;-)

Edit: Typos

Cheers,

sahsanu

Edited April 20, 2014 by sahsanu