_AddLeadingZeros()

[mLipok]

I would like to present this little useful function:

For $i = 1 To 10
    ConsoleWrite(_AddLeadingZeros($i), 5) & @CRLF)
Next

Func _AddLeadingZeros($iDigitToExpand, $iNumberOfDigits)
    If Not IsString($iDigitToExpand) Then $iDigitToExpand = String($iDigitToExpand)
    If StringIsDigit($iDigitToExpand) Then
        Local $sVarLen = StringLen(String($iDigitToExpand))
        For $i = 1 To $iNumberOfDigits - $sVarLen
            $iDigitToExpand = '0' & String($iDigitToExpand)
        Next
    EndIf
    Return $iDigitToExpand
EndFunc   ;==>__AddLeadingZeros

mLipok

[BrewManNH]

Or you could do this.

For $i = 1 To 10
    ConsoleWrite(StringFormat("%05s",$i) & @CRLF)
Next

Or this if you want it to be variable length.
 

Global $Length = 5
For $i = 1 To 10
    ConsoleWrite(StringFormat("%0" & $Length & "s",$i) & @CRLF)
Next

Edited April 26, 2014 by BrewManNH

[JohnOne]

Or if you want the example to work, and with a little less processing.

For $i = 1 To 10
    ConsoleWrite(_AddLeadingZeros($i, 5) & @CRLF)
Next

Func _AddLeadingZeros($iDigitToExpand, $iNumberOfDigits)
    If Not IsString($iDigitToExpand) Then $iDigitToExpand = String($iDigitToExpand)
    If StringIsDigit($iDigitToExpand) Then
        Local $sVarLen = StringLen(String($iDigitToExpand))
        Local $0 = ""
        For $i = 1 To $iNumberOfDigits - $sVarLen
            $0 &= "0"
        Next
        $iDigitToExpand = $0 & $iDigitToExpand
    EndIf
    Return $iDigitToExpand
EndFunc   ;==>_AddLeadingZeros

[UEZ]

Here another way using built-in (UDF) function:
 

#include <String.au3>

For $i = 1 To 10
    ConsoleWrite(_StringRepeat("0", 5 - StringLen($i)) & $i & @CRLF)
Next

Br,

UEZ

[JohnOne]

For $i = 1 To 12
    ConsoleWrite(_Func($i, 4) & @LF)
Next

Func _Func($iDigitToExpand, $iNumberOfDigits)
    Local $0 = "00000000000000000000000000000000000"
    Return StringLeft($0, $iNumberOfDigits - StringLen($iDigitToExpand)) & $iDigitToExpand
EndFunc

[mLipok]

Thanks to all for interesting ideas and different variations for this task.
After the thoughts that I think will be the shortest version:

For $i = 1 To 12
    ConsoleWrite(_AddLeadingZeros($i, 5) & @LF)
Next

Func _AddLeadingZeros($iDigitToExpand, $iNumberOfDigits)
    Return StringRight("00000000000000000000000000000000000" & String($iDigitToExpand), $iNumberOfDigits)
EndFunc   ;==>_AddLeadingZeros

Of course, assuming we do not exceed a certain fixed amount of zeros.

Best regards,

mLipok

EDIT:

I'm sorry, I admit myself to an mistake.

BrewManNH version is shorter:

Func _AddLeadingZeros($iDigitToExpand, $iNumberOfDigits)
    Return StringFormat("%0" & $iNumberOfDigits & "s", $iDigitToExpand)
EndFunc   ;==>_AddLeadingZeros

Edited April 27, 2014 by mLipok

[guinness]

Though StringFormat() has a huge overhead.

[mLipok]

You mean CPU usage ?

[guinness]

No in terms of execution, it's quite slow compared to the likes of the string functions and even SRE.

[BrewManNH]

How often do you plan on using it depends on which function to use. Also, do you have benchmarks that show this? I remember the debate over UBound vs. the count in the first element and which was slower, could be a perception problem rather than an actual problem.

[guinness]

Also, do you have benchmarks that show this?

No.

I remember the debate over UBound vs. the count in the first element and which was slower, could be a perception problem rather than an actual problem.

This was the case once until a developer changed how UBound() worked.

[BrewManNH]

In regards to the speed of StringFormat over other methods, it is slower but does give you the correct results whereas the other methods don't seem to do as well. The StringRight method will cut off any number longer than the specified length, if the length is 5 then any number over 99999 is going to come back as a 5 digit number and not the correct result. The function posted originally will only work with integers and not floating point numbers because of the StringIsDigit function.

So, if accuracy is the goal, and length of the number might be an issue, and you're dealing with anything other than integers, the _StringRepeat function is probably the most efficient out of all the posted examples. It's about twice as fast as StringFormat and gives the correct results.

[Celtic88]

expandcollapse popup

$TXTT = RANDOMCHR(99)
MsgBox(0, "", $TXTT)

$RTXTT = REV($TXTT)
MsgBox(0, "", $RTXTT)

$CTXTT = CRYPTTEXT($RTXTT)
MsgBox(0, "", $CTXTT)

$DTXTT = DCRYPTTEXT($CTXTT)
MsgBox(0, "", $DTXTT)

$RTXTT2 = REV($DTXTT)
MsgBox(0, "", $RTXTT2)

Func RANDOMCHR($LEN)
    Local $T, $LOL
    For $I = 1 To $LEN
        Do
            $T = Random(48, 122, 1)
        Until Not ($T >= 58 And $T <= 64 Or $T >= 91 And $T <= 97)
        $LOL &= Chr($T)
    Next
    Return $LOL
EndFunc   ;==>RANDOMCHR

Func REV($txt)
    Local $LOL, $LEN = StringLen($txt)
    For $I = $LEN To 1 Step -1
        $LOL &= StringMid($txt, $I, 1)
    Next
    Return $LOL
EndFunc   ;==>REV

Func CRYPTTEXT($txt)
    Local $CRYPTXT
    For $I = 1 To StringLen($txt)
        $CRYPTXT &= Chr(Asc(StringMid($txt, $I, 1)) + 60)
    Next
    Return $CRYPTXT
EndFunc   ;==>CRYPTTEXT

Func DCRYPTTEXT($txt)
    Local $CRYPTXT
    For $I = 1 To StringLen($txt)
        $CRYPTXT &= Chr(Asc(StringMid($txt, $I, 1)) - 60)
    Next
    Return $CRYPTXT
EndFunc   ;==>DCRYPTTEXT

[ValeryVal]

Recursive version:

For $i = 1 To 10 
    ConsoleWrite(_AddLeadingZeros($i, 5) & @CRLF)
Next

Func _AddLeadingZeros($iDigitToExpand, $iNumberOfDigits)
 if $iNumberOfDigits <= StringLen($iDigitToExpand) then Return $iDigitToExpand
 Return "0" & _AddLeadingZeros($iDigitToExpand, $iNumberOfDigits-1)
EndFunc   ;==>_AddLeadingZeros

Edited April 29, 2014 by ValeryVal

[ValeryVal]

 

Recursive version:

For $i = 1 To 10 
    ConsoleWrite(_AddLeadingZeros($i, 5) & @CRLF)
Next

Func _AddLeadingZeros($iDigitToExpand, $iNumberOfDigits)
 if $iNumberOfDigits <= StringLen($iDigitToExpand) then Return $iDigitToExpand
 Return "0" & _AddLeadingZeros($iDigitToExpand, $iNumberOfDigits-1)
EndFunc   ;==>_AddLeadingZeros

Fibonacci numbers:

For $i = 1 To 10
    ConsoleWrite(fib($i) & @CRLF)
Next

func fib($i)
  if $i = 1 or $i = 2 then
   Return 1
  else
   Return fib($i-1) + fib($i-2)
  endif
endfunc

Factorial:

For $i = 1 To 10
  ConsoleWrite(factorial($i) & @CRLF)
Next

func factorial ($i)
  if $i = 0 then
   Return 1
  else
   Return $i*factorial($i-1)
  endif
endfunc

Edited April 29, 2014 by ValeryVal